9

WinForms アプリケーションの SQL サーバー接続文字列を VB.NET に格納する一般的な方法を知る必要があります。

ネットを検索したところ、次の各質問に対する回答が見つかりました。

  • app.config 値の読み取り方法
  • ASP.NETリファレンスでそれを行う方法: this SO question .
  • 接続文字列を保存するにはどうすればよいですか (暗号化されていないため安全ではありません)

接続文字列をVB.NETに安全に保存する方法app.config（またはそれがより良い場合）について完全な回答が欲しいです。settings.settings

app.config適切な場所ですか？これらの値を暗号化できますか?

4

2 に答える 2

11

簡単に言うと、.net フレームワークでそれが可能になります。

http://msdn.microsoft.com/en-us/library/89211k9b(v=vs.80).aspx

関連情報:

これは、machine.configファイルに入ります。

<configProtectedData defaultProvider="RsaProtectedConfigurationProvider">
  <providers>
    <add name="RsaProtectedConfigurationProvider" 
      type="System.Configuration.RsaProtectedConfigurationProvider, ... />
    <add name="DataProtectionConfigurationProvider" 
      type="System.Configuration.DpapiProtectedConfigurationProvider, ... />
  </providers>
</configProtectedData>

そして、これはアプリケーションコードです:

Shared Sub ToggleConfigEncryption(ByVal exeConfigName As String)
    ' Takes the executable file name without the
    ' .config extension.
    Try
        ' Open the configuration file and retrieve 
        ' the connectionStrings section.
        Dim config As Configuration = ConfigurationManager. _
            OpenExeConfiguration(exeConfigName)

        Dim section As ConnectionStringsSection = DirectCast( _
            config.GetSection("connectionStrings"), _
            ConnectionStringsSection)

        If section.SectionInformation.IsProtected Then
            ' Remove encryption.
            section.SectionInformation.UnprotectSection()
        Else
            ' Encrypt the section.
            section.SectionInformation.ProtectSection( _
              "DataProtectionConfigurationProvider") 'this is an entry in machine.config
        End If

        ' Save the current configuration.
        config.Save()

        Console.WriteLine("Protected={0}", _
        section.SectionInformation.IsProtected)

    Catch ex As Exception
        Console.WriteLine(ex.Message)
    End Try
End Sub

更新 1

このリンクをありがとう@wpcoder

于 2012-05-15T18:58:52.193 に答える
8

私の仕事では、完全な接続文字列を app.config に保存していますが、AES256 で暗号化しています。それはかなりうまく機能し、かなりの量のセキュリティを追加します. 接続文字列を暗号化および復号化できる小さなツールを作成したので、app.config ファイルの編集は非常に簡単です。アプリケーションにハードコーディングされた暗号化キーがあるだけなので、誰かがアセンブリを逆コンパイルすることを気にかけている場合は、それを理解することができますが、それは私たちのニーズに十分に高いバーを上げます. 接続文字列の暗号化と復号化に使用するクラスは次のとおりです。

Public Class Aes256Base64Encrypter
    Public Function Decrypt(ByVal encryptedText As String, ByVal secretKey As String) As String
        Dim plainText As String = Nothing
        Using inputStream As MemoryStream = New MemoryStream(System.Convert.FromBase64String(encryptedText))
            Dim algorithm As RijndaelManaged = getAlgorithm(secretKey)
            Using cryptoStream As CryptoStream = New CryptoStream(inputStream, algorithm.CreateDecryptor(), CryptoStreamMode.Read)
                Dim outputBuffer(0 To CType(inputStream.Length - 1, Integer)) As Byte
                Dim readBytes As Integer = cryptoStream.Read(outputBuffer, 0, CType(inputStream.Length, Integer))
                plainText = Unicode.GetString(outputBuffer, 0, readBytes)
            End Using
        End Using
        Return plainText
    End Function


    Public Function Encrypt(ByVal plainText As String, ByVal secretKey As String) As String
        Dim encryptedPassword As String = Nothing
        Using outputStream As MemoryStream = New MemoryStream()
            Dim algorithm As RijndaelManaged = getAlgorithm(secretKey)
            Using cryptoStream As CryptoStream = New CryptoStream(outputStream, algorithm.CreateEncryptor(), CryptoStreamMode.Write)
                Dim inputBuffer() As Byte = Unicode.GetBytes(plainText)
                cryptoStream.Write(inputBuffer, 0, inputBuffer.Length)
                cryptoStream.FlushFinalBlock()
                encryptedPassword = System.Convert.ToBase64String(outputStream.ToArray())
            End Using
        End Using
        Return encryptedPassword
    End Function


    Private Function getAlgorithm(ByVal secretKey As String) As RijndaelManaged
        Const salt As String = "put a salt key here"
        Const keySize As Integer = 256

        Dim keyBuilder As Rfc2898DeriveBytes = New Rfc2898DeriveBytes(secretKey, Unicode.GetBytes(salt))
        Dim algorithm As RijndaelManaged = New RijndaelManaged()
        algorithm.KeySize = keySize
        algorithm.IV = keyBuilder.GetBytes(CType(algorithm.BlockSize / 8, Integer))
        algorithm.Key = keyBuilder.GetBytes(CType(algorithm.KeySize / 8, Integer))
        algorithm.Padding = PaddingMode.PKCS7
        Return algorithm
    End Function
End Class

実際には、秘密鍵をハードコーディングする ConnectionStringEncrpyter クラス内にそれをラップしました。

于 2012-05-15T18:48:41.603 に答える