3

入力 XML :

<content>
    <link>
        <text>sign on</text>
        <trackableReference local="/PUBLIC_WEB_URL" title=""/>
    </link>
</content>

出力xml:

<content>
    <a id="mylink" href="PUBLIC_WEB_URL" title="">sign on</a>
</content>

xsltが試したのは、これでうまくいきます:

1) 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="content">
        <content>
            <xsl:apply-templates/>
        </content>
    </xsl:template>
    <xsl:template match="*[name()='link']">
        <a id="mylink">
            <xsl:attribute name="href"><xsl:value-of select="trackableReference/@local"/></xsl:attribute>
            <xsl:attribute name="title"><xsl:value-of select="trackableReference/@title"/></xsl:attribute>
            <xsl:value-of select="text"/>
        </a>
    </xsl:template>
</xsl:stylesheet>

2)

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="content">
        <content>
            <xsl:apply-templates/>
        </content>
    </xsl:template>
    <xsl:template match="*[name()='link']">
        <a id="mylink">
            <xsl:attribute name="href">
                <xsl:for-each select="child::*">
                    <xsl:choose>
                        <xsl:when test="name()='trackableReference'">
                            <xsl:value-of select="@local"/>
                        </xsl:when>
                    </xsl:choose>
                </xsl:for-each>
            </xsl:attribute>
            <xsl:attribute name="title">
                <xsl:for-each select="child::*">
                    <xsl:choose>
                        <xsl:when test="name()='trackableReference'">
                            <xsl:value-of select="@title"/>
                        </xsl:when>
                    </xsl:choose>
                </xsl:for-each>
            </xsl:attribute>
            <xsl:for-each select="child::*">
                <xsl:choose>
                    <xsl:when test="name()='text'">
                        <xsl:value-of select="."/>
                    </xsl:when>
                </xsl:choose>
            </xsl:for-each>
        </a>
    </xsl:template>
</xsl:stylesheet>

しかし、トラバースする子ノードに応じて値を動的に変更するグローバル変数をテンプレートに作成する必要があるシナリオがあります。このシナリオで変更された上記のテンプレートの例

<xsl:template match="*[name()='link']">
    <xsl:variable name="x1"/>
    <xsl:variable name="x2"/>
    <xsl:variable name="x3"/>
    <xsl:for-each select="child::*">
        <xsl:choose>
            <xsl:when test="name()='trackableReference'">
                <xsl:value-of select="@local"/>
                <xsl:value-of select="@title"/>
            </xsl:when>
            <xsl:when test="name()='text'">
                <xsl:value-of select="."/>
            </xsl:when>
        </xsl:choose>
    </xsl:for-each>
    <a id="mylink">
        <xsl:attribute name="href"><xsl:value-of select="$x1"/></xsl:attribute>
        <xsl:attribute name="title"><xsl:value-of select="$x2"/></xsl:attribute>
        <xsl:value-of select="$x3"/>
    </a>
</xsl:template>

ここ

  • x1から選択した値を変数に割り当てる必要があります@local。
  • x2から選択した値を変数に割り当てる必要があります@title。
  • x3変数には、ノードから選択された値を割り当てる必要があり'text'ます。

したがって、トラバースされた子ノードから抽出された値が割り当てられるように、これらの変数を上で宣言したいと思います。ここで行き詰まり、先に進めません。

誰でもこの問題を解決できますか。

4

1 に答える 1

0

変数を使用する必要がある理由はわかりませんが、例を次に示します。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="content">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="link">
        <xsl:variable name="x1" select="trackableReference/@local"/>
        <xsl:variable name="x2" select="trackableReference/@title"/>
        <xsl:variable name="x3" select="text"/>
        <a id="mylink" href="{$x1}" title="{$x2}">          
            <xsl:value-of select="$x3" />           
        </a>        
    </xsl:template>

</xsl:stylesheet>

変数が本当に必要ない場合は、次のようにすることができます。

<xsl:template match="link">
    <a id="mylink" href="{trackableReference/@local}" title="{trackableReference/@title}">          
        <xsl:value-of select="text" />          
    </a>        
</xsl:template>

また、あなたが次のように言っていることに気付きました。

値が動的に変更されるテンプレートにいくつかのグローバル変数を作成します

これは不可能です。変数は、一度設定すると値を変更できません。

于 2012-06-07T05:03:08.443 に答える