2

私はマルチスレッドアプリケーションを作成しています。それはクラスTThreadの動的配列を作成しますが、私にとっての謎は、「アクセス違反」から「作成」へのエラーが発生することです。

コードフォーム：

Unit UNT_Main;

Interface

Uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, UNT_Socks;

Type
  TFRM_Main = Class(TForm)
    Procedure FormCreate(Sender: TObject);
  Private
    Procedure OnUpload(Success: Boolean; SockAction: TSockAction);
  Public
    { Public declarations }
  End;

Var
  FRM_Main: TFRM_Main;
  Socks: Array Of TSocks;
  SA: Array Of TSockAction;

Implementation

{$R *.dfm}

Procedure TFRM_Main.OnUpload(Success: Boolean; SockAction: TSockAction);
Begin
  ShowMessage(SockAction.Response);
End;

Procedure TFRM_Main.FormCreate(Sender: TObject);
Var
  I: Integer;
Begin

  SetLength(Socks, 5);
  SetLength(SA, 5);

  For I := 0 To High(Socks)-1 Do
  Begin
    SA[I].SUrl := 'http://google.com.co';
    Socks[I].Create(SA[I]);
    Socks[I].OnUpload := Self.OnUpload;
    Socks[I].Start;
  End;

End;

End.

コードUNT_Socks：

Unit UNT_Socks;

Interface

Uses Classes, IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient, IdHTTP;

// action script
Type
  TSockAction = Record
    SUrl: String;
    Response: String;
  End;

  // Eventos
Type
  // on upload event
  TUpload = Procedure(Success: Boolean; SockAction: TSockAction) Of Object;

  // Clase Socks, ejecuta las acciones
Type
  TSocks = Class(TThread)
    // Http indy sock
    Http: TIdHTTP;
    // action script
    FAtnSck: TSockAction;
    // Temp boolean response
    FbTempRet: Boolean;
  Private
    { Eventos }
    FOnUpload: TUpload;
    { Destructor }
    { Metodos & Funciones }
    Function UploadFile: Boolean;
    { Eventos }
    Procedure DoUpload;
  Protected
    Procedure Execute; Override;
  Public
    { Constructor }
    Constructor Create(SockAction: TSockAction);
    { Eventos }
    Property OnUpload: TUpload Read FOnUpload Write FOnUpload;
  End;

Implementation

{ Constructor }
Constructor TSocks.Create(SockAction: TSockAction);
Begin
  Inherited Create(True);

  FAtnSck := SockAction; // <===== Access Violation Here!
  Http := TIdHTTP.Create(Nil);
End;

{ Eventos }
Procedure TSocks.DoUpload;
Begin
  // check if the event is assign
  If Assigned(FOnUpload) Then
    // call it
    FOnUpload(FbTempRet, FAtnSck);
End;

{ Execute }
Procedure TSocks.Execute;
Begin

  FbTempRet := UploadFile;
  Synchronize(DoUpload);

End;

Function TSocks.UploadFile: Boolean;
Var
  SRes: String;
Begin

  Try
    With Http Do
      FAtnSck.Response := Get(FAtnSck.SUrl);
  Except
    Result := False;
  End;

  Result := True;
End;

End.

何が間違っている可能性がありますか？

ありがとうございました。

4

3 に答える 3

9

作成ループには2つのバグがあります。

1）代わりHigh(Socks)-1にループする必要があるときにループしていHigh(Socks)ます。5つの要素の配列を割り当てていますが、初期化するのはそのうちの4つだけです。で-1を使用せずHigh()、Length()代わりにで使用してください。

2）誤用TSocks.Create()しているため、AVを取得しています。コンストラクターではなくインスタンスメソッドのように呼び出していますが、インスタンスがまだ構築されていないため、クラッシュします。

代わりにこれを使用してください：

For I := 0 To High(Socks) Do
Begin
  SA[I].SUrl := 'http://google.com.co';
  Socks[I] := TSocks.Create(SA[I]); // <-- here
  Socks[I].OnUpload := Self.OnUpload;
  Socks[I].Start;
End;
于 2012-05-06T03:26:42.047 に答える
2

それ以外の

Socks[I].Create(SA[I]);

あなたが使用する必要があります

Socks[I]:= TSocks.Create(SA[I]);

いくつかのマイナーな通知：

なぜHigh（Socks）-1？

Uploadfileの結果は常にTrueになりますか？

Httpを解放する必要がありますか？

于 2012-05-06T03:27:15.743 に答える
1

Remyに同意します。また、UNT_SocksのTSocksにメモリリークがあります。スレッドの終了後、Http（TIdHttp）、FAtnSck（TSockAction）フィールドが解放されません。

TSockの構成にFreeOnTermiateを設定します

Constructor TSocks.Create(SockAction: TSockAction);
Begin
  Inherited Create(True);
  FreeOnTerminate:=True;
  FAtnSck := SockAction;  
  Http := TIdHTTP.Create(Nil);
End;

次に、TSockのデストラクタをオーバーライドします

 Destructor TSocks.Destroy;
 Begin

   SockAction.Free; // <===== if needed
   Http.Free;
   Inherited;
 End;
于 2012-05-06T06:14:07.513 に答える