1

ColdFusion 9 を使用しています

Ben Nadel のブログの良い作品を参考にして、試してみました

ucase(digestUtils.sha512(imageBinary))

SHA-512ハッシュの場合、私はそれを恐れています：

sha512 メソッドが見つかりませんでした。指定されたメソッド名と引数の型を持つメソッドがないか、ColdFusion が確実に解読できない引数の型で sha512 メソッドがオーバーロードされています。指定された引数に一致するメソッドが 0 個見つかりました。これが Java オブジェクトであり、メソッドが存在することを確認した場合は、javacast 関数を使用してあいまいさを減らします。

ここで見たので、sha512が実際にメソッドとして存在することがわかりましたが、実行すると

cfdump var="#digestUtils#"

私は得るだけです：

md5(byte[])     byte[]
md5(java.lang.String)   byte[]
md5Hex(byte[])  java.lang.String
md5Hex(java.lang.String)    java.lang.String
sha(java.lang.String)   byte[]
sha(byte[])     byte[]
shaHex(java.lang.String)    java.lang.String
shaHex(byte[])  java.lang.String

他の方法はどうなりましたか？私は何か他のことを試みなければならないと思います。

ColdFusion ソリューションでアドバイスしてください。ColdFusion/Java ソリューションも問題ありません。サードパーティの担当者が URL パラメータを提供する SSO アプリケーションを作成しようとしています。XML 投稿を取得するために、最初のパラメーターを正常にデコードしました。ここで、ハッシュ ペイロードである 2 番目のパラメーターを取得し、アルゴリズムを調べて、最初のパラメーターが改ざんされていないことを確認する必要があります。

========= 編集はここから始まります: わかりました、もう一度コードを書いてみましたが無駄でした。

アルゴリズムは単純に思えます。しかし、それを実装しようとすると、私は死んでいます。

1. compute the hash string value of the XMLPost string above:
 a. convert the base64 salt string to a UTF-8 byte array.
 b. convert the base64 XML payload string to a UTF-8 byte array.
 c. create a new byte array consisting of the XML payload bytes from step b, appended with the salt bytes from step a.
 d. perform a SHA512 hash on the concatenated byte array from step c, which results in a hashed byte array.
 e. create a new byte array consisting of the hashed bytes from step d, appended with the salt bytes from step a.
 f. convert the result of step e to a base64-encoded string and should be the value of query string parameter "h" payload hash.

xmlPost は私のサード パーティの担当者によって作成されました。この XML ペイロード文字列は UTF-8 バイト配列に変換され、その後 base-64 文字列に変換されました。結果の base-64 文字列は、以下の xmlPost の値です。

だから私はこれを行います：

<code>
<cfset xmlPost = urlDecode("PD94bWwgdmVyc2lvbj0iMS4wIj8%2bPEVzdG9yZVNzb0N1c3RvbWVyIHhtbG5zOnhzaT0iaHR0cDovL3d3dy53My5vcmcvMjAwMS9YTUxTY2hlbWEtaW5zdGFuY2UiIHhtbG5zOnhzZD0iaHR0cDovL3d3dy53My5vcmcvMjAwMS9YTUxTY2hlbWEiPjxDdXN0b21lcklkPjExMjk0MDwvQ3VzdG9tZXJJZD48RGVhbGVyQ29kZT5OODg4ODg8L0RlYWxlckNvZGU%2bPFBvaW50QmFsYW5jZT4yODA8L1BvaW50QmFsYW5jZT48Rmlyc3ROYW1lPkZhaXRoPC9GaXJzdE5hbWU%2bPExhc3ROYW1lPkh1dHVsYTwvTGFzdE5hbWU%2bPC9Fc3RvcmVTc29DdXN0b21lcj4%3d") />
<cfset salt = "3dfjh674!MujErf98344@090" />
<cfset payload_hash = urlDecode("EtLDRJfcRESFKpY4OGZZnRSN2THqT%2bEelzOuXVU06jotd2kE4yKnlYay7BqyAdcUSATRgSMaHxZa6uBqKKd9rjNkZmpoNjc0IU11akVyZjk4MzQ0QDA5MA%3d%3d") />

<cfset strXML = ToString( ToBinary( xmlpost ) ) /> <!--- to get actual XML --->

<!--- base64 encoding returns a byte array --->
<cfset saltByteArray = toBase64( salt, "utf-8" )  /> 
<cfset xmlpostByteArray = toBase64( xmlPost, "utf-8" ) />
<!--- append salt to xmlpost --->
<cfset xmlpostsaltByteArray = xmlpostByteArray & saltByteArray />

<!--- now let us perform a sha512 hash on this concatenated byte array --->
<cfscript>
// Create an instance of our DigestUtils class
digestUtils = createObject("java","org.apache.commons.codec.digest.DigestUtils");
// I hash a byte array using the given algorithm and return a
// 32-character Hexadecimal string. Home-made hash function for CF9 and earlier
function hashBytes( bytes, algorithm = "SHA-512" ){
    // Get our instance of the digest algorithm that we'll use
    // to hash the byte array.
    var messageDigest = createObject( "java", "java.security.MessageDigest" ).getInstance( javaCast( "string", algorithm ) );

    // Get the digest for the given byte array. This returns the
    // digest (i.e., hash) in byte-array format.
    var digest = messageDigest.digest( bytes );

    // Now that we have our digested byte array (i.e., our hash as another byte
    // array), we have to convert that into a HEX string. So, we'll need a HEX buffer.
    var hexBuffer = [];

    // Each integer in the byte digest needs to be converted into
    // a HEX character (with possible leading zero).
    for (byte =1 ;byte LTE ArrayLen(digest);byte = byte + 1) {
    //for ( var byte in digest){
        // Get the hex value for this byte. When converting the
        // byte, only use the right-most 8 bits (last 8 bits of the integer)
        // otherwise the sign of the byte can create oddities

        var tail = bitAnd( 255, byte );

        // Get the hex-encoding of the byte.
        var hex = ucase( formatBaseN( tail, 16 ) );

        // In order to make sure that all of the HEX characters
        // are two-digits, we have to prepend a zero for any
        // value that was originally LTE to 16 (the largest value
        // that won't result in two HEX characters).
        arrayAppend( hexBuffer, (tail <= 16 ? ("0" & hex) : hex) );
    }

    // Return the flattened character buffer.
    return( arrayToList( hexBuffer, "" ) );
}

// Get the hash of the byte array using our hashBytes() function
hashByteArray = hashBytes( xmlpostsaltByteArray );  
</cfscript>


<!--- The hashByteArray is in HEX format now. Convert to binary --->
<!--- You must binary decode the hashed string before converting it to binary --->
<cfset hashByteArray = toBase64( BinaryDecode( hashByteArray, 'HEX' ) ) />

<!--- The final step is to append this new hashbytearray with the salt byte array --->

<cfset hashByteArray = hashByteArray & saltByteArray />

<!--- now convert this value to a base64 encoded string --->

<cfset hashByteArray2 = toBase64( hashByteArray )/>

strXML 変数に対して得られるものは次のとおりです。

Actual xml structure converted from base 64 to string:
<?xml version="1.0"?><EstoreSsoCustomer xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema"><CustomerId>112940</CustomerId><DealerCode>N88888</DealerCode><PointBalance>280</PointBalance><FirstName>Faith</FirstName><LastName>Hutula</LastName></EstoreSsoCustomer>

最終的な値 hasByteArray2 は、payload_hash とほとんど似ていません。

これを行うのはこれが初めてであり、ハッシュ、バイト配列、および文字変換に関する私の理解は、数十年前に窓の外に飛び出しました。

私は何を間違っていますか？

ありがとう、フェイス・スローン

4

1 に答える 1

3

DigestUtils.sha512はバージョン 1.4 で追加されました。ColdFusion 9 は古いバージョンの 1.3 を使用しています。そのため、メソッドが見つかりません。

に基づいて他の関数を使用しMessageDigestます。必ず正しいアルゴリズムを渡してください。

    imageHash = hashBytes( imageBinary, "SHA-512" );

更新:更新されたコードに基づいて、一部の指示が誤解を招く可能性があります。指定されたエンコーディング（base64およびutf-8）からxmlおよび文字列を文字列ではなくバイト配列にデコードすることを意味していると思います：salt

    // note: salt value has invalid characters for base64
    // assuming it is a plain utf-8 string
    saltArray = charsetDecode(salt, "utf-8");
    xmlByteArray = binaryDecode(xmlPost, "base64");

次に、2 つのバイナリ配列をマージします (カスタム関数を参照)。

    mergedBytes = mergeArrays( xmlByteArray, saltArray );

新しいバイト配列のハッシュを計算します。

    messageDigest = createObject( "java", "java.security.MessageDigest" );
    messageDigest = messageDigest.getInstance( javaCast( "string", "SHA-512") );
    hashedByteArray = messageDigest.digest( javacast("byte[]", mergedBytes) );

配列を再度マージします。

    mergedBytes = mergeArrays( hashedByteArray, saltArray);

最後に、バイナリを base64 に変換して比較します。

    calculatedPayload = binaryEncode( javacast("byte[]", mergedBytes), "base64");

    // check results
    arePayloadsEqual = compare(calculatedPayload, payload_hash) eq 0;
    WriteDump("arePayloadsEqual="& arePayloadsEqual);
    WriteDump("calculatedPayload="& calculatedPayload);
    WriteDump("payload_hash="& payload_hash);

注: BinaryDecode/CharsetDecodeJava 配列を返します。CF 配列とは異なり、それらは不変です (つまり、変更できません)。したがって、便利な addAll(..) トリックはここでは機能しません。

    // merge immutable arrays the long way
    function mergeArrays( array1, array2 ){
        var i = 0;
        var newArray = [];
        for (i = 1; i <= arrayLen(arguments.array1); i++) {
            arrayAppend(newArray, arguments.array1[i]);
        }
        for (i = 1; i <= arrayLen(arguments.array2); i++) {
            arrayAppend(newArray, arguments.array2[i]);
        }
        return newArray;
    }
于 2012-05-25T20:15:01.400 に答える