3

私が書いている perl スクリプトは、Makefile のような継続行を持つファイルを解析する必要があります。つまり、空白で始まる行は前の行の一部です。

私は以下のコードを書きましたが、あまりクリーンでも perl っぽいとも思えません (「redo」も使用していません!)。

多くのエッジ ケースがあります: 奇妙な場所での EOF、単一行のファイル、空白行 (または非空白行、または継続行) で開始または終了するファイル、空のファイル。すべてのテスト ケース (およびコード) は次の場所にあります: http://whatexit.org/tal/flatten.tar

私のすべてのテストに合格する、よりクリーンで perl っぽいコードを書くことができますか?

#!/usr/bin/perl -w

use strict;

sub process_file_with_continuations {
    my $processref = shift @_;
    my $nextline;
    my $line = <ARGV>;

    $line = '' unless defined $line;
    chomp $line;

    while (defined($nextline = <ARGV>)) {
        chomp $nextline;
        next if $nextline =~ /^\s*#/;  # skip comments
        $nextline =~ s/\s+$//g;  # remove trailing whitespace
        if (eof()) {  # Handle EOF
            $nextline =~ s/^\s+/ /;
            if ($nextline =~ /^\s+/) {  # indented line
                &$processref($line . $nextline);
            }
            else {
                &$processref($line);
                &$processref($nextline) if $nextline ne '';
            }
            $line = '';
        }
        elsif ($nextline eq '') {  # blank line
            &$processref($line);
            $line = '';
        }
        elsif ($nextline =~ /^\s+/) {  # indented line
            $nextline =~ s/^\s+/ /;
            $line .= $nextline;
        }
        else {  # non-indented line
            &$processref($line) unless $line eq '';
            $line = $nextline;
        }
    }
    &$processref($line) unless $line eq '';
}

sub process_one_line {
    my $line = shift @_;
    print "$line\n";
}

process_file_with_continuations \&process_one_line;
4

2 に答える 2

7

ファイル全体をメモリに丸呑みし、正規表現を使用して処理するのはどうですか。はるかに「パーリッシュ」。これはテストに合格し、はるかに小さくてきれいです。

#!/usr/bin/perl

use strict;
use warnings;

$/ = undef;             # we want no input record separator.
my $file = <>;          # slurp whole file

$file =~ s/^\n//;       # Remove newline at start of file
$file =~ s/\s+\n/\n/g;  # Remove trailing whitespace.
$file =~ s/\n\s*#[^\n]+//g;     # Remove comments.
$file =~ s/\n\s+/ /g;   # Merge continuations

# Done
print $file;
于 2009-06-17T08:07:33.587 に答える
3

ファイル全体をメモリにロードしてもかまわない場合は、以下のコードがテストに合格します。行を配列に格納し、各行を前の行（続き）または配列の最後（その他）に追加します。

#!/usr/bin/perl

use strict;
use warnings;

my @out;

while( <>)
  { chomp;
    s{#.*}{};             # suppress comments
    next unless( m{\S});  # skip blank lines
    if( s{^\s+}{ })       # does the line start with spaces?
      { $out[-1] .= $_; } # yes, continuation, add to last line
    else 
      { push @out, $_;  } # no, add as new line
  }

$, = "\n";                # set output field separator
$\ = "\n";                # set output record separator
print @out;
于 2009-06-17T08:56:39.913 に答える