4

1つのトランザクションで2つTVarの異なるをアトミックに更新できますか？つまりTVar、競合を減らすために、多数のデータ構造からデータ構造を構成できますか？もしそうなら、あなたは例を提供できますか？

4

2 に答える 2

8

1 つのトランザクションで 2 つの異なる TVar をアトミックに更新できますか?

はい、1 回のトランザクションで複数の TVar をアトミックに更新できます。それが STM の要点のようなものです。できなければあまり役に立ちません。

競合を減らすために、多数の TVar からデータ構造を構成できますか? もしそうなら、例を挙げていただけますか？

TVar をデータ構造に格納する (ややばかげた) 例を次に示します。これは、銀行内の口座間のランダムな同時トランザクションの束をシミュレートしますTVar Integer。アカウント TVar は、アカウント ID からのマップに保持されます。これは、新しいアカウントをその場で作成できるように、それ自体が TVar に保持されます。

import Control.Concurrent
import Control.Concurrent.MVar
import Control.Concurrent.STM
import Control.Monad
import System.Random

import qualified Data.Map as Map

type AccountId = Int
type Account = TVar Dollars
type Dollars = Integer
type Bank = TVar (Map.Map AccountId Account)

numberOfAccounts = 20
threads = 100
transactionsPerThread = 100
maxAmount = 1000

-- Get account by ID, create new empty account if it didn't exist
getAccount :: Bank -> AccountId -> STM Account
getAccount bank accountId = do
  accounts <- readTVar bank
  case Map.lookup accountId accounts of
    Just account -> return account
    Nothing -> do
      account <- newTVar 0
      writeTVar bank $ Map.insert accountId account accounts
      return account

-- Transfer amount between two accounts (accounts can go negative)
transfer :: Dollars -> Account -> Account -> STM ()
transfer amount from to = when (from /= to) $ do
  balanceFrom <- readTVar from
  balanceTo <- readTVar to
  writeTVar from $! balanceFrom - amount
  writeTVar to $! balanceTo + amount

randomTransaction :: Bank -> IO ()
randomTransaction bank = do
  -- Make a random transaction
  fromId <- randomRIO (1, numberOfAccounts)
  toId   <- randomRIO (1, numberOfAccounts)
  amount <- randomRIO (1, maxAmount)

  -- Perform it atomically
  atomically $ do
    from <- getAccount bank fromId
    to   <- getAccount bank toId
    transfer amount from to

main = do
  bank <- newTVarIO Map.empty

  -- Start some worker threads to each do a number of random transactions
  workers <- replicateM threads $ do
    done <- newEmptyMVar
    forkIO $ do
      replicateM_ transactionsPerThread $ randomTransaction bank
      putMVar done ()
    return done

  -- Wait for worker threads to finish
  mapM_ takeMVar workers

  -- Print list of accounts and total bank balance (which should be zero)
  summary <- atomically $ do
    accounts <- readTVar bank
    forM (Map.assocs accounts) $ \(accountId, account) -> do
      balance <- readTVar account
      return (accountId, balance)

  mapM_ print summary
  putStrLn "----------------"
  putStrLn $ "TOTAL BALANCE: " ++ show (sum $ map snd summary)

転送中に競合状態が発生しなかった場合、これにより、最後に合計残高がゼロになるはずです。

于 2012-04-11T05:48:21.727 に答える
7

トランザクションは完全にアトミックです。複数TVarの を変更すると、両方の変更が一緒に、アトミックに、分離して発生します。atomically単一のブロックで実行されるものはすべて、単一のトランザクションです。例えば：

swap :: (Num a) => TVar a -> TVar a -> STM ()
swap v1 v2 = do
    a <- readTVar v1
    b <- readTVar v2
    writeTVar v1 b
    writeTVar v2 a

ここでswap a bは、アトミックに 2 つTVarの を交換します。このようなアトミック トランザクションの構成可能性は、STM の主な利点の 1 つです。

于 2012-04-11T05:21:16.857 に答える