2

列の単語の前半を取り、別の列に格納する必要があります。偶数個の単語があると仮定できます。カーソルと、文字列を取得し、区切り記号を使用してテーブルに解析することがわかった関数を使用してそれを行いました。

drop table #test
create table #test (id int identity, my_name varchar(128), cleaned_name varchar(128))

insert into #test (my_name) VALUES ('abcd efgh abcd1 efgh1')
insert into #test (my_name) VALUES ('name1 name2 name1a name2a')
insert into #test (my_name) VALUES ('one two one* two*')

select *
from #test


DECLARE @HalfName varchar(100)
DECLARE @i varchar(100)
set @i = 1
while @i <= (select count(*) from #test)
begin
      SELECT @HalfName = COALESCE(@HalfName + ' ', '') + aa.WORD
      FROM (select top (select count(*) / 2 from dm_generic.dbo.GETALLWORDS((select [my_name]
      from #test 
      where id = @i), ' ')) *
      from dm_generic.dbo.GETALLWORDS(
      (select [my_name]
      from #test 
      where id = @i), ' ') 
      ) aa

      update #test 
      set cleaned_name = @HalfName 
      where id = @i

      set @i = @i + 1
      set @HalfName = ''
end

select *
from #test

私はカーソルなしでそれをやろうとしています:

UPDATE bb
   SET cleaned_name =
          (SELECT COALESCE (bb.cleaned_name + ' ', '') + aa.WORD
             FROM (SELECT TOP (SELECT count (*) / 2
                                 FROM dm_generic.dbo.GETALLWORDS (
                                         (SELECT [my_name]
                                            FROM #test a
                                           WHERE a.id = bb.id),
                                         ' '))
                          *
                     FROM dm_generic.dbo.GETALLWORDS ( (SELECT [my_name]
                                                          FROM #test b
                                                         WHERE b.id = bb.id),
                                                      ' ')) aa)
  FROM #test bb

私が得ているのは：

Msg 512, Level 16, State 1, Line 1
Subquery returned more than 1 value. This is not permitted when the subquery follows =, !=, <, <= , >, >= or when the subquery is used as an expression.
The statement has been terminated.

どんな助けでも大歓迎です。

すべてのレスポンダーのおかげで、私は最終的に@BradC によるこのソリューションを使用して自分自身を醸造しました。

update updated
set cleaned_name = (
SELECT Clean
FROM #test AS extern
CROSS APPLY
( 
select TOP (SELECT count (*) / 2 
            FROM dm_generic.dbo.GETALLWORDS (
                                           (SELECT [my_name]
                                            FROM #test a
                                            WHERE a.id = extern.id), ' '))
WORD + ' '
FROM dm_generic.dbo.GETALLWORDS (
         (SELECT [my_name]
            FROM #test a
           WHERE a.id = extern.id),
         ' ')
    FOR XML PATH('')
) pre_trimmed (Clean)
where extern.id = updated.id)
from #test updated

@Nikola Markovinović ソリューションもうまく機能します。

4

2 に答える 2

1

ローカル変数の連結トリックはローカル変数なしでは機能しません-@HalfNameを使用してGETALLWORDSからの単語を連結していますが、列名（この場合はcleaned_name）を使用して機能しません。それを機能させるには、xmlパス連結トリックに使用する必要があります。

したがって、SQL Server 2005以降を使用している場合は、次のことを試してください。

UPDATE bb
   SET cleaned_name =
      (SELECT stuff ((SELECT TOP (SELECT count (*) / 2 
                                   FROM dm_generic.dbo.GETALLWORDS (
                                         (SELECT [my_name]
                                            FROM #test a
                                           WHERE a.id = bb.id),
                                         ' ')
                                  )
                             ' ' + aa.my_name
                        FROM dm_generic.dbo.GETALLWORDS (
                                         (SELECT [my_name]
                                            FROM #test a
                                           WHERE a.id = bb.id),
                                         ' ') aa 
                         FOR XML PATH(''),TYPE).value('(./text())[1]','VARCHAR(MAX)')
                     , 1, 1, '')
      )
  FROM #test bb

免責事項：私はこれをテストすることはできません。最初にUDFのみで試してから、クエリに組み込んでください。

更新：括弧を置き忘れました-最後の行の最初の閉じ括弧を削除し、最後の括弧の後に1つ追加する必要があります。

于 2012-04-10T09:56:11.513 に答える
0

以下の関数を作成する

ALTER FUNCTION [dbo].[halfWords]
    (
      @InputString VARCHAR(4000)
    )
RETURNS VARCHAR(4000)
AS BEGIN

    DECLARE @Index INT
    DECLARE @Char CHAR(1)
    DECLARE @PrevChar CHAR(1)
    DECLARE @WordCount INT
    DECLARE @WordCount2 INT
    DECLARE @firstHalf varchar(4000)

    SET @Index = 1
    SET @WordCount = 0

    WHILE @Index <= LEN(@InputString)
        BEGIN
            SET @Char = SUBSTRING(@InputString, @Index, 1)
            SET @PrevChar = CASE WHEN @Index = 1 THEN ' '
                                 ELSE SUBSTRING(@InputString, @Index - 1, 1)
                            END

            IF @PrevChar = ' '
                AND @Char != ' ' 
                SET @WordCount = @WordCount + 1

            SET @Index = @Index + 1
            SET @wordcount2 = ( @wordcount / 2 )
        END


    SET @wordcount = 0 
    SET @Index = 1
    WHILE @Index <= LEN(@InputString)
        BEGIN
            SET @Char = SUBSTRING(@InputString, @Index, 1)
            SET @PrevChar = CASE WHEN @Index = 1 THEN ' '
                                 ELSE SUBSTRING(@InputString, @Index - 1, 1)
                            END

            IF @PrevChar = ' '
                AND @Char != ' ' 
                SET @WordCount = @WordCount + 1


            IF ( @wordcount2 = @WordCount ) 
                BEGIN
                    SET @firstHalf = SUBSTRING(@InputString, 0, @Index) 

                END
            SET @Index = @Index + 1

        END
    RETURN @firstHalf
   END

次に、以下の更新クエリで使用します

  UPDATE    #test
  SET       cleaned_name = dbo.[halfWords] (my_name)

参照用のクエリを選択

SELECT dbo.halfWords ('one two three four five six seven eight')

戻ります

one two three four
于 2012-04-10T11:18:03.023 に答える