0

XSLTを使い始めたばかりで、これを理解しようとしています。どうぞよろしくお願いいたします。

XMLファイルの例

<purchases>
    <item id = "1" customer_id = "5">
    </item>
    <item id = "2" customer_id = "5">
    </item>
    <item id = "7" customer_id = "4">
    </item>
</purchases>

必要なHTML出力：

<table>
    <tr><th>Customer ID</th><th>Number of Items Purchased</th></tr>
    <tr><td>5</td><td>2</td></tr>
    <tr><td>4</td><td>1</td></tr>
</table>

ID番号5の顧客が2つのアイテムを購入しました。ID番号4の顧客が1つのアイテムを購入しました。

4

3 に答える 3

1

XSLT1.0ソリューション...。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" indent="yes"/>

      <xsl:template match="/">
        <table>
          <xsl:apply-templates select="purchases/item"/>     
        </table>
      </xsl:template>

   <xsl:template match="item">
     <xsl:if test="not(
       preceding-sibling::*[@customer_id=current()/@customer_id]
       )">     
         <tr><td><xsl:value-of select="@customer_id"/></td>
           <td><xsl:value-of select="count(following-sibling::item
             [@customer_id=current()/@customer_id])+1"/></td>
         </tr> 
     </xsl:if>   
  </xsl:template>

</xsl:stylesheet>
于 2012-06-05T16:38:21.800 に答える
0

XSLT 2.0が必要な場合は、次のXSLTでうまくいくはずです。

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output indent="yes"/>
    <xsl:template match="/purchases">
        <table>
            <tr>
                <th>Customer ID</th>
                <th>Number of Items Purchased</th>
            </tr>
            <xsl:for-each-group select="item" group-by="@customer_id">
                <tr>
                    <td>
                        <xsl:value-of select="current-grouping-key()"/>
                    </td>
                    <td>
                        <xsl:value-of select="count(current-group())"/>
                    </td>
                </tr>
            </xsl:for-each-group>
        </table>
    </xsl:template>
</xsl:stylesheet>
于 2012-06-05T16:17:47.467 に答える
0

考えられるXslt1.0ソリューションは次のようになります。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" indent="yes"/>

    <xsl:key name="kCustomer" match="item" use="@customer_id"/>

    <xsl:template match="/">
        <xsl:apply-templates />
    </xsl:template>

    <xsl:template match="purchases">
        <xsl:element name="table">
            <xsl:element name="tr">
                <xsl:element name="th">Customer ID</xsl:element>
                <xsl:element name="th">Number of Items Purchased</xsl:element>
                <xsl:for-each select="item[generate-id(.) = generate-id(key('kCustomer', @customer_id))]">
                    <xsl:variable name="total" select="count(/purchases/item[@customer_id=current()/@customer_id]/@id)" />
                    <xsl:element name="tr">
                        <xsl:element name="td">
                            <xsl:value-of select="./@customer_id" />
                        </xsl:element>
                        <xsl:element name="td">
                            <xsl:value-of select="$total" />
                        </xsl:element>
                    </xsl:element>
                </xsl:for-each>
            </xsl:element>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

合計に基づいてグループ化および並べ替える方法に関するDimitresの回答から採用。

Dimitreが指摘しているように、購入テンプレートは次のように簡略化できます。

    <xsl:template match="purchases">
        <table>
            <tr>
                <th>Customer ID</th>
                <th>Number of Items Purchased</th>
            </tr>
            <xsl:for-each select="item[generate-id(.) = generate-id(key('kCustomer', @customer_id))]">
                <xsl:variable name="total" select="count(/purchases/item[@customer_id=current()/@customer_id]/@id)" />
                    <tr>
                        <td>
                            <xsl:value-of select="./@customer_id" />
                        </td>
                        <td>
                            <xsl:value-of select="$total" />
                        </td>
                    </tr>
            </xsl:for-each>
        </table>
    </xsl:template>
于 2012-06-05T16:42:42.153 に答える