perl - Perl で文字列 "abc" を $hash->{a}->{b}->{c} に変換する

Question

次のように、動的にネストされたハッシュ参照を作成しました。

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } };

ユーザーが「abc something」を入力できるようにすることで、c の値を「something」に設定したいと考えています。

値を取得するには、次のようにします。

my $keys = 'a.b.c'; 
my $v='something';
my $h = $hash;
foreach my $k(split /\./, $keys) {
  $h = $h->{$k};
}
print $h; # "value"

しかし、キーの値をどのように設定するのでしょうかc$v

print Dumper $hash;

変更を反映しますか？$hは foreach ループの最後の ref ではないため、これを変更しても の変更は反映されません$hash。頭の中の結び目を解決する方法のヒントはありますか?

Answer 1

このようなもの：

my $h = $hash;
my @split_key = split /\./, $keys;
my $last_key = pop @split_key;
foreach my $k (@split_key) {
    $h = $h->{$k};
}
$h->{$last_key} = $v;

Answer 2

sub dive_val :lvalue {
   my $p = \shift;
   $p = \( ($$p)->{$_} ) for @_;
   return $$p;
}

my $data;
my $key = 'a.b.c';
my $val = 'value';

dive_val($data, split /\./, $key) = $val;

この関数のより強力な (したがって少し使いにくい) バージョンがData::Diverによって提供されます。

use Data::Diver qw( DiveVal );

my $data;
my $key = 'a.b.c';
my $val = 'value';

DiveVal($data //= {}, map \$_, split /\./, $key) = $val;

(daxim の使い方は少しずれています。)

Answer 3

use strictures;
use Data::Diver qw(DiveVal);

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } },
    'a.b.c',
    'something',
);

DiveVal($hash, split /[.]/, $path) = $value;
# { a => { b => { c => 'something' } } }