1

指定したパスにノードが存在するかどうかを確認するにはどうすればよいですか? たとえば、次の xml があります。

<?xml version="1.0" encoding="UTF-8"?>
<books>
  <bookgroup name="group1">
    <book name="BookName1"/>
    <book name="BookName2"/>
    <book name="BookName3"/>
    <book name="BookName4"/>
    <book name="BookName5"/>
  </bookgroup>
  <bookgroup name="group2">
    <book name="BookName6"/>
    <book name="BookName7"/>
  </bookgroup>
  <selected>
    <book name="BookName2"/>
    <book name="BookName3"/>
  </selected>
</books>

望ましい出力は、子ノード BookName2 と BookName 3 が選択されたタグに存在するため true を返し、その子が選択されたタグに存在しないため false を返すことです。

これは私が試したことです：

    <xsl:template name="IsChildExist">
    <xsl:param name="bookGroupName"/>
    <xsl:variable name="isExist">
        <xsl:for-each select="//bookgoup[@NAME=$bookGroupName]/book">
            <xsl:variable name="childNode" select="./@name"/>
            <xsl:choose>
                <xsl:when test="count(//selected/book[@name=$childNode])>0">
                    <xsl:value-of select="true()"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="false()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </xsl:variable>
    <xsl:value-of select="$isExist"/>
</xsl:template>

しかし、for-each ループのブレークでまだ戦っています。

前もって感謝します。

4

1 に答える 1

2

XSLT には、ループから「抜け出す」という概念がありません。これは関数型言語であるため、命令型言語の通常の制御フローから離れて、考え方を変える必要があります。

特定の問題を解決するために、キーを使用して選択した本を検索できます

<xsl:key name="selected" match="selected/book" use="@name" />

実際にはxsl:for-eachはまったく必要ありません。特定の要素だけでなく、要素のリストのいずれかがキーに属しているかどうかを調べて選択できます

<xsl:template name="IsChildExist">
  <xsl:param name="bookGroupName" select="@name"/>
  <xsl:variable name="isExist">
     <xsl:choose>
        <xsl:when test="key('selected', //bookgroup[@name=$bookGroupName]/book/@name)">
           <xsl:value-of select="true()"/>
        </xsl:when>
        <xsl:otherwise>
           <xsl:value-of select="false()"/>
        </xsl:otherwise>
     </xsl:choose>
  </xsl:variable>
  <xsl:value-of select="$isExist"/>
</xsl:template>

ただし、名前付きテンプレートを使用する必要はありますか? 出力しようとしているものに応じて、XSLT で通常のテンプレート パターン マッチングを利用してこれを行うことができます。このXSLを試してください

<xsl:output method="xml" indent="yes"/>
   <xsl:key name="selected" match="selected/book" use="@name" />

   <xsl:template match="bookgroup[key('selected', book/@name)]">
      <bookgroup>
         <xsl:apply-templates select="@*"/>
         <xsl:text>TRUE</xsl:text>
      </bookgroup>
   </xsl:template>

   <xsl:template match="bookgroup">
      <bookgroup>
         <xsl:apply-templates select="@*"/>
         <xsl:text>FALSE</xsl:text>
      </bookgroup>
   </xsl:template>

   <xsl:template match="selected" />

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

サンプル XML に適用すると、次のように出力されます。

<books>
   <bookgroup name="group1">TRUE</bookgroup>
   <bookgroup name="group2">FALSE</bookgroup>
</books>
于 2012-05-28T10:39:14.433 に答える