1

SQL Server2005とasp.net2008をc＃で使用しています...2つのテーブルResultとStud_Info......があります。

1] Stud_Info

CREATE TABLE Stud_Info
(Enroll_Number varchar(20) NOT NULL,  
Salutation varchar(10) NULL,  
First_Name varchar(20) NULL,  
Middle_Name varchar(20) NULL,  
Last_Name varchar(20) NULL,  
Course_Id varchar(20) NULL,  
Batch varchar(20) NULL)

INSERT into Stud_Info values(11161,'Mr.','Mack','B','Botha','MECH','Batch1');    
INSERT into Stud_Info values(11162,'Mr.','John','A','Los','CIVIL','Batch2');    
INSERT into Stud_Info values(11163,'Ms.','Merry','F','Dsuza','ELCT','Batch1');    
INSERT into Stud_Info values(11164,'Mr.','Pow','B','Janero','MECH','Batch2');    
INSERT into Stud_Info values(11165,'Mr.','Martin','J','Smith','MECH','Batch1');    

SELECT * from Stud_Info

2番目のテーブルはこのようなものです...

2] Exam_Result

CREATE TABLE Exam_Result
(Result_Id numeric(18, 0) IDENTITY(1,1) NOT NULL,  
Enroll_Number varchar(50) NULL,  
Student_Name varchar(100) NULL,  
Course_Id varchar(50) NULL,  
Semester varchar(50) NULL,  
Subject_Id varchar(50) NULL,  
Subject_Name varchar(50) NULL,  
MarksObtained numeric(18, 0) NULL,  
Exam_Type varchar(50) NULL)

INSERT into Exam_Result values(11161,'Mack B Botha','MECH',1,'MT','Maths',25,'Internal1');  
INSERT into Exam_Result values(11161,'Mack B Botha','MECH',1,'EN','English',22,'Internal1');  
INSERT into Exam_Result values(11161,'Mack B Botha','MECH',1,'SC','Science',20,'Internal1');  
INSERT into Exam_Result values(11166,'Barden V John','CIVIL',1,'SS','Social',21,'Internal2');  
INSERT into Exam_Result values(11161,'Mack B Botha','MECH',2,'SM','Simple Maths',24,'Internal2');  
INSERT into Exam_Result values(11161,'Mack B Botha','MECH',2,'SM','Simple Maths',69,'Final');  

SELECT * from Exam_Result

サブジェクトの行から列への動的変換にこのストアドプロシージャを使用しています......正常に動作します。

    Create Proc GetExamResults (@Course_Id varchar(100), @Semester varchar(10))
as
begin
    declare @subjname varchar(100)  
    declare @subjects varchar(7000)  
    declare @subjectsselection varchar(7000)  
    declare @SumSelection varchar(7000)  
    declare @NoOfSubjects int
    set @NoOfSubjects = 0

    set @subjects = ''  
    set @subjectsselection = '' 
    set @SumSelection = ''

    DECLARE subject_cursor CURSOR  
    FOR SELECT distinct Subject_Name FROM Exam_Result where course_id = @Course_Id And Semester = @Semester 

    OPEN subject_cursor  

    FETCH NEXT FROM subject_cursor  
    INTO @subjname  

    WHILE @@FETCH_STATUS = 0  
    BEGIN  
        set @subjects = @subjects + '[' + @subjname + '],'  
        set @subjectsselection = @subjectsselection + 'Sum(Isnull([' + @subjname + '],0)) As [' + @subjname + '],' 
        set @SumSelection = @SumSelection + 'Sum(Isnull([' + @subjname + '],0))+' 

        set @NoOfSubjects = @NoOfSubjects + 1

        FETCH NEXT FROM subject_cursor  
        INTO @subjname  
    End  
    CLOSE subject_cursor;  
    DEALLOCATE subject_cursor;  

    select @subjects = LEFT(@subjects, LEN(@subjects) - 1)  
    select @subjectsselection = LEFT(@subjectsselection, LEN(@subjectsselection) - 1)  
    select @SumSelection = LEFT(@SumSelection, LEN(@SumSelection) - 1)  

    print @subjects  
    print @subjectsselection  
    print @SumSelection

    declare @query nvarchar(4000)  

    set @query = 'select S.Enroll_Number, pvt.Student_Name, pvt.Course_Id, pvt.Semester, ' + @subjectsselection + ',' 
    set @query = @query + 'Exam_Type,' + @SumSelection + ' As Grand_Total, '
    set @query = @query + '(' + @SumSelection + ')' + '/' + convert(varchar(10),@NoOfSubjects) + ' As Avg'
    set @query = @query + ' From '  
    set @query = @query + '(select Enroll_Number, Student_Name, Course_Id, Semester, Subject_Name, MarksObtained, Exam_Type from Exam_Result ) ps '  
    set @query = @query + ' pivot(sum(MarksObtained) for Subject_Name in (' + @subjects + ')) as pvt'  
    set @query = @query + ' inner join Stud_Info S on S.Enroll_Number = pvt.Enroll_Number '
    set @query = @query + ' where pvt.Course_Id = ''' + @Course_Id + ''' and pvt.Semester = ''' + @Semester + ''''
    set @query = @query + ' group by S.Enroll_Number, pvt.Student_Name, pvt.Course_Id, pvt.Semester, Exam_Type'
    print @query
    exec sp_executesql @query  
end

現在、私はo/pのようになっています...

Enroll_Number  Student_Name Course_Id   Semester  Maths    English    Science    Social    Smathas    total    avg

11161           MACK         MECH        1         25       22         20         0         0          67      total/all sub
11166           Barden       CIV         1         0        0          0          21        0          21      total/all sub

ノート

ここでは、Exam_Resultテーブルにあるすべてのサブジェクトと、Exam_Resultからのすべてのサブ（geでは-67）とすべてのサブジェクトの平均の合計を取得しています。

今の質問は、ユーザーの選択に従って模索することによって結果を表示したいです....たとえば、ユーザーがCourse_Id=MECHとSemester=1のみを表示したい場合、 .... o/pは...である必要があります。

Enroll_No    Student_Name    Course_ID    Semester    Maths    English    Science     Type         Grand_Total    Avg

11161        Mack B Botha     MECH         1          25        22         20        internal1       67          66.22

すべてのコースと学期に科目の修正はありません..変更される可能性があります....そしてCourse_Idと学期ごとにグループ化する必要がありますガイダンスとクエリを教えてください私はあなたの答えを実装します....この情報を願っています私のことを説明するのに十分です....すべての答えは大歓迎です...ありがとう

4

1 に答える 1

1

あなたのこのコメントに答える：

私のサイトのSQLServer2005では機能しません。エラーメッセージ102、レベル15、状態1、行1が表示されます。「ps」の近くの構文が正しくありません。SUBSTRING関数に渡された無効な長さパラメーター。

最初のエラーは、動的クエリの実行時に発生する可能性があります。よくわかりませんが、データベースの互換性レベルが90未満であるためPIVOT、許可/認識されていないようです。このサイトで、PIVOT句を使用せずにピボットして回避する方法に関する質問を検索してください。または、可能であれば、DBの互換性レベルを90に設定します。

2番目のエラーについては、クエリをテストしているときにも発生しました。（パラメーターの値を指定しなかった場合に発生しました。）エラーの原因は次の行です。

select @subjects = LEFT(@subjects, LEN(@subjects) - 1)

カーソルクエリが行を返さない場合、@subjects変数は空のままになり、LEN(@subjects) - 1結果は-1になります。これは、長さ引数としてに渡されるとLEFT()、エラーになります。

問題を回避するには、条件を追加するだけです。

if LEN(@subjects) > 0 select @subjects = LEFT(@subjects, LEN(@subjects) - 1)

他の2つの文字列（@subjectsselectionおよび@SumSelection）についても同じようにします。

また、次に質問をして何かが機能していないと言ったときは、コメントではなく、すべての関連情報（エラーメッセージを含む）を質問に入れてください。

于 2012-05-02T10:45:04.847 に答える