18

ARM Cortex-M3（NXPのLCP17xx）のコードを作成しています。私はこれまで静的メモリを使用してきましたが、すべてがうまく機能しました。動的メモリのサポートを追加しようとしましたが、mallocを呼び出すと、システムがスタックします。

アームベアメタル用にgccでコンパイルし、newlibを使用しています。バージョン：gcc-arm-none-eabi-4_6-2012q1

mallocサポートを追加するために、単純な_sbrk関数を実装し、リンカースクリプトを変更して、ヒープ用のスペースを確保しました（この部分に関するさまざまなチュートリアルを読みましたが、次に発生した問題については説明していません）。

いくつかのLEDの助けを借りて、コードが呼び出されるポイントまで実行されmalloc、その後は続行されないことを確信できます。それは私の機能にさえ到達しません_sbrk。また、後でコードにsizeofへの呼び出しを含めると、への呼び出しでスタックします。malloc

それで、コードを呼び出すときに到達したり戻ったりmallocすることなくスタックするという間違ったことは何ですか？_sbrk

呼び出しが含まれている場合と含まれていない場合に生成されるメモリマップをしばらく見つめた後、mallocそれはによって使用される構造に関連していると思われmallocます。

これは、RAMメモリを定義するldスクリプトの一部です。

.bss :
{
    _start_bss = .;
    *(.bss)
    *(COMMON)
    _ebss = .;
    . = ALIGN (8);
    _end = .;
} >sram
. = ALIGN(4);
_end_bss = .;
. = ALIGN(256);
_start_heap = .;
PROVIDE( __cs3_heap_start = _start_heap)

_end_stack = 0x10008000;

次に、_end_stackが割り込みベクタテーブルに設定されます。

そして今、異なるマップの比較。コードでmallocを使用しない場合：

 *(COMMON)
            0x1000000c                _ebss = .
            0x10000010                . = ALIGN (0x8)
 *fill*     0x1000000c        0x4 00
            0x10000010                _end = .
            0x10000010                . = ALIGN (0x4)
            0x10000010                _end_bss = .
            0x10000100                . = ALIGN (0x100)
            0x10000100                _start_heap = .

コードでmallocを使用したメモリマップ：

*(COMMON)
COMMON      0x10000848        0x4 ...arm-none-eabi/lib/armv7-m/libc.a(lib_a-reent.o)
            0x10000848                errno
            0x1000084c                _ebss = .
            0x10000850                . = ALIGN (0x8)
*fill*      0x1000084c        0x4 00
            0x10000850                _end = .

.bss.__malloc_max_total_mem
            0x10000850        0x4
.bss.__malloc_max_total_mem
            0x10000850        0x4 ...arm-none-eabi/lib/armv7-m/libc.a(lib_a-mallocr.o)
            0x10000850                __malloc_max_total_mem

(...) It goes on (...)
            0x1000085c                __malloc_current_mallinfo
            0x10000884                . = ALIGN (0x4)
            0x10000884                _end_bss = .
            0x10000900                . = ALIGN (0x100)
            0x10000900                _start_heap = .
4

1 に答える 1

17

それで、これをデバッグするのに約10時間費やした後、私はついにそれを機能させました。問題はリンカースクリプトにありました。しかし、私が投稿したのはbssセクションではなく、テキストとデータのセクションでした。動作するスクリプトは次のとおりです。

OUTPUT_FORMAT("elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_startup)

MEMORY
{
    rom (rx)  : ORIGIN = 0x00000000, LENGTH = 512K
    ram (rwx) : ORIGIN = 0x10000000, LENGTH =  32K
}

/* Define the top our stack at the end of SRAM */
_end_stack = 0x10008000;

EXTERN(__interrupt_vector_table);

SECTIONS
{
    .text :
    {
        /* Insert the interrupt vector table first */
        __interrupt_vector_table = .;
        *(.interrupt_vector_table)
        /* Startup assembly */
        *(.startup)
        /* Rest of the code (C) */
        *(.text) *(.text.*) *(.glue_7) *(.glue_7t)
        *(.vfp11_veneer)
        *(.ARM.extab* .gnu.linkonce.armextab.*)
        *(.rodata) *(.rodata.*)
        . = ALIGN(8);
        _end_text = .;
        _start_datai = .;
    } >rom

    .data :
    {
        _start_data = .;
        *(vtable)
        *(.data) *(.data.*)
        . = ALIGN (8);
        _end_data = .;
    } >ram AT >rom

    .data_init : { _end_datai = .; } >rom

    __exidx_start = .;
    .ARM.exidx : { *(.ARM.exidx* .gnu.linkonce.armexidx.*) } > rom
    __exidx_end = .;

    .bss :
    {
        _start_bss = .;
        *(.bss)
        *(COMMON)
    } >ram 

    . = ALIGN(4);
    _end_bss = .;
    . = ALIGN(256);

    _start_heap = .;
    PROVIDE( __cs3_heap_start = _start_heap);

    /* Linker wants .eh_frame section defined because of gcc 4.4.X bug,
     * just discard it here. */
    /DISCARD/ : { *(.eh_*) }
}

_end = .;
PROVIDE(end = .);

また、初期化コードに変数の初期化を追加する必要がありました。

extern unsigned int _start_data;
extern unsigned int _end_data;
extern unsigned int _start_datai;
extern unsigned int _end_datai;

void init(void) {

    // (...) Other stuff

    // Initialize Global Variables
    uint32_t* data_begin  = (uint32_t*) &_start_data;
    uint32_t* data_end    = (uint32_t*) &_end_data;
    uint32_t* datai_begin = (uint32_t*) &_start_datai;
    uint32_t* datai_end   = (uint32_t*) &_end_datai;
    while(data_begin < data_end)
    {
        *data_begin = *datai_begin;
        data_begin++;
        datai_begin++;
    }

これらの2つのページは非常に役に立ちましたが、何が起こっているのかを理解するのにまだ多くの時間がかかりました：http: //fun-tech.se/stm32/linker/index.phpとhttp://e2e.ti.com/support /microcontrollers/stellaris_arm_cortex-m3_microcontroller/f/473/t/44452.aspx?pi23648=1

これが、私が経験したのと同じ問題を経験している他の誰かに役立つことを願っています。

于 2012-05-06T23:38:33.357 に答える