cython - Cythonを使用してコピーせずにmallocされたバッファをCからPythonに変換しますか?

Question

Cython で、malloc() で割り当てられ、後で free() で解放されると予想される大きなバッファを返す C 関数があるとします。

次に、このバッファーを (バイト) str オブジェクトとして Python に渡す必要があります。Python はその所有権を取得し、後で str オブジェクトがなくなったら free() を呼び出します。これは可能ですか？

Answer 1

numpy を使用した実装については、https: //gist.github.com/1249305をご覧ください。

numpy がオプションでない場合は、メモリビューを使用して、次のようなものが機能する可能性があります。

from libc.stdlib cimport free
cimport fn # in here is the c function with signature: char * char_ret(int n);

cdef class BuffWrap:
    cdef long siz
    cdef char * _buf
    cdef char[:] arr
    def __cinit__(self,  long siz):
        self.siz = siz
        self._buf = fn.char_ret(siz) # storing the pointer so it can be freed
        self.arr = <char[:siz]>self._buf
    def __dealloc__(self):
        free(self._buf)
        self.arr = None
    # here some extras:
    def __str__(self):
        if self.siz<11:
            return 'BuffWrap: ' + str([ii for ii in self.arr])
        else:
            return ('BuffWrap: ' + str([self.arr[ii] for ii in range(5)])[0:-1] + ' ... '
                    + str([self.arr[ii] for ii in range(self.siz-5, self.siz)])[1:])
    def __getitem__(self, ind): 
        """ As example of magic method.  Implement rest of to get slicing
        http://docs.cython.org/src/userguide/special_methods.html#sequences-and-mappings
        """
        return self.arr[ind]

__dealloc__のインスタンスへのすべての参照がBuffWrap消え、ガベージ コレクションが取得されると、ポインターによって保持されているメモリを解放するメソッドに注意してください。この自動割り当て解除は、すべてをクラスにラップする正当な理由です。

返されたポインターを使用して、たとえばバイト配列のバッファーに使用する方法がわかりませんでした。誰かが知っているなら、私は見てみたいです。