0

参照

VBE で sheet1 内のプロシージャのステートメントの行番号を見つけて、次の行にコードを追加することにより、Sheet1 内のプロシージャにコード (サブルーチン呼び出し) を追加しようとしています。次のコードは、これを実現しようとしています。

' This will search for and modify the appropriate Node#button_Click() subroutine
    With ActiveWorkbook.VBProject.VBComponents("Sheet1").CodeModule
            ProcLineNum = .ProcStartLine("Node" & NumNodes & "Button" & "_Click", 0)
            .InsertLines ProcLineNum + 1, "load_node_form(" & DQUOTE & "Node " & NumNodes & DQUOTE & ")"
    End With

サブルーチン全体は次のとおりです。

Public Sub Node_Button_Duplication()
'
'Com: Copies and pastes Node 1's button to the appropriate column

Dim shp As Shape
Dim code As String
Dim ProcLineNum As Long
Const DQUOTE = """"

' Copy Node 1 button and paste in appropriate location

    ActiveSheet.Shapes("CommandButton1").Select
    Selection.Copy
    Cells(5, 10 + 7 * (NumNodes - 1) - 1).Select
    ActiveSheet.Paste
    Selection.ShapeRange.IncrementLeft 47.25
    Selection.ShapeRange.IncrementTop -13.5


    Set shp = ActiveSheet.Shapes(Selection.Name)

    With shp.OLEFormat.Object
        .Object.Caption = "Node" & Str(NumNodes)
        .Name = "Node" & NumNodes & "Button"
    End With

' This will search for and modify the appropriate Node#button_Click() subroutine
    With ActiveWorkbook.VBProject.VBComponents("Sheet1").CodeModule
            ProcLineNum = .ProcStartLine("Node" & NumNodes & "Button" & "_Click", 0)
            .InsertLines ProcLineNum + 1, "load_node_form(" & DQUOTE & "Node " & NumNodes & DQUOTE & ")"
    End With

End Sub

サブルーチンは、ボタン ("CommandButton1") をコピーして貼り付け、名前を変更してから、サブルーチン呼び出しを割り当てようとします。プロシージャを見つける際の問題は、新しいボタンが作成されると、「CommandButton#_Click() プロシージャは、エディタから選択するまで VBE に表示されないため、コードが検索しようとするとエラーが発生することです。その手続きのために。

4

1 に答える 1

1

これはあなたがしようとしていることですか？

Option Explicit

Public Sub Node_Button_Duplication()
    Dim shp As Shape
    Dim code As String
    Dim ProcLineNum As Long, NumNodes As Long

    Const DQUOTE = """"

    ActiveSheet.Shapes("CommandButton1").Select
    Selection.Copy
    Cells(5, 10 + 7 * (NumNodes - 1) - 1).Select
    ActiveSheet.Paste
    Selection.ShapeRange.IncrementLeft 47.25
    Selection.ShapeRange.IncrementTop -13.5

    Set shp = ActiveSheet.Shapes(Selection.Name)

    With shp.OLEFormat.Object
        .Object.Caption = "Node" & Str(NumNodes)
        .Name = "Node" & NumNodes & "Button"
    End With

    With ActiveWorkbook.VBProject.VBComponents( _
    ActiveWorkbook.Worksheets("Sheet1").CodeName).CodeModule
        .InsertLines Line:=.CreateEventProc("Click", "Node" & NumNodes & "Button") + 1, _
        String:=vbCrLf & _
        "load_node_form(" & DQUOTE & "Node " & NumNodes & DQUOTE & ")"
    End With
End Sub
于 2012-05-18T21:46:48.790 に答える