7

この質問に答えたいと思います

Perl の派手な書式設定とハッシュ データへのキー付きアクセスをすべて取得するには、(これのより良いバージョンの) 関数が必要です。

# sprintfx(FORMAT, HASHREF) - like sprintf(FORMAT, LIST) but accepts
# "%<key>$<tail>" instead of "%<index>$<tail>" in FORMAT to access the
# values of HASHREF according to <key>. Fancy formatting is done by
# passing '%<tail>', <corresponding value> to sprintf.
sub sprintfx {
  my ($f, $rh) = @_;
  $f =~ s/
     (%%)               # $1: '%%' for '%'
     |                  # OR
     %                  # start format
     (\w+)              # $2: a key to access the HASHREF
     \$                 # end key/index
     (                  # $3: a valid FORMAT tail
                        #   'everything' upto the type letter
        [^BDEFGOUXbcdefginosux]*
                        #   the type letter ('p' removed; no 'next' pos for storage)
         [BDEFGOUXbcdefginosux]
     )
    /$1 ? '%'                           # got '%%', replace with '%'
        : sprintf( '%' . $3, $rh->{$2}) # else, apply sprintf
    /xge;
  return $f;
}

しかし、フォーマット文字列の「テール」をキャプチャするための危険な/力ずくのアプローチを恥じています。

信頼できる FORMAT 文字列の正規表現はありますか?

4

2 に答える 2

1

Perl とまったく同じように行う方法を知りたい場合は、Perl の機能を参照してください。

Perl_sv_vcatpvfnは、sprintfフォーマット パーサーおよびエバリュエーターです。(5.14.2 の実装へのリンク。)

于 2012-04-18T20:08:01.350 に答える
1

許容される形式は、 で十分に規定されていperldoc -f sprintfます。とフォーマット文字の間には'%'、次のものを含めることができます。

     (\d+\$)?         # format parameter index (though this is probably
                      # incompatible with the dictionary feature)

     [ +0#-]*         # flags

     (\*?v)?          # vector flag

     \d*              # minimum width

     (\.\d+|\.\*)?    # precision or maximum width

     (ll|[lhqL])?     # size
于 2012-04-18T20:03:03.810 に答える