shell - ksh および AT&T sed、パターンに一致する改行

Question

「aaa bbb」を分割する必要があります

aaa
bbb

1 行のコードで。gnused では、次のことができます。

print 'aaa bbb'  | sed 's/ /\n/g'

bash では、次のことができます。

echo 'aaa bbb' | sed 's/ '"/`echo \\\n`/"

しかし、ksh/zsh では、AIX で at&t sed を使用すると、次のいずれも機能しません。

print 'aaa bbb' | sed "s/ /`echo -e \\\n`/"
print 'aaa bbb' | sed 's/ '"/`echo \\\n`/"
print 'aaa bbb' | sed "s/ /`echo \\\n`/"

1行で、sedに回避策はありますか?

score 1 · Accepted Answer

これはあなたのために働くかもしれません：

echo -e "aaa bbb ccc\nxxx yyy zzz" |
sed 'G;:a;s/ \+\(.*\(.\)\)/\2\1/;ta;s/.$//'
aaa
bbb
ccc
xxx
yyy
zzz

多分：

echo -e "aaa bbb ccc\nxxx yyy zzz" |
sed -e 'G' -e ':a' -e 's/ \+\(.*\(.\)\)/\2\1/' -e 'ta' -e 's/.$//'
aaa
bbb
ccc
xxx
yyy
zzz

score 1 · Accepted Answer

これが「1行で」と見なされるかどうかはわかりません...

print 'aaa bbb'  | sed 's/ /
/g'

...それは単一のコマンドであり、以前に at&t sed (または SCO Unix が使用するもの) で使用したことがあると思います...

score 1 · Accepted Answer

行にスペースが 1 つだけあると仮定すると、次のようになります。

sed 'h;s/^[^ ]* //;x;s/ [^ ]*$//;G'

すべてのスペースに対してこれを行うには: (ここで私のローカルでバグを引き起こしていると思いsedます; 上記のようにコマンドを組み合わせることができませんでした)

$ echo aaa bbb ccc def ghi zzz |
> sed -e :s -e h -e 's/ .*$//' -e p -e x -e 's/^[^ ]* //' -e ts -e d
aaa
bbb
ccc
def
ghi
zzz

(このケースをより適切に処理するために GNU sed が拡張された理由がわかります。) ホールドスペースを使用してあらゆる種類のことを行うことができ、条件分岐 ( s/.../.../;thereifmatched) を使用するとさらに多くのことができます。

3 に答える 3