0

Perlでソートするのに助けが必要です。この形式の日付の配列があります。DD-MMM-YY。例19-FEB-12。

私はすでにかなりの時間を費やしましたが、それを機能させることができませんでした。私もperlにとても慣れていません。どんなに助けても大歓迎です。ありがとう！！

4

6 に答える 6

10

これは、Time::Pieceコアモジュールのstrptimeメソッドを使用して日付をデコードし、結果のエポック秒に従ってそれらをソートすることで実行できます。

このプログラムはそのアイデアを示しています。

use strict;
use warnings;

use Time::Piece;

my @dates = <DATA>;
chomp @dates;

my @sorted = sort {
  Time::Piece->strptime($a, '%d-%b-%y') <=> Time::Piece->strptime($b, '%d-%b-%y')
} @dates;

print "$_\n" for @sorted;

__DATA__
05-FEB-12
10-MAR-11
22-AUG-11
26-FEB-12
10-NOV-12
07-JUN-11
20-APR-12
19-DEC-12
17-JAN-11
25-NOV-11
28-FEB-11
04-SEP-11
03-DEC-12
16-SEP-12
31-DEC-11
08-JUN-11
22-JUN-12
02-AUG-12
23-SEP-11
14-MAY-11

出力

17-JAN-11
28-FEB-11
10-MAR-11
14-MAY-11
07-JUN-11
08-JUN-11
22-AUG-11
04-SEP-11
23-SEP-11
25-NOV-11
31-DEC-11
05-FEB-12
26-FEB-12
20-APR-12
22-JUN-12
02-AUG-12
16-SEP-12
10-NOV-12
03-DEC-12
19-DEC-12
于 2012-06-11T21:35:08.310 に答える
3

簡単な方法は、日付をYYYYMMDD辞書順でソートできる形式に変換することです。

MM2 桁の数字で表される月でなければならないことに注意してください。

于 2012-06-11T21:22:04.993 に答える
1

コア モジュールTime::Pieceを使用して、DD-MMM-YY (または任意の入力形式) を ISO 8601 形式に変換できます。これにより、単純なソートが可能になります。この例では、ソート キーとして ISO 値を含む生データの配列を構築します。それを並べ替えます。ソートされた順序でデータを返します。

#!/usr/bin/env perl
use strict;
use warnings;
use Time::Piece;
my $t;
my @data;
while (<DATA>) {
    chomp;
    $t = Time::Piece->strptime( $_, "%d %b %y" );
    push @data, [ $t->datetime, $_ ];    #...ISO 8601 format...
}
my @sorteddata = sort { $a->[0] cmp $b->[0] } @data;
for my $value (@sorteddata) {
    print $value->[1], "\n";
}
__DATA__
19 Feb 12
17 Aug 11
31 Mar 10
01 Aug 11
08 Apr 11
29 Feb 11
于 2012-06-11T21:34:05.983 に答える
1

基本的な Perl のみ (モジュールなし) を使用してこれを行う方法を次に示します。

#! perl -w

use strict;

my @dates = ( '19-FEB-12', '15-APR-12', '13-JAN-11' );

# map month names to numbers
my %monthnum = ( 
    'JAN' => 1, 'FEB' => 2, 'MAR' => 3, 'APR' => 4,
    'MAY' => 5, 'JUN' => 6, 'JUL' => 7, 'AUG' => 8,
    'SEP' => 9, 'OCT' => 10, 'NOV' => 11, 'DEC' => 12 
    );


# sort the array using a helper function
my @sorted_dates = sort { convert_date($a) cmp convert_date($b) } @dates;

print join(", ", @sorted_dates), "\n";
# outputs: 13-JAN-11, 19-FEB-12, 15-APR-12

exit(0);

# THE END



# converts from 19-FEB-12 to 120219, for sorting
sub convert_date
{
    my $d1 = shift;
    my $d2;

    if ($d1 =~ /(\d{2})-([A-Z]{3})-(\d{2})/)
    {
        $d2 = sprintf( "%02d%02d%2d", $3, $monthnum{$2}, $1 );
    }
    else
    {
        die "Unrecognized format: $d1";
    }

    return $d2;
}

これは、日付が正しくフォーマットされていることに依存していますが、さらに検証を追加するのは簡単です。

于 2012-06-11T21:37:30.800 に答える
0

DateTimeモジュールを使用します。または、月オプション（* nix）を指定してsortコマンドを使用します。または、dd-mmm-yyyyをyyyymmddに変換してから、並べ替えます。

于 2012-06-11T21:49:05.417 に答える
-2

完全にゼロから：

印刷出力：

Unsorted:
14-OCT-06
15-OCT-06
13-OCT-06
19-FEB-12
29-DEC-02
15-JAN-02

Sorted (Least recent to most recent):
15-JAN-02
29-DEC-02
13-OCT-06
14-OCT-06
15-OCT-06
19-FEB-12

コード：

#!C:\Perl64

#Input Strings
@inputs = ('14-OCT-06','15-OCT-06','13-OCT-06', '19-FEB-12', '29-DEC-02', '15-JAN-02');

print "Unsorted:\n";
foreach(@inputs){
    print $_."\n";
}

# Hash for Month : Number
%months = ('JAN' => '01',
         'FEB' => '02',
         'MAR' => '03',
         'APR' => '04',
         'MAY' => '05',
         'JUN' => '06',
         'JUL' => '07',
         'AUG' => '08',
         'SEP' => '09',
         'OCT' => '10',
         'NOV' => '11',
         'DEC' => '12');
# Hash for Number : Month
%revmonths = ('01'=>'JAN',
         '02' => 'FEB',
         '03' => 'MAR',
         '04' => 'APR',
         '05' => 'MAY',
         '06' => 'JUN',
         '07' => 'JUL',
         '08' => 'AUG',
         '09' => 'SEP',
         '10' => 'OCT',
         '11' => 'NOV',
         '12' => 'DEC');

# Rearrange the order to 'Year-Month-Day'
@dates = ();
foreach(@inputs){
    my @split = split('-',$_);
    my @rearranged = reverse(@split);
    @rearranged[1] = $months{$rearranged[1]};
    push(@dates, \@rearranged);
}

# Sort based on these three fields
@sorted = sort { $a->[2] <=> $b->[2] } @dates;
@sorted = sort { $a->[1] <=> $b->[1] } @sorted;
@sorted = sort { $a->[0] <=> $b->[0] } @sorted;

# Replace Month Number with Month name
$size = @sorted;
for $counter (0..$size-1){
    my $ref = $sorted[$counter];
    my @array = @$ref;
    my $num = $array[1];
    $array[1] = $revmonths{$array[1]};
    my @array = reverse(@array);
    $sorted[$counter] = \@array;
}

print "\nSorted (Least recent to most recent):\n";
foreach(@sorted){
    my @temp = @$_;
    my $day = $temp[0];
    my $month = $temp[1];
    my $year = $temp[2];
    print $day."-".$month."-".$year;
    print "\n";
}
于 2012-06-11T22:28:24.623 に答える