2

Active Directoryから情報を取得し、Microsoft OutlookforMacで新しい署名を作成するスクリプトを作成しました。

次のコードを使用して署名を作成します（実際には関係がないため、他のコードは省略します）。

tell application "Microsoft Outlook"

    make new signature with properties {name:strName, content:contentHTML, plain text content:"", include in random:false}

end tell

ここで、strNameは他の場所から取得した署名の名前であり、contentHTMLは他の場所で作成したHTMLの実際の署名です。

この署名をMicrosoftOutlookに追加することは完全に機能していますが、作成した署名を現在のアカウントのデフォルトの署名に設定する方法がわかりません。私はまったく役に立たなかったかなり多くの研究をしました、そして私は辞書も調べました。

4

1 に答える 1

3

これはAppleScriptで行うことができます。Outlook 2011ディクショナリには、これを具体的に行うものは何もないため、代わりにUI要素をスクリプト化することでこれを行うことができますが、これは確かにかなり不格好です。

署名はアカウントごとに設定されるため、このスクリプトにアカウントの名前と、そのアカウントに設定する署名の名前を指定する必要があります。

setDefaultSignature to "strName" for "Gmail"

on setDefaultSignature to mySignature for accountName
  tell application "Microsoft Outlook" to activate
  tell application "System Events"
    -- turn on UI automation - may throw a permissions dialog
    if UI elements enabled is false then set UI elements enabled to true

    click menu item "Preferences..." of menu 1 of menu bar item "Outlook" of menu bar 1 of application process "Outlook"
    click item 1 of (buttons of window "Outlook Preferences" of application process "Outlook" whose description is "Signatures")
    click button "Default Signatures..." of window "Signatures" of application process "Outlook"

    repeat with thisRow in rows of table 1 of scroll area 1 of sheet 1 of window "Signatures" of application process "Outlook"
      if value of text field of thisRow as string is accountName then
        click pop up button 1 of thisRow
        click menu item mySignature of menu 1 of pop up button 1 of thisRow
        click button "OK" of sheet 1 of window "Signatures" of application process "Outlook"
        click item 1 of (buttons of window "Signatures" of application process "Outlook" whose description is "close button")
        exit repeat
      end if
    end repeat
  end tell
end setDefaultSignature
于 2013-02-27T05:47:30.003 に答える