ms-access - VBA コードファイルを検索する方法

Question

以前の開発者が多くの自動化されたタスクを作成した新しい会社で仕事を始めたばかりです。もちろん、事実上ドキュメントはなく、以前の開発者と一緒に仕事をする機会もありませんでした。そのため、これらすべてのプロセスをふるいにかけ、いくつかの特定のファイルを変更するプロセスを探しています。

すべてのストアドプロシージャを SQL でスクリプト化し、検索ツールを使用しましたが、探しているものが見つかりませんでした。そのため、必要なプロセスが、使用されている多くの Access データベースの 1 つにあるかどうか疑問に思っています。SQL Server では、C# アプリを記述して proc をスクリプト化し、それらを検索できるようにするのは簡単でしたが、Access では、各データベースを個別に開いてコードファイルを検索する必要があるようです。

プログラムで VBA コードファイルを検索する方法はありますか?

score 16 · Accepted Answer

Access データベースファイル内のコードモジュールの検索に関心がある場合は、VBE オブジェクトモデルを使用できます。ActiveVBProjectこのサンプルは、現在のデータベースのすべてのモジュールで単語を検索します。データベースに複数の VBProject が含まれている場合は、VBProjects コレクションを列挙し、プロジェクトを一度に 1 つずつ名前で検索できます。

For Each objComponent In Application.VBE.VBProjects(ProjName).VBComponents

または、プロジェクトを名前ではなく番号で参照したい場合は、番号が 0 ではなく 1 から始まることに注意してください。

Public Sub findWordInModules(ByVal pSearchWord As String)
    'Dim objComponent As VBComponent
    ' VBComponent requires reference to Microsoft Visual Basic
    ' for Applications Extensibility; use late binding instead:
    Dim objComponent As Object
    Dim strMessage As String
    Dim strModuleList As String

    strModuleList = vbNullString
    For Each objComponent In Application.VBE.ActiveVBProject.VBComponents
        If objComponent.CodeModule.Find(pSearchWord, 1, 1, -1, -1) = True Then
            strModuleList = strModuleList & "; " & objComponent.Name
        End If
    Next objComponent
    strMessage = "Text '" & pSearchWord & "' found in "
    If Len(strModuleList) > 0 Then
        strMessage = strMessage & "modules: " & Mid(strModuleList, 3)
    Else
        strMessage = strMessage & "no modules"
    End If
    Debug.Print strMessage
End Sub

Findその方法の Access ヘルプトピックを確認します。私が使用したものとは異なるオプションを好むかもしれません。

複数の db ファイルをターゲットにして、それぞれのモジュールを検索する場合は、メソッドを使用してこれを自動化できますOpenDatabase。その部分の詳細はお任せします。