3

この質問（http://stackoverflow.com/q/1333558/948404）と同様に、XPathを使用して、次のような構造の製品の合計を計算したいと思います。

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

各アイテムの積の合計を計算するXPath式はありvalueますquantityか？

更新：ソリューションはPHPのXSLTProcessorクラスで動作する必要があります。つまり、おそらくXSLT1.0に準拠している必要があります。これが、XSLT2.0を使用した2つのおそらく正しい答えをまだ受け入れなかった理由です。PHPの実装でも、ブラウザでも、w3schoolsのTryitEditor[1]でもテストできませんでした。ごめん！

  1. http://w3schools.com/xsl/tryxslt.asp?xmlfile=cdcatalog&xsltfile=cdcatalog
4

3 に答える 3

4

次の XPath 2.0 式を使用します。

sum(/items/item/(value * quantity))

以下は検証用の XSLT 2.0 変換です。

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

    <xsl:template match="/">
        <xsl:sequence select="sum(/items/item/(value * quantity))"/>
    </xsl:template>
</xsl:stylesheet>

この変換が提供された XML ドキュメントに適用されると、次のようになります。

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

XPath 式が評価され、この評価の結果が出力されます。

8

説明:

XPath 2.0 では、ロケーション ステップを

/(expression)、

あるいは

/someFunction(argumentList)

Ⅱ．XSLT 1.0 ソリューション:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <xsl:call-template name="sumProducts">
    <xsl:with-param name="pNodes" select="item"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="sumProducts">
   <xsl:param name="pNodes" select="/.."/>
   <xsl:param name="pAccum" select="0"/>

   <xsl:choose>
    <xsl:when test="not($pNodes)">
     <xsl:value-of select="$pAccum"/>
    </xsl:when>
    <xsl:otherwise>
     <xsl:call-template name="sumProducts">
      <xsl:with-param name="pNodes" select="$pNodes[position() >1]"/>
      <xsl:with-param name="pAccum" select=
      "$pAccum + $pNodes[1]/value * $pNodes[1]/quantity"/>
     </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

この変換が提供された XML ドキュメント (上記) に適用されると、ここでも必要な正しい結果が生成されます。

8

注意: この種の問題は、FXSL ライブラリを使用して簡単に解決できます。呼び出すテンプレートはtransform-and-sum.

于 2012-05-20T02:32:04.120 に答える
1

この提案に基づいてhttps://stackoverflow.com/a/1334165/948404XSLT1.0およびXPath1.0に準拠したソリューションを思いつきました。これらは、libxml / libxsltによって実装され、PHPの実装で使用されますXSLTProcessor（@Dimitre Novatchevに感謝）確認のため）。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/items">
        <xsl:call-template name="recursivesum">
            <xsl:with-param name="items" select="*" />
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="recursivesum">
        <xsl:param name="items" />
        <xsl:param name="sum" select="0" />
        <xsl:variable name="head" select="$items[1]" />
        <xsl:variable name="tail" select="$items[position()>1]" />
        <xsl:variable name="thissum" select="$head/value * $head/quantity" />
        <xsl:choose>
            <xsl:when test="not($tail)">
                <xsl:value-of select="$sum+$thissum" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="recursivesum">
                    <xsl:with-param name="sum" select="$sum+$thissum" />
                    <xsl:with-param name="items" select="$tail" />
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:transform>
于 2012-05-21T13:32:13.557 に答える
1

これを試して：

<xsl:stylesheet version="2.0"xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:sequence select="sum(/items/item/(value * quantity))"/>
    </xsl:template>
</xsl:stylesheet>
于 2012-05-19T23:03:06.840 に答える