0

私は以下のようなソースXMLを持っています：

<ROOT>
    <RECORD>
        <Tag1>Tag1 Value</Tag1>
        <Tag2>
            <TagA1>TagA1 Value</TagA1>
            <TagA2>TagA2 Value</TagA2>
            <TagA3>TagA3 Value</TagA3>
        </Tag2>
        <Tag1>Tag1 Value</Tag1>
    </RECORD>
<RECORD>
        <Tag1>Tag1 Value</Tag1>
        <Tag2>
            <TagA1>TagA1 Value</TagA1>
            <TagA2>TagA2 Value</TagA2>
        </Tag2>
        <Tag1>Tag1 Value</Tag1>
</RECORD>
</ROOT>

私はこれを以下のように必要とします::

<ROOT>
    <RECORD>
        <Tag1>Tag1 Value</Tag1>
        <Tag2>TagA1 Value | TagA2 Value | TagA3 Value</Tag2>
        <Tag1>Tag1 Value</Tag1>
    </RECORD>
<RECORD>
        <Tag1>Tag1 Value</Tag1>
        <Tag2>TagA1 Value | TagA2 Value</Tag2>
        <Tag1>Tag1 Value</Tag1>
</RECORD>
</ROOT>

XSLTを使用してそれを実現するにはどうすればよいですか？

4

3 に答える 3

1

これは、RECORD要素の「孫」ノードに一致するテンプレートを用意し、値を出力するだけで実現できると思います。例えば

<xsl:template match="RECORD/*/*">
   <xsl:value-of select="." />
</xsl:template>

ただし、|を処理するには、最初のノードと後続のノードに別々のケースが必要になります。それらの間の文字。代わりにこのXSLTを試してください

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="RECORD/*/*[1]">
      <xsl:value-of select="." />
   </xsl:template>

   <xsl:template match="RECORD/*/*[position() > 1]">
      <xsl:value-of select="concat(' | ', .)" />
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>
于 2012-05-18T09:46:58.507 に答える
1

目的の出力を生成する1つの可能性は次のとおりです。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">     
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>      

  <xsl:template match="RECORD/*[*]">
    <xsl:copy>
      <xsl:for-each select="*">
        <xsl:value-of select="."/>
        <xsl:if test="position() != last()"> | </xsl:if>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>
于 2012-05-18T09:43:10.670 に答える
0

もう1つのバリエーション（すでに提案されているアイデアを使用しますが、私が思うに、最も単純なアプローチであり、使用しません<xsl:for-each>）：

XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="no" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <!-- Identity Template: copies everything as-is -->
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <!-- For all grandchildren of <RECORD> elements, concat them, using -->
  <!-- a pipe as a delimiter (as long as we're not on the last element) -->
  <xsl:template match="RECORD/*/*">
    <xsl:value-of select="." />
    <xsl:if test="position() != last()">
        <xsl:text> | </xsl:text>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

入力XML：

<?xml version="1.0" encoding="UTF-8"?>
<ROOT>
  <RECORD>
    <Tag1>Tag1 Value</Tag1>
    <Tag2>
      <TagA1>TagA1 Value</TagA1>
      <TagA2>TagA2 Value</TagA2>
      <TagA3>TagA3 Value</TagA3>
    </Tag2>
    <Tag1>Tag1 Value</Tag1>
  </RECORD>
  <RECORD>
    <Tag1>Tag1 Value</Tag1>
    <Tag2>
      <TagA1>TagA1 Value</TagA1>
      <TagA2>TagA2 Value</TagA2>
    </Tag2>
    <Tag1>Tag1 Value</Tag1>
  </RECORD>
</ROOT>

出力：

<?xml version="1.0" encoding="UTF-8"?>
<ROOT>
  <RECORD>
    <Tag1>Tag1 Value</Tag1>
    <Tag2>TagA1 Value | TagA2 Value | TagA3 Value</Tag2>
    <Tag1>Tag1 Value</Tag1>
  </RECORD>
  <RECORD>
    <Tag1>Tag1 Value</Tag1>
    <Tag2>TagA1 Value | TagA2 Value</Tag2>
    <Tag1>Tag1 Value</Tag1>
  </RECORD>
</ROOT>
于 2012-05-19T23:57:17.227 に答える