0

フォーム内に、Excel ファイルを含むオブジェクト (ワークシート) があります。次に、ワークシートのフィールドの合計を計算するボタンがあり、その合計がフォームのフィールドに表示されます。それをどのようにコーディングしますか？考え方はこんな感じ

合計 = 合計 (A2:A51)

doc.total = totalr

4

1 に答える 1

2

ノーツ クライアントから使用されるフォームでこれを行っており、ノーツ クライアントを実行しているマシンに Excel がある場合は、VBA を使用できます。ファイルをユーザーのハード ドライブに抽出し、Excel で開き、列の一番下にセルを追加してそこに SUM() 関数を配置し、その新しいセルの値を取得し、UIDOC のフィールドを更新してから、temp を消去します。ファイル。

以下のコードは、"excelfile" と呼ばれる RichText フィールド (Excel ファイルを含む)、Excel ファイルからの合計値を含む "Sum" と呼ばれるフィールド、およびコードを含むボタンを含むフォームがあることを前提としています。さらに、コードを機能させるには、ドキュメントを添付ファイルと共に保存する必要があります。

それが役に立てば幸い。

Sub Click(Source As Button)

On Error Goto errorhandler

Dim s As New NotesSession
Dim ws As New NotesUIWorkspace
Dim uidoc As NotesUIDocument
Set uidoc = ws.CurrentDocument
Dim doc As NotesDocument
Set doc = uidoc.Document
Dim rtitem As NotesRichTextItem
Dim isfileopen As Boolean

Dim filename As String, rows As Double, cols As Double, colToSum As String, c As Integer
Dim xlApp As Variant, xlWorkbook As Variant, xlSheet As Variant, pathname As String

isfileopen = False

'convert column letter to number
colToSum = "A"
c = Asc(colToSum) - 64

'extract file
pathname = s.GetEnvironmentString( "Directory", True ) & "\"
Set rtitem = doc.GetFirstItem("excelfile")
If Not (doc.HasEmbedded) Then
    Msgbox "There are no file attachments on this document"
    Goto ExitGracefully
End If  
Forall o In rtitem.EmbeddedObjects
    If ( o.Type = EMBED_ATTACHMENT ) Then
        filename = pathname & o.Name            
        Call o.ExtractFile( filename )          
    End If
End Forall

'open file
Print "Opening file " & filename & "..."
Set xlApp = CreateObject("Excel.Application") 
xlApp.Workbooks.Open filename
isfileopen = True

'get sheet
Print "Gathering data ..."
Set xlWorkBook = xlApp.ActiveWorkbook 
Set xlSheet = xlWorkBook.ActiveSheet 
xlSheet.Cells.SpecialCells(11).Activate
rows = xlApp.ActiveWindow.ActiveCell.Row 
cols = xlApp.ActiveWindow.ActiveCell.Column 

'add a row and put the sum() formula there
Print "Computing sum with Excel..."
xlSheet.Cells( rows+1, c ).value = "=SUM(" & colToSum & "1:" & colToSum & Cstr(rows) & ")"

'update UI doc
Call uidoc.FieldSetText( "Sum", Cstr(xlSheet.Cells( rows+1, c ).value) )

exitgracefully:

'close excel
Print "Closing Excel..."
If Not xlWorkbook Is Nothing Then
    xlWorkbook.Close False 
End If
If Not xlApp Is Nothing Then
    xlApp.DisplayAlerts = False
    xlApp.Quit
    Set xlApp = Nothing 
End If 

If isfileopen Then
    'remove temp file
    Print "Removing " & filename
    Kill filename
End If

'done
Print "Done"

Exit Sub
errorhandler:
Msgbox Error & " line " & Erl
Exit Sub
End Sub
于 2012-10-08T22:27:04.557 に答える