excel - OLE2 を使用する Oracle Forms が 3 層セットアップで Excel ドキュメントを保存しない

Question

システム設定:

3-Tier environment
Client Machine - doesn't matter
Web-Tier - Not sure.  Probably Windows Server 2008 64 bit
       -Jdk 7u3
App Server - Windows Server 2008 64 bit
       -Weblogic Server 10.3.6
       -Excel 2010
       -Jdk 7u3
Database Server - Not sure. Probably Windows Server 2008 64 bit.
       -Oracle Database 11g

Programming using Oracle Forms 11.1.1.6

さて、私の問題は、彼らのシステムを設計したとき、データベース以外のすべてが 1 台の PC にあったことです。Excel 文書の読み書きはまったく問題なくできました。次に、クライアント、アプリサーバー、データベースサーバーを含む階層型セットアップにすべてを移動しました。すべてがうまくいきました。最後に、彼らは 3 層システムをセットアップしましたが、そこで問題が発生しました。

Oracle Forms で Excel ドキュメントに書き込むと、Webutil を使用してアプリケーションサーバーからファイルをコピーしようとするまで、コードはエラーなしで実行されているように見えます。

PROCEDURE Export_to_Excel IS
 -- Declare the OLE objects
 application OLE2.OBJ_TYPE;
 workbooks OLE2.OBJ_TYPE;
 workbook OLE2.OBJ_TYPE;
 worksheets OLE2.OBJ_TYPE;
 worksheet OLE2.OBJ_TYPE;
 --cell OLE2.OBJ_TYPE;
 range OLE2.OBJ_TYPE;
 range_col OLE2.OBJ_TYPE;

 -- Declare handles to OLE argument lists
 args OLE2.LIST_TYPE;
 p_filename VARCHAR(255);

 --p_file TOOL_RES.RFHANDLE;
 p_file Text_IO.File_Type;
 p_filename_client      VARCHAR2(500);
 v_filename                     VARCHAR2(500);
 v_error                            VARCHAR2(500);
 passed_filename            VARCHAR2(500);
BEGIN

 -- Retrieve user specific directory to create new file in
 p_filename := Webutil_file_transfer.get_work_area;

 -- Start Excel 
 application:=OLE2.CREATE_OBJ('Excel.Application');

 -- Return object handle to the Workbooks collection 
 workbooks:=OLE2.GET_OBJ_PROPERTY(application, 'Workbooks');

 -- Add a new Workbook object to the Workbooks collection
 workbook:=OLE2.GET_OBJ_PROPERTY(workbooks,'Add');

 -- Return object handle to the Worksheets collection for the Workbook
 worksheets:=OLE2.GET_OBJ_PROPERTY(workbook, 'Worksheets');

 -- Set up the Header worksheet
 args:=OLE2.CREATE_ARGLIST; 
 OLE2.ADD_ARG(args, 1);
 worksheet:=OLE2.GET_OBJ_PROPERTY(worksheets,'Item',args);
 OLE2.DESTROY_ARGLIST(args);
 OLE2.set_property(worksheet,'Name','Header');

 -- Build header form
 populate_header(worksheet);

 -- Autofit columns
 range := OLE2.GET_OBJ_PROPERTY( worksheet,'UsedRange');
 range_col := OLE2.GET_OBJ_PROPERTY( range,'Columns');
 OLE2.INVOKE( range_col,'AutoFit' );
 OLE2.RELEASE_OBJ( range );
 OLE2.RELEASE_OBJ( range_col );


 -- Set up the Item worksheet
 args:=OLE2.CREATE_ARGLIST; 
 OLE2.ADD_ARG(args, 2);
 worksheet:=OLE2.GET_OBJ_PROPERTY(worksheets,'Item',args);
 OLE2.DESTROY_ARGLIST(args);
 OLE2.set_property(worksheet,'Name','Item List');

 -- Build Item sheet
 populate_item_sheet(worksheet);

 -- Delete the last worksheet that excel automatically creates
 args:=OLE2.CREATE_ARGLIST; 
 OLE2.ADD_ARG(args, 3);
 worksheet:=OLE2.GET_OBJ_PROPERTY(worksheets,'Item',args);
 OLE2.DESTROY_ARGLIST(args);
 OLE2.invoke(worksheet, 'Delete');

 -- Save as worksheet
 OLE2.SET_PROPERTY(application,'DisplayAlerts',FALSE);
 IF p_filename is not null THEN
        args := OLE2.CREATE_ARGLIST;
        OLE2.ADD_ARG( args, p_filename || :PARAMETER_B1.FILENAME || '.xlsx');
        OLE2.ADD_ARG( args, 56 );
        OLE2.INVOKE( workbook,'SaveAs',args );
        OLE2.DESTROY_ARGLIST( args );
 END IF;

 -- Close workbook
 OLE2.INVOKE( workbook ,'Close');

 -- Release the OLE objects
 OLE2.RELEASE_OBJ(worksheet);
 OLE2.RELEASE_OBJ(worksheets);
 OLE2.RELEASE_OBJ(workbook);
 OLE2.RELEASE_OBJ(workbooks);
 OLE2.INVOKE(application, 'Quit');
 OLE2.RELEASE_OBJ(application); 

 --Check if file was writen correctly
 p_file := text_io.fopen(p_filename || :PARAMETER_B1.FILENAME || '.xlsx','r');
 Text_IO.Fclose(p_file);

 --Added the following code
 passed_filename := :PARAMETER_B1.FILENAME || '.xlsx';
 v_filename := p_filename || passed_filename;

 -- Popup a dialog box to allow user to select the location to save the file
 p_filename_client := CLIENT_GET_FILE_NAME ( 'C:\', passed_filename, NULL, 'Select A Directory', SAVE_FILE, FALSE );

 if p_filename_client is null then
      message ('Creation of the spreadsheet has been canceled.');
        raise form_trigger_failure;
 end if;

 -- File Transfer to Client
 PROCESS_COMM_FILE_CLIENT.FILE_TRANSFER('O', p_filename_client, v_filename, null, v_error);

 EXCEPTION
      WHEN others THEN
        Text_IO.Fclose(p_file);
                message( SQLERRM( SQLCODE ) ) ;
        if p_filename_client is not null then
          MESSAGE('An error occurred while creating file.');
      end if;
END;

フォームが本来のように App Server で作成されないため、コードは FILE_TRANSFER で失敗します。

発生している関連する問題は、Excel ドキュメントをアップロードして oracle に読み込もうとすると、ORA-305500 エラーが発生することです。DBA に Excel をアンインストールして再インストールしてもらい、インストール中にすべての機能/アドオンが含まれていることを確認しましたが、問題はまだ修正されていません。

この問題を解決するために何をすべきか、またはこの問題の解決を続けるために何をすべきかについて、誰かが私に提案してもらえますか?

ありがとう、

明細書

score 0 · Accepted Answer

問題がOLEを使用したファイルの実際の生成に関連している場合は、ディレクトリを作成することをお勧めします。

C:\Windows\System32\config\systemprofile

Oracle FormsのOLEコードは、このディレクトリでOLE構成設定をチェックします。ディレクトリが空であるかどうかは関係ありません。ディレクトリが存在することだけです。

score 0 · Accepted Answer

$ORACLE_HOME/forms/server/webutil.cfgディレクトリの読み取りに制限がある場合は、を確認してください。

基本的に、パラメータを確認してください"transfer.appsrv.read.<n>=/.../.../".

score 0 · Accepted Answer

私があなたの問題を理解している場合は、ファイルをクライアントマシンに保存するつもりです。WEB_FORMS を使用している (つまり、Web ブラウザを使用してフォームアプリケーションにアクセスしている) と仮定すると、次のコードを使用して、ファイルを AS からクライアントマシンに保存できますPROCESS_COMM_FILE_CLIENT.FILE_TRANSFER。OLE オブジェクトは AS でファイルを作成します。AS (アプリサーバー) からローカルマシンにファイルを取得する必要があります。

l_success := webutil_file_transfer.AS_to_Client_with_progress 
     (clientFile => 'c:\fine.xlsx' 
     ,serverFile => 'c:\data\file.xlsx' 
     ,progressTitle => 'Save file in progress' 
     ,progressSubTitle => 'Please wait');
if l_success then 
     message('File saved successfully'); 
else 
     message('Cannot save file'); 
end if;

上記のコードは、ファイルがローカルマシンに保存されていることを示す進行状況バーを含む [ファイルを保存中] ポップアップボックスを表示する必要があります。

excel - OLE2 を使用する Oracle Forms が 3 層セットアップで Excel ドキュメントを保存しない

3 に答える 3

Related

Reference