24

たとえば、次のコード (ベクトルの合計) のパフォーマンスを向上させるために、2 つのデバイスを使用するにはどうすればよいですか? より多くのデバイスを「同時に」使用することはできますか? はいの場合、さまざまなデバイスのグローバル メモリ上のベクトルの割り当てをどのように管理できますか?

#include <stdio.h>
#include <stdlib.h>
#include <math.h>
#include <time.h>
#include <cuda.h>

#define NB 32
#define NT 500
#define N NB*NT

__global__ void add( double *a, double *b, double *c);

//===========================================
__global__ void add( double *a, double *b, double *c){

    int tid = threadIdx.x + blockIdx.x * blockDim.x; 

    while(tid < N){
        c[tid] = a[tid] + b[tid];
        tid += blockDim.x * gridDim.x;
    }

}

//============================================
//BEGIN
//===========================================
int main( void ) {

    double *a, *b, *c;
    double *dev_a, *dev_b, *dev_c;

    // allocate the memory on the CPU
    a=(double *)malloc(N*sizeof(double));
    b=(double *)malloc(N*sizeof(double));
    c=(double *)malloc(N*sizeof(double));

    // allocate the memory on the GPU
    cudaMalloc( (void**)&dev_a, N * sizeof(double) );
    cudaMalloc( (void**)&dev_b, N * sizeof(double) );
    cudaMalloc( (void**)&dev_c, N * sizeof(double) );

    // fill the arrays 'a' and 'b' on the CPU
    for (int i=0; i<N; i++) {
        a[i] = (double)i;
        b[i] = (double)i*2;
    }

    // copy the arrays 'a' and 'b' to the GPU
    cudaMemcpy( dev_a, a, N * sizeof(double), cudaMemcpyHostToDevice);
    cudaMemcpy( dev_b, b, N * sizeof(double), cudaMemcpyHostToDevice);

    for(int i=0;i<10000;++i)
        add<<<NB,NT>>>( dev_a, dev_b, dev_c );

    // copy the array 'c' back from the GPU to the CPU
    cudaMemcpy( c, dev_c, N * sizeof(double), cudaMemcpyDeviceToHost);

    // display the results
    // for (int i=0; i<N; i++) {
    //      printf( "%g + %g = %g\n", a[i], b[i], c[i] );
    //  }
    printf("\nGPU done\n");

    // free the memory allocated on the GPU
    cudaFree( dev_a );
    cudaFree( dev_b );
    cudaFree( dev_c );
    // free the memory allocated on the CPU
    free( a );
    free( b );
    free( c );

    return 0;
}

前もって感謝します。ミケーレ

4

1 に答える 1

39

CUDA 4.0 がリリースされて以来、あなたが求めているタイプのマルチ GPU 計算は比較的簡単です。それ以前は、同じホスト アプリケーション内で複数の GPU を使用するために、GPU ごとに 1 つのホスト スレッドとある種のスレッド間通信システムを備えたマルチスレッド ホスト アプリケーションを使用する必要がありました。

これで、ホスト コードのメモリ割り当て部分に対して次のようなことが可能になります。

double *dev_a[2], *dev_b[2], *dev_c[2];
const int Ns[2] = {N/2, N-(N/2)};

// allocate the memory on the GPUs
for(int dev=0; dev<2; dev++) {
    cudaSetDevice(dev);
    cudaMalloc( (void**)&dev_a[dev], Ns[dev] * sizeof(double) );
    cudaMalloc( (void**)&dev_b[dev], Ns[dev] * sizeof(double) );
    cudaMalloc( (void**)&dev_c[dev], Ns[dev] * sizeof(double) );
}

(免責事項: ブラウザーで記述され、コンパイルもテストもされていないため、自己責任で使用してください)。

ここでの基本的な考え方はcudaSetDevice、デバイスで操作を実行しているときにデバイスを選択するために使用することです。したがって、上記のスニペットでは、2 つの GPU を想定し、それぞれにメモリを割り当てています [最初のデバイスでは (N/2) double、2 番目のデバイスでは N-(N/2)]。

ホストからデバイスへのデータ転送は、次のように簡単です。

// copy the arrays 'a' and 'b' to the GPUs
for(int dev=0,pos=0; dev<2; pos+=Ns[dev], dev++) {
    cudaSetDevice(dev);
    cudaMemcpy( dev_a[dev], a+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice);
    cudaMemcpy( dev_b[dev], b+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice);
}

(免責事項: ブラウザーで記述され、コンパイルもテストもされていないため、自己責任で使用してください)。

コードのカーネル起動セクションは次のようになります。

for(int i=0;i<10000;++i) {
    for(int dev=0; dev<2; dev++) {
        cudaSetDevice(dev);
        add<<<NB,NT>>>( dev_a[dev], dev_b[dev], dev_c[dev], Ns[dev] );
    }
}

(免責事項: ブラウザーで記述され、コンパイルもテストもされていないため、自己責任で使用してください)。

カーネルの各インスタンスは、処理する配列要素の異なる数で呼び出される可能性があるため、カーネル呼び出しに追加の引数を追加したことに注意してください。必要な変更を解決するのはあなたに任せます。しかし、ここでも基本的な考え方は同じです: を使用cudaSetDeviceして特定の GPU を選択し、通常の方法でカーネルを実行し、各カーネルは独自の引数を取得します。

これらのパーツを組み合わせて、単純なマルチ GPU アプリケーションを作成できるはずです。最近の CUDA バージョンとハードウェアで複数の GPU アプリケーションを支援するために使用できる機能は他にもたくさんあります (ユニファイド アドレッシング、ピア ツー ピア機能など)。CUDA SDK にはシンプルなマルチ GPU アプリケーションもあり、より多くのアイデアを探すことができます。

于 2012-05-10T09:43:22.423 に答える