3

新しいインスタンスを作成するのではなく、プログラムで IE ( iexplore.exe) を起動し、(新しいタブを開くか、現在の URL を置き換えることによって) 現在実行中のインスタンスに移動する方法。

コマンド ライン スイッチを検索し、 を使用してみInternetExplorer.Applicationましたが、役に立ちませんでした。

ここに私が必要とするものの擬似があります（IE6-IE9がいいでしょう）：

ShellExecute(Handle, 'open', 'iexplore.exe',
    '"http://google.com" -single_instance',
    nil, SW_RESTORE);

これが私の試みを示すためのコードです。Delphi のコード (一部HWND から IHTMLDocument2 を取得する方法に基づく):

implementation

uses ShellApi, ComObj, ActiveX, SHDocVw, MSHTML;        

function GetIEFromHWND(WHandle: HWND; var IE: IWebbrowser2): Boolean;
type
  TObjectFromLResult = function(LRESULT: lResult; const IID: TIID;
    wParam: WPARAM; out pObject): HRESULT; stdcall;
var
  hInst: HMODULE;
  lRes: Cardinal;
  Msg: UINT;
  pDoc: IHTMLDocument2;
  ObjectFromLresult: TObjectFromLresult;
begin
  Result := False;
  hInst := LoadLibrary('oleacc.dll');
  if hInst <> 0 then
  try
    @ObjectFromLresult := GetProcAddress(hInst, 'ObjectFromLresult');
    if @ObjectFromLresult <> nil then
    begin
      Msg := RegisterWindowMessage('WM_HTML_GETOBJECT');
      if SendMessageTimeOut(WHandle, Msg, 0, 0, SMTO_ABORTIFHUNG, 1000, lRes) <> 0 then
        if ObjectFromLresult(lRes, IHTMLDocument2, 0, pDoc) = S_OK then
        begin
          (pDoc.parentWindow as IServiceprovider).QueryService(
            IWebbrowserApp, IWebbrowser2, IE);
          Result := IE <> nil;
        end;
      end;
  finally
    FreeLibrary(hInst);
  end;
end;

function GetActiveIEServerWindow(const Activate: Boolean=True): HWND;
var
  Wnd, WndChild: HWND;
begin
  Result := 0;
  Wnd := FindWindow('IEFrame', nil); // top level IE
  if Wnd <> 0 then
  begin
    WndChild := FindWindowEx(Wnd, 0, 'Shell DocObject View', nil);
    if WndChild <> 0 then
    begin
      WndChild := FindWindowEx(WndChild, 0, 'Internet Explorer_Server', nil);
      if WndChild <> 0 then
      begin
        Result := WndChild;
        if Activate then
        begin
          if IsIconic(Wnd) then
            ShowWindow(Wnd, SW_RESTORE)
          else
            SetForegroundWindow(Wnd);
        end;
      end;
    end;
  end;
end;

// Method 1
procedure TForm1.Button1Click(Sender: TObject);
const
  navOpenInNewTab = $800;
var
  IEServerWnd: HWND;
  IE: IWebBrowser2;
begin
  IEServerWnd := GetActiveIEServerWindow;
  if (IEServerWnd <> 0) and GetIEFromHWnd(IEServerWnd, IE) then
  begin
    // *** this opens the Default browser, e.g Google Chrome 
    // *** if IE is the Default browser, an empty new window is opened.
    OleVariant(IE).Navigate('http://www.yahoo.com', Longint(navOpenInNewTab));
  end
  else
  begin
    ShellExecute(Handle, 'open', 'iexplore.exe',
    '"http://google.com"',
    nil, SW_RESTORE);
  end;
end;

procedure InternetExplorerNavigate(URL: WideString);
const
  navOpenInNewTab = $800;
var
  IE: OleVariant;
begin
  try
    // *** this always fails (security constraints?)
    IE := GetActiveOleObject('InternetExplorer.Application');
  except
    IE := CreateOleObject('InternetExplorer.Application');
  end;
  IE.Visible := True;
  IE.Navigate(URL, Longint(navOpenInNewTab));
end;

// Method 2
procedure TForm1.Button2Click(Sender: TObject);
begin
  InternetExplorerNavigate('http://google.com');
end;
4

1 に答える 1

4

あなたの方法「1」は実際に機能します。少なくともここでの問題は、'Shell DocObject View' ウィンドウが最上位の IE ウィンドウの直接の子ではないことです。ここで IE8 では、「Internet Explorer_Server」ウィンドウは、「Frame Tab」の子である「TabWindowClass」の子である「Shell DocObject View」の子です。方法 1 で 'FindWindowEx' が 0 を返すことを確認できれば、それが失敗の理由です。以下は、使用するように変更されたコードですEnumChildWindows。

function EnumChilds(hwnd: HWND; lParam: LPARAM): BOOL; stdcall;
const
  Server = 'Internet Explorer_Server';
var
  ClassName: array[0..24] of Char;
begin
  GetClassName(hwnd, ClassName, Length(ClassName));
  Result := ClassName <> Server;
  if not Result then
    PLongWord(lParam)^ := hwnd;
end;

function GetActiveIEServerWindow(const Activate: Boolean=True): HWND;
var
  Wnd, WndChild: HWND;
begin
  Result := 0;
  Wnd := FindWindow('IEFrame', nil); // top level IE
  if Wnd <> 0 then
  begin

//    WndChild := FindWindowEx(Wnd, 0, 'Shell DocObject View', nil);
//    if WndChild <> 0 then
//    begin
//      WndChild := FindWindowEx(WndChild, 0, 'Internet Explorer_Server', nil);

    WndChild := 0;
    EnumChildWindows(Wnd, @EnumChilds, LongWord(@WndChild));

    if WndChild <> 0 then
    begin
      Result := WndChild;
      if Activate then
      begin
        if IsIconic(Wnd) then
          ShowWindow(Wnd, SW_RESTORE)
        else
          SetForegroundWindow(Wnd);
      end;
    end;
//    end;
  end;
end;

メソッド '2' に関しては、IE がそのアクティブなオブジェクトの参照を返すことをサポートしていないという Web 上のリンクをいくつか見ましたが、それに関する公式の参照はありません。

于 2012-04-14T14:50:38.570 に答える