1

20個の値を含む配列（「origA」など）と別の配列（値が1つしかない「itemA」など）があります。 「origA」の10個のランダム値を「itemA」にプッシュする必要があります。しかし、できませんすでに「itemA」にプッシュされているのと同じ値をプッシュします。

どうすればこれを行うことができますか？

4

3 に答える 3

3

のコピーを作成し、origA追加したアイテムをそこから削除できitemAます。

最適化されていないバージョン:

var origA:Array = [1, 2, 3, 4, 5, 6, 7];
var itemA:Array = [0];

var copyA:Array = origA.concat();
var N:int = 10;
var n:int = Math.min(N, copyA.length);

for (var i:int = 0; i < n; i++) {
    // Get random value
    var index:int = Math.floor(Math.random() * copyA.length);
    var value:int = copyA[index];
    // Remove the selected value from copyA
    copyA.splice(index, 1);
    // Add the selected value to itemA
    itemA.push(value);
}

trace(itemA);
//0,1,7,2,6,4,3,5

最適化されたバージョン ( length、indexOf、spliceまたはpushループ内での呼び出しなし):

var origA:Array = [1, 2, 3, 4, 5, 6, 7];
var itemA:Array = [0];

var copyA:Array = origA.concat();
var copyALength:int = copyA.length;
var itemALength:int = itemA.length;
var N:int = 10;
var n:int = Math.min(N, copyALength);
for (var i:int = 0; i < n; i++) {
    // Get random value
    var index:int = Math.floor(Math.random() * copyALength);
    var value:int = copyA[index];
    // Remove the selected value from copyA
    copyA[index] = copyA[--copyALength];
    // Add the selected value to itemA
    itemA[itemALength++] = value;
}

trace(itemA);
//0,2,5,7,4,1,3,6

Edit1:元の配列にいくつかのアイテムしかない場合は、最初のバージョンまたは他の回答の他のソリューションを使用してください。ただし、数千以上のアイテムがある場合は、最適化されたバージョンを使用することをお勧めします.

編集：21,000アイテムを含む配列からランダムに選択されたアイテムをコピーするのにかかる時間は次の1,000,000とおりです。

  • 他のすべてのバージョン:2000ms
  • 最適化されたバージョン:12ms
  • 元の配列を複製せずに最適化されたバージョン:1ms
于 2012-04-16T07:14:14.430 に答える
2

これが本当に短いものです。MAXに達するまで元の配列からランダムなアイテムを削除してから、ターゲットの配列に連結します。

const MAX:int = 10;
var orig:Array = [0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20];
var target:Array = [];
var tmp:Array = [];
var i : int = -1;
var len : int = orig.length;
while (++i < MAX && len > 0) {
    var index:int = int( Math.random()*len );
    tmp[i] = orig[index];
    orig[index] = orig[--len];
}
target = target.concat(tmp);

編集

アイテムを削除する@schの方法を採用しました。受け入れられるべきは彼の答えです。これをwhileループのために保持しました。

于 2012-04-16T07:31:15.630 に答える
2 
// Define how many random numbers are required.
const REQUIRED:int = 10;

// Loop until either the original array runs out of numbers,
// or the destination array reaches the required length.
while(origA.length > 0 && itemA.length < REQUIRED)
{
    // Decide on a random index and pull the value from there.
    var i:int = Math.random() * origA.length;
    var r:Number = origA[i];

    // Add the value to the destination array if it does not exist yet.
    if(itemA.indexOf(r) == -1)
    {
        itemA.push(r);
    }

    // Remove the value we looked at this iteration.
    origA.splice(i, 1);
}
于 2012-04-16T06:57:59.580 に答える