1

xmlソースの異なるノードにある番号から文字列を作成する必要がありますが、データレートノードの順序はランダムであり、開始番号は少なくとも600から開始する必要があることに注意してください。600がない場合は、開始します。 800で。

<datarate rate="200" />
<datarate rate="600" />
<datarate rate="300" />
<datarate rate="400" />
<datarate rate="800" />
<datarate rate="1000" />

http://example.com/src/600/800/

グループに基づいて並べ替えを試しましたが、役に立ちませんでした。誰かアイデアがありますか？

あなたが提供できるどんな助けにも感謝します！

4

3 に答える 3

1

XSLT 2を使用すると、次のことができます。

<xsl:template match="/">
   <xsl:for-each select="//datarate[number(@rate) ge 600]">
      <xsl:sort select="@rate" data-type="number"/>
      <xsl:value-of select="@rate"/>
      <xsl:if test="not(position() eq last())">
         <xsl:text>, </xsl:text>
      </xsl:if>
   </xsl:for-each>
</xsl:template>
于 2012-05-21T17:19:37.047 に答える
0

しきい値の数値を事前に知っている場合は、次のような非常に単純な変換を行うことができます。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" encoding="UTF-8"/>

    <xsl:template match="/">
        <xsl:apply-templates select="//datarate">
            <xsl:sort select="@rate" data-type="number"/>
        </xsl:apply-templates>
    </xsl:template> 

    <xsl:template match="datarate[@rate &lt; 600]"/>

    <xsl:template match="datarate">
        [<xsl:value-of select="@rate"/>]
    </xsl:template>
</xsl:stylesheet>

があるかどうかを確認し、見つからない場合はしきい値として600使用する必要があるため、次のようになります。800600

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="text" encoding="UTF-8"/>

   <xsl:variable name="threshold">
       <xsl:choose>
           <xsl:when test="//datarate[@rate = 600]">600</xsl:when>
           <xsl:otherwise>800</xsl:otherwise>
       </xsl:choose>
   </xsl:variable>

   <xsl:template match="/">
       <xsl:apply-templates select="//datarate">
           <xsl:sort select="@rate" data-type="number"/>
       </xsl:apply-templates>
   </xsl:template>  

   <xsl:template match="datarate[@rate &lt; $threshold]"/>

   <xsl:template match="datarate">
       [<xsl:value-of select="@rate"/>]
   </xsl:template>
</xsl:stylesheet>

変数宣言にロジックを追加したい場合も、ない場合600もあります。800$threshold

ps文字列をどのように作成するかについての詳細がないので、@rateで囲まれた値を出力しました[]。

于 2012-05-21T16:04:21.360 に答える
0

この短くて単純な変換（明示的な条件付き命令はまったく使用されません-no xsl:choose、no xsl:when、no xsl:otherwise）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/*">
  <t>
    <xsl:apply-templates select="*">
     <xsl:sort select="@rate" data-type="number"/>
    </xsl:apply-templates>
  </t>
 </xsl:template>

 <xsl:template match=
  "datarate
     [not(@rate >= 600)
     or
      not(../*[@rate = 600]) and not(@rate >= 800)
     ]"/>
</xsl:stylesheet>

提供されたXMLドキュメントに適用された場合（整形式にするために単一の最上位要素にラップされます）：

<t>
    <datarate rate="200" />
    <datarate rate="600" />
    <datarate rate="300" />
    <datarate rate="400" />
    <datarate rate="800" />
    <datarate rate="1000" />
</t>

必要な正しい結果を生成します：

<t>
   <datarate rate="600"/>
   <datarate rate="800"/>
   <datarate rate="1000"/>
</t>

以下に適用すると、わずかに変更されたXMLドキュメント（600のレートではなく、601と650のレート）：

<t>
    <datarate rate="200" />
    <datarate rate="601" />
    <datarate rate="650" />
    <datarate rate="300" />
    <datarate rate="400" />
    <datarate rate="800" />
    <datarate rate="1000" />
</t>

ここでも正しい結果が生成されます。

<t>
   <datarate rate="800"/>
   <datarate rate="1000"/>
</t>
于 2012-05-22T02:30:48.527 に答える