1

タイプをサードパーティのライブラリからIDictionarys に変換して、簡単に (JSON に) シリアル化できるようにする関数が必要です。型間に依存関係があるため、辞書がネストされることがあります。

今、私はこのような恐ろしいものを持っています:

//Example type
type A(name) = 
  member __.Name  = name

//Example type
type B(name, alist) =
  member __.Name = name
  member __.AList : A list = alist

let rec ToSerializable x =
  match box x with
  | :? A as a -> dict ["Name", box a.Name]
  | :? B as b -> dict ["Name", box b.Name; "AList", box (List.map ToSerializable b.AList)]
  | _ -> failwith "wrong type"

これにより、すべてがプリミティブ型、そのIEnumerableような型、または辞書に変換されます。

この関数は、型が追加されるにつれて成長し続けます (ug)。タイプ セーフではありません (キャッチオール パターンが必要です)。どのタイプがサポートされているかを理解するには、モノリシック パターン マッチを熟読する必要があります。

これができるようになりたいです：

type ThirdPartyType with
  member x.ToSerializable() = ...

let inline toSerializable x =
  (^T : (member ToSerializable : unit -> IDictionary<string,obj>) x)

let x = ThirdPartyType() |> toSerializable //type extensions don't satisfy static member constraints

だから、私はここで創造性を探しています。私の苦情に対処するこれを書くより良い方法はありますか?

4

2 に答える 2

3

必ずしも拡張性の質問ではありませんが、タイプセーフの問題に対処する1つの可能な解決策を次に示します。

// these types can appear in any assemblies
type A = { Name : string }
type B = { Name : string; AList : A list }
type C(name:string) =
    member x.Name = name
    static member Serialize(c:C) = dict ["Name", box c.Name]

 

// all of the following code goes in one place
open System.Collections.Generic

type SerializationFunctions = class end

let inline serializationHelper< ^s, ^t when (^s or ^t) : (static member Serialize : ^t -> IDictionary<string,obj>)> t = 
    ((^s or ^t) : (static member Serialize : ^t -> IDictionary<string,obj>) t)
let inline serialize t = serializationHelper<SerializationFunctions,_> t

// overloads for each type that doesn't define its own Serialize method
type SerializationFunctions with
    static member Serialize (a:A) = dict ["Name", box a.Name]
    static member Serialize (b:B) = dict ["Name", box b.Name; "AList", box (List.map serialize b.AList)]

let d1 = serialize { A.Name = "a" }
let d2 = serialize { B.Name = "b"; AList = [{ A.Name = "a" }]}
let d3 = serialize (C "test")
于 2012-04-05T01:30:29.847 に答える
2

簡単で明白なアイデアとして: オーバーロードを使用する

//Example type
type A(name) = 
  member __.Name  = name

//Example type
type B(name, alist) =
  member __.Name = name
  member __.AList : A list = alist

type Converter =
    static member ToSerializable(a : A) = dict ["Name", box a.Name]
    static member ToSerializable(b : B) = dict ["Name", box b.Name; "AList", box (b.AList |> List.map Converter.ToSerializable)]
于 2012-04-05T01:31:35.727 に答える