1

データをよりアクセスしやすくするために、表形式のデータを複雑なハッシュに格納したいと考えています。スクリプトがデータをループするので、「HoHoHoA」を成長させようとしています。「perldsc」のガイドラインに従って:

push @ { $hash{$column[$i]}{$date}{$hour} }, $data[$i];

スクリプトは問題なくコンパイルおよび実行されますが、ハッシュにデータは追加されません。

print $hash{"Frequency Min"}{"09/07/08"}{"15"};

キーが存在する必要がありますが、何も返しません。ハッシュに対して「exists」を実行すると、ハッシュが存在しないことが示されます。

私が読んでいるデータファイルは次のようになります。

DATE       TIME     COLUMN1 COLUMN2 COLUMN3...    
09/06/2008 06:12:56 56.23   54.23   56.35...
09/06/2008 06:42:56 56.73   55.28   54.52...
09/06/2008 07:12:56 57.31   56.79   56.41...
09/06/2008 07:42:56 58.24   57.30   58.86...
.
.
.

特定の日付と時間の配列内の各列の値をグループ化したいので、{COLUMN}、{DATE}、および {HOUR} の 3 つのハッシュを作成します。

結果の構造は次のようになります。

%monthData = (
               "COLUMN1" => {
                                    "09/06/2008" => {
                                                      "06" => [56.23,56.73...],
                                                      "07" => [57.31,58.24...]
                                                    }
                            },
               "COLUMN2" => {
                                    "09/06/2008" => {
                                                      "06" => [54.23,55.28...],
                                                      "07" => [56.79,57.30...]
                                                    }
                            },
               "COLUMN3" => {
                                    "09/06/2008" => {
                                                      "06" => [56.35,54.52...],
                                                      "07" => [56.41,58.86...]
                                                    }
                            }
             );

私のコードを見てください：

use feature 'switch';
open DATAFILE, "<", $fileName or die "Unable to open $fileName !\n";

    my %monthData;

    while ( my $line = <DATAFILE> ) {

        chomp $line;

        SCANROWS: given ($row) {

            when (0) { # PROCESS HEADERS

                @headers = split /\t\t|\t/, $line;
            }

            default {

                @current = split /\t\t|\t/, $line;
                my $date =  $current[0];
                my ($hour,$min,$sec) = split /:/, $current[1];

                # TIMESTAMP FORMAT: dd/mm/yyyy\t\thh:mm:ss

                SCANLINE: for my $i (2 .. $#headers) {

                    push @{ $monthData{$headers[$i]}{$date}{$hour} }, $current[$i];

                }
            }
        }
    }

    close DATAFILE;

    foreach (@{ $monthData{"Active Power N Avg"}{"09/07/08"}{"06"} }) {
        $sum += $_;
        $count++;
    }

    $avg = $sum/$count; # $sum and $count are not initialized to begin with.
    print $avg; # hence $avg is also not defined.

私の必要性が十分に明確であることを願っています。これらのサブハッシュ内の配列に値を追加するにはどうすればよいですか?

4

3 に答える 3

7

これでうまくいくはずです。

#!/usr/bin/perl

use strict;
use warnings;

use List::Util qw/sum/;
sub avg { sum(@_) / @_ }

my $fileName = shift;

open my $fh, "<", $fileName
    or die "Unable to open $fileName: $!\n";

my %monthData;

chomp(my @headers = split /\t+/, <$fh>);

while (<$fh>) {
    chomp;
    my %rec;
    @rec{@headers} = split /\t+/;
    my ($hour) = split /:/, $rec{TIME}, 2;

    for my $key (grep { not /^(DATE|TIME)$/ } keys %rec) {
        push @{ $monthData{$key}{$rec{DATE}}{$hour} }, $rec{$key};
    }
}

for my $column (keys %monthData) {
    for my $date (keys %{ $monthData{$column} }) {
        for my $hour (keys %{ $monthData{$column}{$date} }) {
            my $avg = avg @{ $monthData{$column}{$date}{$hour} };
            print "average of $column for $date $hour is $avg\n";
        }
    }
}

注意事項：

  • strictおよびwarningsプラグマ
  • 合計関数を取得するためのList::Utilモジュール
  • 配列をスカラー コンテキストに配置して、配列内の項目数を取得します (avg 関数内)。
  • open のより安全な 3 引数バージョン
  • レキシカルファイルハンドル (古いベアワードスタイルのファイルハンドルではなく)
  • ループの外側で最初にヘッダーを読み取って、ループ内に特別なロジックを持たなくても済むようにする
  • ハッシュ スライスを使用してファイル データを構造化レコードに取得する
  • splitの 3 番目の引数で必要以上に時間を分割しないようにする
  • リスト代入でキャッチしたい変数のみを指定することで、無駄な変数を避ける
  • grepを使用して DATE および TIME キーが %monthData に配置されないようにする
  • それぞれがハッシュ内のレベルを処理するネストされた for ループ
于 2009-07-06T23:05:51.520 に答える
2

次のプログラムで、必要なデータ構造が生成されることを願っています。

#!/usr/bin/perl                        

use strict;
use warnings;
use Data::Dumper;

open my $fh, '<', 'input' or die $!;

my @headers;
for ( split /\t/, ~~ <$fh> ) {
    chomp;
    push @headers, $_ unless /^\t?$/;
}

my %monthData;
while (<$fh>) {
    my @line;
    for ( split /\t/ ) {
        chomp;
        push @line, $_ unless /^\t?$/;
    }

    for my $i ( 2 .. $#headers ) {
        my ($hour) = split /:/, $line[1];
        push @{ $monthData{ $headers[$i] }->{ $line[0] }->{$hour} }, $line[$i];
    }
}

print Dumper \%monthData;
于 2009-07-07T01:54:30.643 に答える
1

これを行うためのプログラムを作成する方法を次に示します。

#! /usr/bin/env perl
use strict;
use warnings;
use 5.010; # for say and m'(?<name>)'

use YAML;
use Data::Dump 'dump';

my(%data,%original);
while( my $line = <> ){
  next unless $line =~ m'
    ^ \s*
      (?<day>   0?[1-9] | [12][0-9] | 3[0-1] ) /
      (?<month> 0?[1-9] | 1[0-2] ) /
      (?<year>  [0-9]{4} )
      \s+
      (?<hour>   0?[1-9] | 1[0-9] | 2[0-4] ) :
      (?<minute> 0?[1-9] | [1-5][0-9] ) :
      (?<second> 0?[1-9] | [1-5][0-9] )
      \s+
      (?<columns> .* )
  'x;
  my @columns = split ' ', $+{columns};

  push @{
    $data{ $+{year}  }
         { $+{month} }
         { $+{day}   }
         { $+{hour}  }
  }, \@columns; # or [@columns]

  # If you insist on having it in that data structure you can do this:
  my $count = 1;
  my $date = "$+{day}/$+{month}/$+{year}";
  for my $column ( @columns ){
    my $col = 'COLUMN'.$count++;
    push @{ $original{$col}{$date}{$+{hour}} }, $column;
  }
}

say Dump \%data, \%original; # YAML
say dump \%data, \%original; # Data::Dump

この入力を考えると

日時 COLUMN1 COLUMN2 COLUMN3
2008 年 9 月 6 日 06:12:56 56.23 54.23 56.35
2008 年 9 月 6 日 06:42:56 56.73 55.28 54.52
2008 年 9 月 6 日 07:12:56 57.31 56.79 56.41
2008 年 9 月 6 日 07:42:56 58.24 57.30 58.86

perl program.pl datafile" " または " perl program.pl < datafile"のいずれか

YAML

---
2008:
  06:
    09:
      06:
        -
          - 56.23
          - 54.23
          - 56.35
        -
          - 56.73
          - 55.28
          - 54.52
      07:
        -
          - 57.31
          - 56.79
          - 56.41
        -
          - 58.24
          - 57.30
          - 58.86
---
列 1:
  2008 年 9 月 6 日:
    06:
      - 56.23
      - 56.73
    07:
      - 57.31
      - 58.24
列 2:
  2008 年 9 月 6 日:
    06:
      - 54.23
      - 55.28
    07:
      - 56.79
      - 57.30
列 3:
  2008 年 9 月 6 日:
    06:
      - 56.35
      - 54.52
    07:
      - 56.41
      - 58.86

データ::ダンプ

(
  {
    2008 => {
          "06" => {
                "09" => {
                      "06" => [["56.23", "54.23", "56.35"], ["56.73", "55.28", "54.52"]],
                      "07" => [["57.31", "56.79", "56.41"], ["58.24", "57.30", "58.86"]],
                    }、
              }、
        }、
  }、
  {
    COLUMN1 => {
                 "09/06/2008" => { "06" => ["56.23", "56.73"], "07" => ["57.31", "58.24"] },
               }、
    COLUMN2 => {
                 "09/06/2008" => { "06" => ["54.23", "55.28"], "07" => ["56.79", "57.30"] },
               }、
    COLUMN3 => {
                 "09/06/2008" => { "06" => ["56.35", "54.52"], "07" => ["56.41", "58.86"] },
               }、
  }、
)
于 2009-07-07T17:00:42.923 に答える