3

数百万行のデータを持つ ORACLE テーブルがあります。属性の 1 つは DATE 型です。関数でその DATE 属性を使用して、そのテーブルに対して選択する必要があります。この関数は、どの行が基準に一致するかを教えてくれます。問題は、このクエリを実行すると、どの行が一致するかを判断するために、(明らかに) 関数を介してテーブル内のすべての行を渡す必要があることです。これは、まったくうまく機能していません。このプロセスをより速く実行するための良い解決策を見つけようとしています。

私が試してみようと思ったいくつかのアイデアを次に示します。

  1. データのサブセットでビューを作成し、それらの行を関数に渡します。
  2. データのサブセットを新しい別のテーブルにダンプし、それらの行を関数に渡します。
  3. データのサブセットで具体化されたビューを作成し、それらの行を関数に渡します。

また、結果を減らすために WHERE 句に追加できることはあまりなく、この DATE と関数の使用だけです。

これらまたは他の誰かが使用して成功したものについての意見は素晴らしいでしょう. 可能であれば、SQL ソリューションが私の最初の選択肢です。

編集 機能：

FUNCTION add_business_days (in_date IN DATE, in_number_of_days IN NUMBER,in_skip_fridays IN number DEFAULT 0,in_skip_bank_holidays IN NUMBER DEFAULT 0)
  RETURN DATE
  IS
    v_return_date DATE := in_date;
  BEGIN
    FOR i IN 1..in_number_of_days
    LOOP
      v_return_date := next_business_day(v_return_date,in_skip_fridays,in_skip_bank_holidays);
    END LOOP;
    RETURN v_return_date;
  END;

関数は次のように呼び出されます。

SELECT * 
  FROM tableA 
 WHERE tableA.begin_dt < TRUNC(SYSDATE)
   AND CUBS_DATE_PKG.add_business_days(file_dt,15) = TRUNC(SYSDATE)

関数 next_business_day

FUNCTION NEXT_BUSINESS_DAY (in_date DATE) 
RETURN DATE IS
    v_next_day DATE;
    --set up the holidays
    c_new_years_day  CONSTANT DATE := holiday_observed(TRUNC(in_date,'YYYY'));
    c_next_new_year  CONSTANT DATE := holiday_observed(TRUNC(ADD_MONTHS(in_date,12),'YYYY'));
    c_mlk_day        CONSTANT DATE := first_weekday(TRUNC(in_date,'YYYY'),'MONDAY') + 14;
    c_presidents_day CONSTANT DATE := first_weekday(ADD_MONTHS(TRUNC(in_date,'YYYY'),1),'MONDAY')+14;
    c_memorial_day   CONSTANT DATE := first_weekday(ADD_MONTHS(TRUNC(in_date,'YYYY'),5),'MONDAY')-7;
    c_july_4         CONSTANT DATE := holiday_observed(TO_DATE('04-JUL-'||TO_CHAR(in_date,'YYYY'),'DD-MON-YYYY'));
    c_pioneer_day    CONSTANT DATE := holiday_observed(TO_DATE('24-JUL-'||TO_CHAR(in_date,'YYYY'),'DD-MON-YYYY'));
    c_labor_day      CONSTANT DATE := first_weekday(ADD_MONTHS(TRUNC(in_date,'YYYY'),8),'Monday');
    c_veterans_day   CONSTANT DATE := holiday_observed(TO_DATE('11-NOV-'||TO_CHAR(in_date,'YYYY'),'DD-MON-YYYY'));
    c_thanksgiving   CONSTANT DATE := first_weekday(ADD_MONTHS(TRUNC(in_date,'YYYY'),10),'THURSDAY')+21;
    c_christmas      CONSTANT DATE := holiday_observed(TO_DATE('25-DEC-'||TO_CHAR(in_date,'YYYY'),'DD-MON-YYYY'));

  BEGIN
    IF LTRIM(RTRIM(TO_CHAR(in_date,'DAY'))) IN ('FRIDAY','SATURDAY','SUNDAY')
    THEN
      v_next_day := NEXT_DAY(in_date,'MONDAY');
    ELSE
      v_next_day := in_date + 1;
    END IF;

    v_next_day := TRUNC(v_next_day);
    --now, we have to check to see if v_next_day falls on a holiday
    IF v_next_day IN (c_new_years_day, c_next_new_year, c_mlk_day, c_presidents_day,
                      c_memorial_day,c_july_4, c_pioneer_day, c_labor_day,
                      c_veterans_day,c_thanksgiving, c_christmas)
    THEN
      v_next_day := next_business_day(v_next_day);
    END IF;
    RETURN TRUNC(v_next_day);
  END next_business_day;

解決：

他の人から提供された正確な解決策がなかったため、ここに解決策を入力していますが、@JustinCave は適切な概念を提供しました。関数を決定論的にすることになりました。そのため、既存の関数を新しい決定論的な関数でラップしました。次に、必要なテーブルにこの関数のインデックスを作成しました。22 分から 1 秒未満で実行されます。さらに、@Sebas 式を使用して結果セットを削減しました。

CREATE OR REPLACE FUNCTION deter_add_business_days (p_date DATE,p_days NUMBER)
   RETURN DATE
   DETERMINISTIC
IS
BEGIN
   RETURN cubs_owner.cubs_date_pkg.add_business_days (p_date, p_days);
END;
4

3 に答える 3

3

関数は決定論的ですか？もしそうなら、それは決定論的とマークされていますか? テーブルの関数ベースのインデックスの一部にすることはできますか?

テーブル全体をクエリするのではなく、使用できるデータのサブセットを特定できる場合は、クエリに適用できる追加の述語があることを意味します。ビュー/マテリアライズドビュー/個別のテーブルを生成するために適用する条件は、述語としてクエリに追加するのに適しているようです。

于 2012-05-31T14:29:37.460 に答える
2

関数 next_business_day:

  • IF LTRIM(RTRIM(TO_CHAR(in_date,'DAY'))) IN ('FRIDAY','SATURDAY','SUNDAY') => LTRIM/RTRIM をスキップしますか? オラクルによって事前にフォーマットされた日を扱っているので、おそらくスペースを削除する必要はありません

  • RETURN TRUNC(v_next_day); => TRUNC は必要ありません。数行上で実行しただけです。

わかりました、それは非常に小さなことですが、百万単位で乗算されます...

クエリについては、次の小さなハックを思いついたことをお勧めします: 休日は 11 日しかないため、返される行はfile_dtTRUNC(SYSDATE) + 7*(15+11)/5 日以下である必要があります。 . pl/sql ブロッ​​クは次のようになります。

DECLARE
    TYPE T_IDS IS TABLE OF tableA.id%TYPE;
    arrDays T_IDS;
    iDays NUMBER := 15;
BEGIN
    --reduce the amount of rows the gross way:
    SELECT tableA.id BULK COLLECT INTO arrDays 
      FROM tableA 
     WHERE tableA.begin_dt < TRUNC(SYSDATE)
       AND tableA.file_dt <= (TRUNC(SYSDATE) + FLOOR(7*(iDays+11)/5)));

    --use the reduced recordset against the businessdays validation to retrieve
    --correct rows:
    --here you ahve to store/process the results the way you want
    SELECT t2.* 
      FROM TABLE (CAST(arrDays) AS T_IDS) t1
        INNER JOIN tableA t2 ON t1.column_value = t2.id
     WHERE CUBS_DATE_PKG.add_business_days(t2.file_dt, iDays) = TRUNC(SYSDATE);
END;

まったくテストしていません。バグの可能性があることをお詫びします。乾杯

于 2012-05-31T16:04:26.330 に答える
2

祝日のテーブルと、そこから部分的に派生した年の毎日に基づいて次の営業日を与えるテーブルを用意するのは、ほとんど費用がかかりません。その後、クエリにそのテーブルへの安価な結合が含まれ、関数がなくなる可能性があります。

于 2012-05-31T19:39:23.050 に答える