vbscript - すべての空のファイルを再帰的にダウンロードするスクリプトを作成するにはどうすればよいですか?

Question

ドライブ C からサイズが 0 のすべてのファイルをダウンロードする VBScript を開発する必要があります。次のスクリプトを作成しました。

Dim oFSO 
Dim sDirectoryPath
Dim oFolder  
Dim oFileCollection
Dim oFile
Dim oFolderCollection
Dim n
Set oFSO = CreateObject("Scripting.FileSystemObject")
sDirectoryPath = "C:\"
set oFolder = oFSO.GetFolder(sDirectoryPath)
set oFolderCollection = oFolder.SubFolders
set oFileCollection = oFolder.Files
For each oFile in oFileCollection
    IF oFile.Size = 0 Then
        oFile.Delete(true)
    END IF
Next    

ただし、このスクリプトはドライブ C のルート ディレクトリからのみファイルを削除します。このコードでは再帰的を使用する必要がありますが、VBScript は初めてで、どうすればよいかわかりません。お願いします、助けてください。ありがとうございました。

Answer 1

ここでは、テスト済みで動作するスクリプト

set oFso = createobject("scripting.filesystemobject")
sDirectorypath = "c:\testing"
delete_empty_files(sDirectorypath)

sub delete_empty_files(folder)
  set oFolder = oFso.getfolder(folder)
  for each oFile in oFolder.files
    if oFile.size = 0 then
      wscript.echo " deleting " & oFile.path
      oFile.delete(true)
    end if
  next
  for each oSubFolder in oFolder.subfolders
    delete_empty_files(oSubFolder)
  next
end sub