8

非常に単純でばかげた質問：

clojureはマルチマップを提供しますか？私は現在このようなものを持っています：

(defn wrap [func]
  (fn [mp x]
    (let [k (func x)]
      (assoc mp k
             (match (get mp k)
               nil [x]
               v (cons v x))))))

(defn create-mm [func lst]
  (reduce (wrap func) {} lst))

これでマップが作成され、キーごとに、そのキーを持つすべての要素のベクトルが作成されます。ただし、マルチマップは非常に基本的なデータ構造のようで、clojureに組み込まれているのではないかと思います。

ありがとう

4

1 に答える 1

11

Clojureの柔軟性により、マップとセットを使用するだけですばやく自分で作成できるため、これは別個のタイプとしては本当に必要ではないと思います。ここを参照してください：

http://paste.lisp.org/display/89840

編集（とても小さいので、これを貼り付ければよかったです）

サンプルコード（提供：Stuart Sierra）

(ns #^{:doc "A multimap is a map that permits multiple values for each
  key.  In Clojure we can represent a multimap as a map with sets as
  values."}
  multimap
  (:use [clojure.set :only (union)]))

(defn add
  "Adds key-value pairs the multimap."
  ([mm k v]
     (assoc mm k (conj (get mm k #{}) v)))
  ([mm k v & kvs]
     (apply add (add mm k v) kvs)))

(defn del
  "Removes key-value pairs from the multimap."
  ([mm k v]
     (let [mmv (disj (get mm k) v)]
       (if (seq mmv)
         (assoc mm k mmv)
         (dissoc mm k))))
  ([mm k v & kvs]
     (apply del (del mm k v) kvs)))

(defn mm-merge
  "Merges the multimaps, taking the union of values."
  [& mms]
  (apply (partial merge-with union) mms))

(comment
  (def mm (add {} :foo 1 :foo 2 :foo 3))
  ;; mm == {:foo #{1 2 3}}

  (mm-merge mm (add {} :foo 4 :bar 2))
  ;;=> {:bar #{2}, :foo #{1 2 3 4}}

  (del mm :foo 2)
  ;;=> {:foo #{1 3}}
)

コメントで指摘されたケースの追加テスト：

(comment
  (-> {} (add :a 1) (del :a 1) (contains? :a))
  ;;=> false
)
于 2012-06-08T04:16:38.377 に答える