2

これは、10月1日から100日間毎日SQLデータをプルするためのperlスクリプトであり、SQLは日付形式（yyyy-mm-dd）で非常に扱いにくいため、次のようにスクリプトを作成しました。ただし、2011年11月6日の特定の日に、時刻から日付への変換が正しくなく、開始日と終了日が同じになります。

$srt_date='2011-11-06'
$end_date='2011-11-06'

これがperlエラーなのか他の何かなのかわかりません。

use DBI;
use DBD::Oracle qw(:ora_types);
use Compress::Zlib;
use FileHandle;
use Date::Parse;
use Date::Format;

$st_day=str2time('2011-10-1');

@days=(0..100);

foreach $daynum (@days){
$dt1 = $st_day+3600*(24*$daynum);
$dt2 = $st_day+3600*(24*($daynum+1));
$srt_date = time2str("%d-%h-%Y", $dt1);
$end_date = time2str("%d-%h-%Y", $dt2);
print $srt_date, ',' ,$end_date, '\n';
my $sqlGetEid = "select x,y from z where DATETIME>='$srt_date' and DATETIME<'$end_date'";
}
4

2 に答える 2

1

DateTimeDST遷移を正しく処理する方法は次のとおりです。

use strict; #ALWAYS!
use warnings; #ALWAYS!
use DateTime;

my $st_day = '2011-10-1';

my ($year, $month, $day) = split /-/, $st_day;

my $dt = DateTime->new(
    year => $year,
    month => $month,
    day => $day,
    time_zone => 'local',
);

my @days = 0..100;
foreach my $daynum (@days) {
    my $dt1 = $dt->ymd;
    my $dt2 = $dt->add(days => 1)->ymd;
    printf "%s,%s\n", $dt1, $dt2;
}
于 2012-05-07T18:06:37.480 に答える
0

正確に何を達成したいかはわかりませんが、次のような問題を解決できるのに、なぜわざわざ100個のSQLステートメントを実行する必要があるのでしょうか。

SELECT trunc(datetime, 'DD') truncdate, x,y
FROM z WHERE datetime between '2011-10-01'
AND to_date('20111001', 'YYYYMMDD') + 99

ハッシュにtruncdateキーとして入力します。日付がISO8601の場合、通常の（cmp）ソートでハッシュをループすることで同じ順序になります。

編集：私はあなたがこれをどのように行うことができるかを明確にします：

my $sth = $mdbh->prepare("SELECT trunc(datetime, 'DD') truncdate, x,y
    FROM z WHERE datetime between '2011-10-01'
    AND to_date('20111001', 'YYYYMMDD') + 99
    ORDER BY truncdate");
$sth->execute();

my $lastdate = "";
my $fh;    

while (my $row = $sth->fetchrow_hashref()) {

    # If new date, create new file
    if ($row->{truncdate} ne $lastdate) {
        close($fh) if $fh;
        open($fh, ">", "$row->{truncdate}.csv") or die "Unable to create file '$row->{truncdate}.csv': $!\n";
    }

    print $fh "$row->{x},$row->{y}\n";
    $lastdate = $row->{truncdate};
}
close($fh) if $fh;
于 2012-05-08T08:51:40.317 に答える