1

以下は私のSQLクエリ出力です

Company Col1    Col2    Col3
Comp1   1       2       3
Comp2   4       5       6
Comp3   7       8       9

接続して結果を取得する Perl 手順

my $query1= qq(select * from database_table);
my $result1 = $dbh->selectall_arrayref($query1, {Slice => {}}); 

  my %result1 =
        map { shift @$_, [ @$_ ]}
        @{$dbh->selectall_arrayref($query1)};
    my @json_output = map { encode_json( { 'name' => $_, 'data'=> $result1{$_} } )
                  } sort keys %result1 ;
    print Dumper %result1;

    [{"name":"Comp1","data":[1,2,3]}, {"name":"Comp2","data":[4,5,6]}, {"name":"Comp3","data":[7,8,9]}]

http://www.perlmonks.org/?node_id=284436#fetchingを読んでいますが、列の値を配列要素として格納する方法がわかりませんでした。(下図参照)

    [{"name":"Col1","data":[1,4,7]}, {"name":"col2","data":[2,5,8]}, {"name":"col3","data":[3,6,9]}]

また、値フィールドはデフォルトでjsonの「文字列」として表示されますが、数値として変換する方法に関する推奨事項はありますか?

4

2 に答える 2

1

あなたが示したように、「fm」と呼ばれるテーブルがあると仮定します。

use DBI;
use strict;
use warnings;
use Data::Dumper;
use JSON::XS;

my $h = DBI->connect('dbi:ODBC:xxx', 'xxx', 'xxx');
my $r = $h->selectall_arrayref(q/select company, col1, col2, col3 from fm/);
print Dumper($r);
my @to_encode;
foreach my $row (@$r) {
    my $hash;
    $hash->{name} = shift @$row;
    $hash->{data} = $row;
    push @to_encode, $hash;
}
my $js = encode_json(\@to_encode);
print Dumper($js);

出力:

$VAR1 = [
          [
            'comp1',
            '1',
            '2',
            '3'
          ],
          [
            'comp2',
            '4',
            '5',
            '6'
          ],
          [
            'comp3',
            '7',
            '8',
            '9'
          ]
        ];
$VAR1 = '[{"name":"comp1","data":["1","2","3"]},{"name":"comp2","data":["4","5","6"]},{"name":"comp3","data":["7","8","9"]}]';

編集:あなたの例を読み直してください。これは本当にあなたが望むものだと思います:

use DBI;
use strict;
use warnings;
use Data::Dumper;
use JSON::XS;

my $h = DBI->connect('dbi:ODBC:baugi', 'sa', 'easysoft');
my $s = $h->prepare(q/select col1, col2, col3 from fm/);
$s->execute;
my $cols = $s->{NAME};

my @data;
for (my $n = 0; $n < scalar(@$cols); $n++)  {
    push @data, {name => $cols->[$n], data => []};
}
while (my @row = $s->fetchrow) {
    for (my $n = 0; $n < scalar(@$cols); $n++) {
        push @{$data[$n]->{data}}, shift @row;
    }
}
my $js = encode_json(\@data);
print Dumper($js);

$VAR1 = '[{"name":"col1","data":["1","4","7"]},{"name":"col2","data":["2","5","8"]},{"name":"col3","data":["3","6","9"]}]';

それを実行し、より優れた SQL を使用して Perl の作業を単純化する、もっと洗練された方法があるかもしれませんが、それは時期尚早で、私はまだ最初のコーヒーを飲んでいません。

ご指摘のとおり、数値はエンコードされた JSON の文字列のように見えます。これは、JSON モジュール (とにかく JSON::XS) がスカラーに対して sv_POK のようなものを使用して、それらが数値か文字列かを推測し、ほとんどの DBD モジュールがすべての列を文字列としてバインドし、返されたスカラーを sv_setpv で設定するためです。面倒ですが、encode_json を呼び出す前に各数値に 0 を追加する必要があります OR:

たまたま DBD::ODBC を変更して、整数を整数としてバインドするようにしました - Perl DBD::ODBC での列バインディングの主要な変更を参照してください。

DBD::Oracle を使用すると、SQL_INTEGER として列をバインドでき、DiscardString 属性を追加できます。

$s->prepare(q/select company,col1,col2,col3 from mytable);
$s->execute;
$s->bind_col(2, undef, {TYPE => SQL_INTEGER, DiscardString => 1});
# repeat for col2 and col3
$r = $s->fetchall_arrayref

他のいくつかの DBD はすでに整数を整数としてバインドしていると思います - DBD::Pg かもしれません。

于 2012-05-21T07:47:28.533 に答える
1

これがどのようになるかです

use strict;
use warnings;

use DBI;
use DBD::mysql;    
use JSON;    
use Data::Dumper;

my $dbh = DBI->connect('DBI:mysql:dbnew:localhost');    
my $query1=qq(select * from database_table);    
my $sth=$dbh->prepare($query1);    
$sth->execute;

my @col_names=@{$sth->{NAME}};

my %result1;    

for(my $i=0;$i<3;$i++)
{
my @res = map { $_->[$i]} @{$dbh->selectall_arrayref($query1)};

@res=map {$_ * 1} @res;

$result1{shift @col_names}=\@res;
}
my @json_output = map {encode_json( { 'name' => $_ , 'data'=> $result1{$_} } )}  sort keys %result1;

print @json_output;
于 2012-05-21T07:19:18.703 に答える