6

Mモジュールによってパラメータ化されたモジュールがあるとしましょうF：

module M (F : sig type id type data end) =
struct
 type idtype = F.id
 type datatype = F.data
 type component = { id : idtype; data : datatype }
 let create id data = { id; data }
 let get_comp_data comp = comp.data
 let get_comp_id comp = comp.id
end

だから私はこのようにそれを使用します：

module F1 = struct type id = int type data = float end
module MF1 = M(F1)

let comp = MF1.create 2 5.0
let id = MF1.get_comp_id comp

Mさて、署名を一致させたい場合S：

module type S = 
sig
  type idtype
  type datatype 
  type component
  val create : idtype -> datatype -> component
  val get_comp_data : component -> datatype
  val get_comp_id : component -> idtype
end

module F1 = struct type id = int type data = float end
module MF1 = (M(F1) : S)

let comp = MF1.create 2 5.0
let id = MF1.get_comp_id comp

ここで気になるのは、とを定義するためにget_comp_data、モジュールでとget_comp_idを指定する必要があることです。今、私が他のレコードタイプを独自のタイプで持っていると想像してみてください。指定するタイプは12個ありますか？それを回避する簡単な方法はありますか？idtypedatatypeSMS

4

1 に答える 1

9

これを行う自然な方法は、使用サイトではなく、定義サイトでモジュールをシールすることです。次に、タイプ共有を1回表現する必要があります。

module M (F : sig type id type data end) :
  S with type idtype = F.id and datatype = F.data
  = struct ... end

ファンクターパラメーターがより複雑な場合は、個々のタイプではなく、モジュール全体を共有することもできます。例えば：

module type TYPES = sig type id type data (* ...and more... *) end

module type S = 
sig
  module Types : TYPES
  type component
  val create : Types.id -> Types.data -> component
  val get_comp_data : component -> Types.data
  val get_comp_id : component -> Types.id
end

module M (F : TYPES) : S with module Types = F
  = struct ... end

または、署名を別のファンクターにネストすることで、署名自体をパラメーター化することもできます。

module type TYPES = sig type id type data (* ...and more... *) end

module S (F : TYPES) =
struct
  module type S =
  sig
    type component
    val create : F.id -> F.data -> component
    val get_comp_data : component -> F.data
    val get_comp_id : component -> F.id
  end
end

module M (F : TYPES) : S(F).S
  = struct ... end
于 2012-05-11T10:07:10.747 に答える