17

Linux で作成したテキスト ファイルを Word パッドで開くと、ファイルは正常に表示されます。ただし、メモ帳で開いて、以下のコードを使用して Excel に読み込もうとすると、1 行として表示されます。

' Open the file
Open Filename For Input As #1

' Look for the Table Title
Do While Not (EOF(1) Or InStr(TextLine, TableTitle) > 0)
    Line Input #1, TextLine
Loop

元の行に分割するにはどうすればよいですか? vbaが使用できる行末セパレータはありますか?

4

3 に答える 3

19

Linux では、 Windows で使用されるキャリッジ リターン+ライン フィード( ) ではなく、改行( \n) を使用して新しい行を示すため、代わりに を使用できません。\r\nLine input

Open Filename For Input As #1
'//load all
buff = Input$(LOF(1), #1)
Close #1

'//*either* replace all lf -> crlf
buff = replace$(buff, vbLf, vbCrLf)
msgbox buff

'//*or* line by line
dim lines() As String: lines = split(buff, vbLf)
for i = 0 To UBound(lines)
   msgbox lines(i)
next
于 2012-06-08T09:39:36.817 に答える
7

関数

Public Function GetLines(fpath$) As Variant
    'REFERENCES:
    'Microsoft Scripting Runtime // Scripting.FileSystemObject
    'Microsoft VBScript Regular Expressions 5.5 // VBScript_RegExp_55.RegExp
    Dim fso As New Scripting.FileSystemObject, RE As New VBScript_RegExp_55.RegExp
    If fso.FileExists(fpath) = True Then
        Dim mts As MatchCollection, mt As Match
        Dim lines() As String
        Dim content$: content = fso.OpenTextFile(fpath).ReadAll()
        With RE
            .Global = True
            .Pattern = "[^\r\n]+" 'catch all characters except NewLines/Carraige Returns
            If .test(content) = True Then
                Set mts = .Execute(content)
                ReDim lines(mts.Count - 1)
                Dim pos&
                For Each mt In mts
                    lines(pos) = mt.Value
                    pos = pos + 1
                Next mt
            Else
                MsgBox "'" & Dir(fpath) & "' contains zero bytes!", vbExclamation
            End If
        End With
        GetLines = lines
    Else
        MsgBox "File not found at:" & vbCrLf & Dir(fpath), vbCritical
    End If
End Function

（からimmediate window）によって呼び出すことができます

?GetLines("C:\BOOT.INI")(2)

そして出力

default=multi(0)disk(0)rdisk(0)partition(1)\WINDOWS

上記の例は、任意の OS から作成された任意のテキスト ファイルからすべての行を取得するために使用できます。

お役に立てれば。

于 2012-06-08T10:08:59.653 に答える