7

を含むモナド変換子スタックがあり、全体ErrorTに変圧器を巻き付けたいと思います。ContT rこれを実行しようとすると、throwErrorタイプエラーを生成するための呼び出しContT rは、自動的にのインスタンスではないようですMonadError。いいでしょう、私は思った-私はそれを1つにするだけだ：

instance MonadError e m => MonadError e (ContT r m) where
  throwError = lift . throwError
  catchError = liftCatch . catchError

の適切な定義を使用しliftCatchます。しかし、コンパイル時にエラーが発生するようになりました。

src\Language\Types.hs:68:10:
    Illegal instance declaration for `MonadError e (ContT r m)'
      (the Coverage Condition fails for one of the functional dependencies;
       Use -XUndecidableInstances to permit this)
    In the instance declaration for `MonadError e (ContT r m)'

UndecidableInstancesプラグマを使用できてうれしいです（あまり気にならないという印象を受けています。たとえば、この質問を参照してください）が、継続トランスフォーマーをインスタンスにするのは難しいのではMonadErrorないかと思いました。結構です、Control.Monad.Transパッケージの作者はすでにそれをしているでしょう...そうですか？

4

1 に答える 1

9

ContT と ErrorT はどちらも非標準の制御フローを許可します。mtl で ContT の周りに ErrorT 型をラップする方法があります。

instance (Error e, MonadCont m) => MonadCont (ErrorT e m)

しかし、これら 2 つのモナド変換子は交換しません。記憶:

newtype Identity a = Identity {runIdentity :: a}
newtype ErrorT e m a = ErrorT {runErrorT :: m (Either e a)}
newtype ContT r m a = ContT {runContT :: (a -> m r) -> m r}

ErrorT String (ContT Bool Identity) ()パッケージmtlで問題ないのは次のとおりです。

ErrorT (ContT ( \ (k :: Either String () -> Identity Bool) -> k (Right ()) ) )

ContT r (ErrorT e Identity) aパッケージmtlでは大丈夫ではありません。しかし、あなたはそれを書くことができます。

結合されたモナドで必要な (>>=) のセマンティクスは何ですか? ネストされたエラー ハンドラのスタックが非ローカル callCC とどのようにやり取りすると予想しますか?

これが私がそれを書く方法です：

{-# LANGUAGE FlexibleInstances, MultiParamTypeClasses, UndecidableInstances   #-}
import Control.Monad
import Control.Monad.Cont
import Control.Monad.Error
import Data.Function
import Data.IORef

handleError :: MonadError e m => (e -> m a) -> m a -> m a
handleError = flip catchError

test2 :: ErrorT String (ContT () IO) ()
test2 = handleError (\e -> throwError (e ++ ":top")) $ do
  x <- liftIO $ newIORef 1
  label <- callCC (return . fix)
  v <- liftIO (readIORef x)
  liftIO (print v)
  handleError (\e -> throwError (e ++ ":middle")) $ do
    when (v==4) $ do
      throwError "ouch"
  when (v < 10) $ do
         liftIO (writeIORef x (succ v))
         handleError (\e -> throwError (e ++ ":" ++ show v)) label
  liftIO $ print "done"

go2 = runContT (runErrorT test2) (either error return)

{-

*Main> go2
1
2
3
4
*** Exception: ouch:middle:top

-}

したがって、上記は mtl だけで動作します。新しいインスタンスとその動作は次のとおりです。

instance MonadError e m => MonadError e (ContT r m) where
  throwError = lift . throwError
  catchError op h = ContT $ \k -> catchError (runContT op k) (\e -> runContT (h e) k)

test3 :: ContT () (ErrorT String IO) ()
test3 = handleError (\e -> throwError (e ++ ":top")) $ do
  x <- liftIO $ newIORef 1
  label <- callCC (return . fix)
  v <- liftIO (readIORef x)
  liftIO (print v)
  handleError (\e -> throwError (e ++ ":middle")) $ do
    when (v==4) $ do
      throwError "ouch"
  when (v < 10) $ do
         liftIO (writeIORef x (succ v))
         handleError (\e -> throwError (e ++ ":" ++ show v)) label
  liftIO $ print "done"

go3 = runErrorT (runContT test3 return)

{-

*Main> go3
1
2
3
4
Left "ouch:middle:3:middle:2:middle:1:middle:top"

-}
于 2012-05-24T18:00:19.607 に答える