1

私はこのXMLを持っています:

<Year>
  <Movies>
    <Add>
        <Key>movie1</Key>
        <Value>black</Value>
    </Add>
    <Add>
        <Key>movie2</Key>
        <Value>white</Value>
    </Add>
  </Movies>
</Year>

これも、開始文字として特別なアスタリスクを使用して、この XML に変換する必要があります。

<Year>
    <MovieList>*movie1-black,movie2-white<MovieList>
</Year>

私は xslt 変換のいくつかのバリエーションを試しましたが、私はいたるところにいます。これは私の最新のハックです。XMLツールでこれをいじっています...

<xsl:template match="b:Year">
 <xsl:copy>
   <xsl:for-each select="*">
      <xsl:element name="MovieList">
        <xsl:for-each select="./b:Movies/b:Add">
          <xsl:if test="position() = 1">*</xsl:if>
          <xsl:value-of select="./b:Key"/>-<xsl:value-of select="./b:Value"/>
          <xsl:if test="position() != last()">,</xsl:if>
        </xsl:for-each>
      </xsl:element>
   </xsl:for-each>
  <xsl:apply-templates select="node()"/>
 </xsl:copy>
</xsl:template>

これに関するガイダンスを持っている xslt の専門家はいますか? ありがとう！

4

2 に答える 2

0

I. このシンプルで効率的な XSLT 1.0 変換 (変数なし、結果の後処理なし):

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
    <Year>
     <xsl:apply-templates/>
    </Year>
 </xsl:template>

 <xsl:template match="Movies">
  <MovieList>
   <xsl:apply-templates/>
  </MovieList>
 </xsl:template>

 <xsl:template match="Add">
  <xsl:value-of select="substring('*,', 2 - (position()=1),1)"/>
  <xsl:value-of select="concat(Key, '-', Value)"/>
 </xsl:template>
</xsl:stylesheet>

提供された XML ドキュメントに適用した場合:

<Year>
    <Movies>
        <Add>
            <Key>movie1</Key>
            <Value>black</Value>
        </Add>
        <Add>
            <Key>movie2</Key>
            <Value>white</Value>
        </Add>
    </Movies>
</Year>

必要な正しい結果が生成されます。

<Year>
   <MovieList>*movie1-black,movie2-white</MovieList>
</Year>

Ⅱ．XSLT 2.0 ソリューション:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
    <Year>
     <xsl:apply-templates/>
    </Year>
 </xsl:template>

 <xsl:template match="Movies">
  <MovieList>
   <xsl:sequence select="'*'[current()/Add]"/>
   <xsl:value-of select="Add/concat(Key, '-', Value)"
        separator=","/>
  </MovieList>
 </xsl:template>
</xsl:stylesheet>
于 2012-04-24T02:42:42.730 に答える
0

XSLT 1.0 でできることは次のとおりです。

 <xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

     <xsl:template match="Year/Movies">
        <Year>
          <xsl:variable name="movielist">
            <xsl:for-each select="Add">
              <xsl:value-of select="concat(Key, '-', Value, ',')"/>
            </xsl:for-each>
          </xsl:variable>
          <MovieList>
              <xsl:value-of select="concat('*',substring($movielist, 0, string-length($movielist)))"/>
          </MovieList>
        </Year>
    </xsl:template>
</xsl:stylesheet>

入力が与えられると、次が生成されます。

<Year>
   <MovieList>*movie1-black,movie2-white</MovieList>
</Year>

同様の例で説明されているように、XSLT 2.0 のseparator属性を利用してより巧妙に行うことができます: Dimitre によるxsl の 2 つのフィールドの連結xsl:value-of

于 2012-04-24T02:04:28.033 に答える