xml - xsltの操作として文字列を評価する方法はありますか？

Question

文字列変数の内容を操作として評価したい。

私の変数それはこの文字列です：1 + 1 + 0

操作を行い、値2を取得したいと思います。

よろしくお願いします、グスタボ

Answer 1

XSLT 1.0 または XSLT 2.0 には、文字列値として提供された XPath 式を評価するための一般的なメカニズムはありません。多くの製品には、これを行うための拡張機能があります (たとえば、saxon:evaluate() を参照)。XSLT 3.0 では、xsl:evaluate 命令という一般的なメカニズムが導入されています。

Answer 2

XSLT 2.0 では、以下の例のように、関数と関数を使用してこれを行うことがtokenize()できnumber()ますsum()。+記号を囲む可能性のある空白を含めたことに注意してください。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:variable name="test1">1+1+0</xsl:variable>
    <xsl:variable name="test2"> 3 + 
    5   +           12 </xsl:variable>

    <xsl:template match="/">
        <xsl:variable name="testSplit1" select="tokenize($test1,'\s*\+\s*')"/>
        <xsl:variable name="testSplitNum1">
            <xsl:for-each select="$testSplit1">
                <item><xsl:value-of select="number(.)"/></item>
            </xsl:for-each>
        </xsl:variable>

        <xsl:variable name="testSplit2" select="tokenize($test2,'\s*\+\s*')"/>
        <xsl:variable name="testSplitNum2">
            <xsl:for-each select="$testSplit2">
                <item><xsl:value-of select="number(.)"/></item>
            </xsl:for-each>
        </xsl:variable>

        <root>
            <items1><xsl:copy-of select="$testSplitNum1"/></items1>
            <sum1><xsl:value-of select="sum($testSplitNum1/item)"/></sum1>
            <items2><xsl:copy-of select="$testSplitNum2"/></items2>
            <sum2><xsl:value-of select="sum($testSplitNum2/item)"/></sum2>
        </root>

    </xsl:template>

</xsl:stylesheet>

結果（ダミー入力ファイル付き）は

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <items1>
        <item>1</item>
        <item>1</item>
        <item>0</item>
    </items1>
    <sum1>2</sum1>
    <items2>
        <item>3</item>
        <item>5</item>
        <item>12</item>
    </items2>
    <sum2>20</sum2>
</root>