emacs - パッケージ名のリストを指定してEmacsパッケージを自動的にインストールする方法は？

Question

私はpackageEmacs拡張機能を管理するために使用しています。.emacs異なるコンピューターでEmacs設定を同期するために、ファイル内のパッケージ名のリストを指定し、パッケージpackageを自動的に検索してインストールできるようにしたいので、を呼び出して手動でインストールする必要はありませんM-x package-list-packages。どうやってするか？

Answer 1

; list the packages you want
(setq package-list '(package1 package2))

; list the repositories containing them
(setq package-archives '(("elpa" . "http://tromey.com/elpa/")
                         ("gnu" . "http://elpa.gnu.org/packages/")
                         ("marmalade" . "http://marmalade-repo.org/packages/")))

; activate all the packages (in particular autoloads)
(package-initialize)

; fetch the list of packages available 
(unless package-archive-contents
  (package-refresh-contents))

; install the missing packages
(dolist (package package-list)
  (unless (package-installed-p package)
    (package-install package)))

Answer 2

Profpatsch のコメントと以下の回答に基づいています。

(defun ensure-package-installed (&rest packages)
  "Assure every package is installed, ask for installation if it’s not.

Return a list of installed packages or nil for every skipped package."
  (mapcar
   (lambda (package)
     ;; (package-installed-p 'evil)
     (if (package-installed-p package)
         nil
       (if (y-or-n-p (format "Package %s is missing. Install it? " package))
           (package-install package)
         package)))
   packages))

;; make sure to have downloaded archive description.
;; Or use package-archive-contents as suggested by Nicolas Dudebout
(or (file-exists-p package-user-dir)
    (package-refresh-contents))

(ensure-package-installed 'iedit 'magit) ;  --> (nil nil) if iedit and magit are already installed

;; activate installed packages
(package-initialize)

Answer 3

Emacs Preludeに使用するコードは次のとおりです。

(require 'package)
(require 'melpa)
(add-to-list 'package-archives
             '("melpa" . "http://melpa.milkbox.net/packages/") t)
(package-initialize)

(setq url-http-attempt-keepalives nil)

(defvar prelude-packages
  '(ack-and-a-half auctex clojure-mode coffee-mode deft expand-region
                   gist haml-mode haskell-mode helm helm-projectile inf-ruby
                   magit magithub markdown-mode paredit projectile
                   python sass-mode rainbow-mode scss-mode solarized-theme
                   volatile-highlights yaml-mode yari yasnippet zenburn-theme)
  "A list of packages to ensure are installed at launch.")

(defun prelude-packages-installed-p ()
  (loop for p in prelude-packages
        when (not (package-installed-p p)) do (return nil)
        finally (return t)))

(unless (prelude-packages-installed-p)
  ;; check for new packages (package versions)
  (message "%s" "Emacs Prelude is now refreshing its package database...")
  (package-refresh-contents)
  (message "%s" " done.")
  ;; install the missing packages
  (dolist (p prelude-packages)
    (when (not (package-installed-p p))
      (package-install p))))

(provide 'prelude-packages)

MELPA を使用していない場合は、必要ありません (必要な場合は、MELPA を使用melpa.elしてload-path(または MELPA 経由でインストールする必要があります)。パッケージ db は毎回更新されません (起動が大幅に遅くなるため)。 ) - アンインストールされたパッケージが存在する場合のみ。

Answer 4

Caskについてはまだ誰も言及していませんが、このタスクには非常に適しています。

基本的に~/.emacs.d/Cask、インストールしたいパッケージのリストを作成します。例えば：

(source melpa)
(depends-on "expand-region")
(depends-on "goto-last-change")
; ... etc

コマンドラインから実行caskすると、これらのパッケージと必要な依存関係がインストールされます。

また、 を使用して、インストール済みのパッケージを自動的に更新することもできますcask update。

Answer 5

package-installパッケージ名をシンボルとして呼び出します。package-install対話的に呼び出して名前を入力すると、パッケージのパッケージ名を見つけることができます。この関数package-installed-pは、既にインストールされているかどうかを知らせます。

例えば：

(mapc
 (lambda (package)
   (or (package-installed-p package)
       (package-install package)))
 '(package1 package2 package3))

Answer 6

この回答で行ったように、ユーザーが最初にパッケージをインストールするかどうかを確認するのが好きです。また、何かをインストールする前に、パッケージの内容を一度更新しています。これが最善の方法かどうかはわかりませんが、上位の回答が私のためにそれを行っていたとは思いません。

(setq required-pkgs '(jedi flycheck cider clojure-mode paredit markdown-mode jsx-mode company))

(require 'cl)

(setq pkgs-to-install
      (let ((uninstalled-pkgs (remove-if 'package-installed-p required-pkgs)))
        (remove-if-not '(lambda (pkg) (y-or-n-p (format "Package %s is missing. Install it? " pkg))) uninstalled-pkgs)))

(when (> (length pkgs-to-install) 0)
  (package-refresh-contents)
  (dolist (pkg pkgs-to-install)
    (package-install pkg)))

Answer 7

(package-install 'org)に追加しても何も起こらないという問題に遭遇しました.emacs。の最新バージョンをインストールしたかったのですがorg-mode、組み込みorg-modeがかなり古いです。

package-installEmacs 25.3.1のソースコードを掘り出しました。関数 self は、パッケージがインストールされているかどうかを既にチェックしており、パッケージが既にインストールされている場合はインストールを拒否します。したがって、(unless (package-installed-p package) ...)回答10093312からのチェックは、実際には不要です。

(defun package-install (pkg &optional dont-select)
  "Install the package PKG.
PKG can be a package-desc or a symbol naming one of the available packages
in an archive in `package-archives'.  Interactively, prompt for its name.

If called interactively or if DONT-SELECT nil, add PKG to
`package-selected-packages'.

If PKG is a package-desc and it is already installed, don't try
to install it but still mark it as selected."
  (interactive
   (progn
     ;; Initialize the package system to get the list of package
     ;; symbols for completion.
     (unless package--initialized
       (package-initialize t))
     (unless package-archive-contents
       (package-refresh-contents))
     (list (intern (completing-read
                    "Install package: "
                    (delq nil
                          (mapcar (lambda (elt)
                                    (unless (package-installed-p (car elt))
                                      (symbol-name (car elt))))
                                  package-archive-contents))
                    nil t))
           nil)))
  (add-hook 'post-command-hook #'package-menu--post-refresh)
  (let ((name (if (package-desc-p pkg)
                  (package-desc-name pkg)
                pkg)))
    (unless (or dont-select (package--user-selected-p name))
      (package--save-selected-packages
       (cons name package-selected-packages)))
    (if-let ((transaction
              (if (package-desc-p pkg)
                  (unless (package-installed-p pkg)
                    (package-compute-transaction (list pkg)
                                                 (package-desc-reqs pkg)))
                (package-compute-transaction () (list (list pkg))))))
        (package-download-transaction transaction)
      (message "`%s' is already installed" name))))

ビルトインorg-modeもインストール済みとしてカウントされ、package-installELPA からの新しいバージョンのインストールを拒否します。package.el を読むのに時間を費やした後、次の解決策を思いつきました。

(dolist (package (package-compute-transaction
                  () (list (list 'python '(0 25 1))
                           (list 'org '(20171211)))))
  ;; package-download-transaction may be more suitable here and
  ;; I don't have time to check it
  (package-install package))

これが機能する理由は、package-*ファミリ関数がシンボルかpackage-descオブジェクトかによって引数の扱いが異なるためです。package-installオブジェクト経由でのみバージョン情報を指定できpackage-descます。

Answer 8

ここに別の方法があります。

;; assure every package is installed
(defun ensure-package-installed (&rest packages)
  (let ((user-required-packages
         (seq-remove
          (lambda (package) (package-installed-p package))
          packages)))
    (when user-required-packages
      (package-refresh-contents)
      (dolist (package user-required-packages)
        (package-install package)))))

;; list of packages to install
(ensure-package-installed
 'try
 'which-key)