0

ColdBox 3.5 と ColdFusion 10 ORM を使用してブログ アプリケーションを作成していますが、ランダムに次のエラー メッセージが表示されます。

エラータイプ: アプリケーション: [N/A]

エラー メッセージ: Hibernate 操作で例外が発生しました。更新または削除された行が存在しないか、セッションに古いデータが含まれていました。

根本原因:org.hibernate.StaleObjectStateException: 行が別のトランザクションによって更新または削除されました (または、保存されていない値のマッピングが正しくありません): [Entry#297e1bfa369cf17501369d26ffae00a4]

/model/entry/Entry.cfc :

component
    persistent="true"
    table="Entry"
    output="false"
{
    // primary key
    property name="entryID" fieldtype="id" ormtype="string" type="string" length="32" generator="uuid";

    // properties
    property name="title" fieldtype="column" ormtype="string" type="string" length="100" notnull="true";
    property name="alias" fieldtype="column" ormtype="string" type="string" length="100" notnull="true";
    property name="body" fieldtype="column" ormtype="string" type="string" sqltype="nvarchar(max)" notnull="true";
    property name="allowComments" fieldtype="column" ormtype="boolean" type="boolean" sqltype="bit" dbdefault="1" default="true" notnull="true";
    property name="released" fieldtype="column" ormtype="boolean" type="boolean" sqltype="bit" dbdefault="1" default="true" notnull="true";
    property name="releasedDate" fieldtype="column" ormtype="timestamp" type="date";
    property name="addDate" fieldtype="timestamp" ormtype="timestamp" type="date";

    // relations
    property name="categories" fieldtype="many-to-many" cfc="model.category.Category" linktable="EntryCategory" fkcolumn="entryID" inversejoincolumn="categoryID" singularname="category" cascade="all" lazy="true";
    property name="comments" fieldtype="one-to-many" cfc="model.entryComment.EntryComment" fkcolumn="entryID" singularname="comment" cascade="all-delete-orphan";
    property name="user" fieldtype="many-to-one" cfc="model.user.User" fkcolumn="userID" notnull="true" cascade="save-update";
    property name="views" fieldtype="one-to-many" cfc="model.entryView.EntryView" fkcolumn="entryID" singularname="view" cascade="all-delete-orphan";

    // validation
    this.constraints = {
        "title" = {"required" = true},
        "body" = {"required" = true},
        "allowComments" = {"required" = true, type="boolean"},
        "released" = {"required" = true, type="boolean"},
        "categories" = {size=1},
        "user" = {type="component"}
    };
}

/model/category/Category.cfc :

component
    persistent="true"
    table="Category"
    schema="system"
    output="false"
{
    // primary key
    property name="categoryID" fieldtype="id" ormtype="string" type="string" length="32" generator="uuid";

    // properties
    property name="name" fieldtype="column" ormtype="string" type="string" length="50" notnull="true";
    property name="alias" fieldtype="column" ormtype="string" type="string" length="50" notnull="true";
    property name="description" fieldtype="column" ormtype="string" type="string" default="" length="200";
    property name="addDate" fieldtype="timestamp" ormtype="timestamp" type="date";
    property name="active" fieldtype="column" ormtype="boolean" type="boolean" sqltype="bit" dbdefault="1" default="true" notnull="true";

    // relations
    property name="entries" fieldtype="many-to-many" cfc="model.entry.Entry" linktable="EntryCategory" fkcolumn="categoryID" inversejoincolumn="entryID" lazy="true" cascade="all" singularname="entry" inverse="true";

    // validation
    this.constraints = {
        "name" = {"required" = true},
        "active" = {"required" = true, type="boolean"}
    };
}

私が実行しているコードは次のとおりです。

<cfscript>
    entry = entityNew("Entry", {
        "title" = "test",
        "body" = "test",
        "alias" = "test",
        "allowComments" = 0,
        "released" = 0,
        "user" = entityLoadByPK("User", "297e1bfa3697d377013697f53ca10084")
    });

    // works 1 out of 5 times
    entry.setCategories([entityLoadByPK("Category", "297e1bfa36986e69013698c3e54f000d")]);

    // works every time
    //entry.setCategories(entityLoad("Category", "297e1bfa36986e69013698c3e54f000d"));
    //entry.setCategories(entityLoad("Category"));

    entitySave(entry);
    ormFlush();
</cfscript>

「5 回中 1 回動作する」および「毎回動作する」というラベルの付いたセクションに注意してください。私は自分が間違っていることを理解していません。リンクされたテーブルを使用するこれらに似た他のオブジェクトがあり、同様のエラーメッセージが表示されます。SQL ログを確認しました。EntryCategoryテーブルに挿入する準備ができたときにエラーが発生したようです。何か案は？

4

1 に答える 1

0

HQL を使用し、(?) で where ID を使用します。それは非常にうまく機能します。

エンティティに既に配列がある場合は、最初に ArrayClear() を使用します。

アップデート：

categories = ormExecuteQuery("from Category where Id IN (:Ids)",
                             {Ids=listToArray(FORM.categoryIDs)});
entry.setCategories(categories);
于 2012-04-10T18:20:48.293 に答える