inno-setup - InnoSetupコンポーネントに関する長い説明

Question

Inno Setupを使用してインストールを構築しており、コンポーネントセクションを使用して、エンドユーザーがインストールするオプションのアイテムを選択できるようにしています。

これらのアイテムのいくつかは、ユーザーがそれらをインテリジェントに選択するのに十分な情報を持つために、より長い説明が必要です。

どこかにさらに詳細な説明を追加する方法はありますか？

Answer 1

このソリューションは、適切な Inno Setup のみを使用します (不審な起源の Inno Setup の廃止されたサード パーティ ビルドではありません)。

ソリューションは、 Inno Setup: OnHover eventに対する私の回答に部分的に基づいています。

HoverComponentChanged必要に応じて手順を調整してください。

[Code]

var
  LastMouse: TPoint;
  CompLabel: TLabel;

function GetCursorPos(var lpPoint: TPoint): BOOL;
  external 'GetCursorPos@user32.dll stdcall';
function SetTimer(
  hWnd: longword; nIDEvent, uElapse: LongWord; lpTimerFunc: LongWord): LongWord;
  external 'SetTimer@user32.dll stdcall';
function ScreenToClient(hWnd: HWND; var lpPoint: TPoint): BOOL;
  external 'ScreenToClient@user32.dll stdcall';
function ClientToScreen(hWnd: HWND; var lpPoint: TPoint): BOOL;
  external 'ClientToScreen@user32.dll stdcall';
function ListBox_GetItemRect(
  const hWnd: HWND; const Msg: Integer; Index: LongInt; var Rect: TRect): LongInt;
  external 'SendMessageW@user32.dll stdcall';  

const
  LB_GETITEMRECT = $0198;
  LB_GETTOPINDEX = $018E;

function FindControl(Parent: TWinControl; P: TPoint): TControl;
var
  Control: TControl;
  WinControl: TWinControl;
  I: Integer;
  P2: TPoint;
begin
  for I := 0 to Parent.ControlCount - 1 do
  begin
    Control := Parent.Controls[I];
    if Control.Visible and
       (Control.Left <= P.X) and (P.X < Control.Left + Control.Width) and
       (Control.Top <= P.Y) and (P.Y < Control.Top + Control.Height) then
    begin
      if Control is TWinControl then
      begin
        P2 := P;
        ClientToScreen(Parent.Handle, P2);
        WinControl := TWinControl(Control);
        ScreenToClient(WinControl.Handle, P2);
        Result := FindControl(WinControl, P2);
        if Result <> nil then Exit;
      end;

      Result := Control;
      Exit;
    end;
  end;

  Result := nil;
end;

function PointInRect(const Rect: TRect; const Point: TPoint): Boolean;
begin
  Result :=
    (Point.X >= Rect.Left) and (Point.X <= Rect.Right) and
    (Point.Y >= Rect.Top) and (Point.Y <= Rect.Bottom);
end;

function ListBoxItemAtPos(ListBox: TCustomListBox; Pos: TPoint): Integer;
var
  Count: Integer;
  ItemRect: TRect;
begin
  Result := SendMessage(ListBox.Handle, LB_GETTOPINDEX, 0, 0);
  Count := ListBox.Items.Count;
  while Result < Count do
  begin
    ListBox_GetItemRect(ListBox.Handle, LB_GETITEMRECT, Result, ItemRect);
    if PointInRect(ItemRect, Pos) then Exit;
    Inc(Result);
  end;
  Result := -1;
end;

procedure HoverComponentChanged(Index: Integer);
var 
  Description: string;
begin
  case Index of
    0: Description := 'This is the description of Main Files';
    1: Description := 'This is the description of Additional Files';
    2: Description := 'This is the description of Help Files';
  else
    Description := 'Move your mouse over a component to see its description.';
  end;
  CompLabel.Caption := Description;
end;

procedure HoverTimerProc(
  H: LongWord; Msg: LongWord; IdEvent: LongWord; Time: LongWord);
var
  P: TPoint;
  Control: TControl; 
  Index: Integer;
begin
  GetCursorPos(P);
  if P <> LastMouse then { just optimization }
  begin
    LastMouse := P;
    ScreenToClient(WizardForm.Handle, P);

    if (P.X < 0) or (P.Y < 0) or
       (P.X > WizardForm.ClientWidth) or (P.Y > WizardForm.ClientHeight) then
    begin
      Control := nil;
    end
      else
    begin
      Control := FindControl(WizardForm, P);
    end;

    Index := -1;
    if (Control = WizardForm.ComponentsList) and
       (not WizardForm.TypesCombo.DroppedDown) then
    begin
      P := LastMouse;
      ScreenToClient(WizardForm.ComponentsList.Handle, P);
      Index := ListBoxItemAtPos(WizardForm.ComponentsList, P);
    end;

    HoverComponentChanged(Index);
  end;
end;

procedure InitializeWizard();
begin
  SetTimer(0, 0, 50, CreateCallback(@HoverTimerProc));

  CompLabel := TLabel.Create(WizardForm);
  CompLabel.Parent := WizardForm.SelectComponentsPage;
  CompLabel.Left := WizardForm.ComponentsList.Left;
  CompLabel.Width := WizardForm.ComponentsList.Width;
  CompLabel.Height := ScaleY(32);
  CompLabel.Top :=
    WizardForm.ComponentsList.Top + WizardForm.ComponentsList.Height -
    CompLabel.Height;
  CompLabel.AutoSize := False;
  CompLabel.WordWrap := True;

  WizardForm.ComponentsList.Height :=
    WizardForm.ComponentsList.Height - CompLabel.Height - ScaleY(8);
end;

CreateCallbackfunctionには、Inno Setup 6 が必要です。Inno Setup 5 で行き詰まっている場合は、 InnoTools InnoCallbackライブラリWrapCallbackの function を使用できます。Inno Setup 5 の Unicode バージョンを使用します。

サイズ変更/サイズ変更可能/最新のウィザードでこれを正しく機能させるには、いくつかの調整が必要です。Inno Setup - サイズ変更されたウィザードでアニメーション GIF を中央に配置する方法と、拡大された Inno Setup ウィザードでの長いコンポーネントの説明を参照してください。

Answer 2

この高度なコンパイラを使用してください(ダウンロード リンクは下のどこかにあります)。

標準コンパイラよりも多くのクラスとイベントをサポートしています。プロパティ「OnItemMouseMove」にアクセスできます。これを使用すると、ラベルによって表示されるすべてのアイテムの説明を保存できます。以下に例を示します。

var
CompLabel: TLabel;

procedure OnItemMouseMove(Sender: TObject; X, Y: Integer; Index: Integer; Area: TItemArea);
begin
  case Index of
    0: CompLabel.Caption := 'This is the description of Component 1';
    1: CompLabel.Caption := 'This is the description of Component 2';
    2: CompLabel.Caption := 'This is the description of Component 3';
    3: CompLabel.Caption := 'This is the description of Component 4'
  else
    CompLabel.Caption := 'Move your mouse over a component to see its description.';
  end;
end;

procedure OnMouseLeave(Sender: TObject);
begin
  CompLabel.Caption := 'Move your mouse over a component to see its description.';
end;

procedure InitializeWizard();
begin
  CompLabel := TLabel.Create(WizardForm);
  CompLabel.Parent := WizardForm.SelectComponentsPage;
  CompLabel.SetBounds(WizardForm.ComponentsList.Left,180,WizardForm.ComponentsList.Width,200);
  CompLabel.Caption := 'Move your mouse over a component to see its description.';
  WizardForm.ComponentsList.OnItemMouseMove := @OnItemMouseMove;
  WizardForm.ComponentsList.OnMouseLeave := @OnMouseLeave;
  WizardForm.ComponentsList.Height := WizardForm.ComponentsList.Height - 40;
end;