actionscript - リンクに示されているようなスプリング効果（トゥイーン）を取得する方法

Question

この mouseover tweenを見ましたが、とても気に入りました。親指の上にマウスを置くだけで、スプリング エフェクトが表示されます。専門家にとっては簡単かもしれないことは知っていますが、これがどのように行われたかはわかりません。

同様の効果を得る方法を提案できる人、またはさらに良いことに、これを学ぶことができるチュートリアルを提案できる人には非常に感謝しています.

Answer 1

TweenLiteを使用します。Bounce.easeOut を約 0.75 のデュレーションで使用します。
必ず TweenLite をインポートしてください

package
{
    import com.greensock.TweenLite;
    import com.greensock.easing.Bounce;

    import flash.display.Sprite;
    import flash.events.MouseEvent;

    public class Testerooni extends Sprite
    {
        public var ball:Sprite = new Sprite();
        public function Testerooni()
        {
            createBall();
            addChild(ball);
            ball.x = 100;
            ball.y = 100;
            ball.addEventListener(MouseEvent.MOUSE_OVER,bounceOver);
            ball.addEventListener(MouseEvent.MOUSE_OUT,bounceOut);
        }

        protected function bounceOver(e:MouseEvent):void
        {
            TweenLite.to(ball,0.5,{scaleX:2,scaleY:2,ease:Bounce.easeOut});
        }

        protected function bounceOut(e:MouseEvent):void
        {
            TweenLite.to(ball,0.5,{scaleX:1,scaleY:1,ease:Bounce.easeOut});
        }

        private function createBall():void
        {
            ball.graphics.lineStyle(1);
            ball.graphics.beginFill(0x0000FF,0.4);
            ball.graphics.drawCircle(0,0,15);
        }
    }
}