3

XML ドキュメントの正しいインデントを処理できる XSLT スタイルシートを探していたところ、http://www.printk.net/~bds/indent.htmlで非常に優れたものを見つけました。

著者がそのような引用について私を責めないことを願っています:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" encoding="ISO-8859-1"/>
  <xsl:param name="indent-increment" select="'   '"/>

  <xsl:template name="newline">
    <xsl:text disable-output-escaping="yes">
</xsl:text>
  </xsl:template>

  <xsl:template match="comment() | processing-instruction()">
    <xsl:param name="indent" select="''"/>
    <xsl:call-template name="newline"/>    
    <xsl:value-of select="$indent"/>
    <xsl:copy />
  </xsl:template>

  <xsl:template match="text()">
    <xsl:param name="indent" select="''"/>
    <xsl:call-template name="newline"/>    
    <xsl:value-of select="$indent"/>
    <xsl:value-of select="normalize-space(.)"/>
  </xsl:template>

  <xsl:template match="text()[normalize-space(.)='']"/>

  <xsl:template match="*">
    <xsl:param name="indent" select="''"/>
    <xsl:call-template name="newline"/>    
    <xsl:value-of select="$indent"/>
      <xsl:choose>
       <xsl:when test="count(child::*) > 0">
        <xsl:copy>
         <xsl:copy-of select="@*"/>
         <xsl:apply-templates select="*|text()">
           <xsl:with-param name="indent" select="concat ($indent, $indent-increment)"/>
         </xsl:apply-templates>
         <xsl:call-template name="newline"/>
         <xsl:value-of select="$indent"/>
        </xsl:copy>
       </xsl:when>       
       <xsl:otherwise>
        <xsl:copy-of select="."/>
       </xsl:otherwise>
     </xsl:choose>
  </xsl:template>    
</xsl:stylesheet>

1 つの厄介なことを除いて、私が望んでいたほとんどすべてのことを実行します。それは、ドキュメントのルート要素の奇妙な 8 スペースのインデントを作成します (XML 宣言ではありません)。結果は次のマークアップのようになります。

<?xml version="1.0" encoding="UTF-8"?>
        <database>
           <books>
              <book id="0">
                 <ISBN value="0123456789"/>
                 <title>Some book title Language</title>
                 <hardcover value="false"/>
                 <price value="40.46"/>
                 <in_stock value="100"/>
                 <annotation>Some annotation</annotation>
              </book>
           </books>
        </database>`

私は XSLT テクノロジにかなり慣れていないため、修正方法を理解するためにかなりの時間を費やしましたが、これまでのところ成功していません。XSLT変換を行うために、標準の javax.xml.transform.Transformer クラスを使用しています。なぜこれが起こるのか、何か考えはありますか？

4

1 に答える 1

6

インデントを行うために特別なXSLTコードは必要ありません。

標準のIDテンプレートのみを使用し <xsl:output indent="yes"/>ます。

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

この変換が任意のXMLドキュメント（このような）に適用される場合：

<database>            <books>
<book id="0">
<ISBN value="0123456789"/>
<title>Some book title Language</title>
              <hardcover value="false"/>
 <price value="40.46"/>
   <in_stock value="100"/>
    <annotation>Some annotation</annotation>
   </book></books> </database>

同じXMLドキュメントを出力しますが、インデントされます：

<database>
   <books>
      <book id="0">
         <ISBN value="0123456789"/>
         <title>Some book title Language</title>
         <hardcover value="false"/>
         <price value="40.46"/>
         <in_stock value="100"/>
         <annotation>Some annotation</annotation>
      </book>
   </books>
</database>
于 2012-04-19T01:38:21.737 に答える