7

.jpg を bmp に変換してから imagelist1 に保存することで、jpg をイメージリストにロードしようとしています。

コードスニップの上から下へ。Selectdir が機能し、fileexists パーツが機能します。これは、フォルダ内のすべての画像をロードするために使用されます。すべての画像は、0.jpg / 1.jpg などのように名前が付けられます。

次に、jpg を tpicture にロードします。bmp の幅/高さを設定し、同じ画像を jpg で bmp をロードしてから、bmp を画像リストに追加します。完了すると、最初の画像 0.jpg が表示されます。

2 つの問題。最初に、BMP の小さな領域 (左上) しか表示されないようにした場合、それは正しい画像でした。これはオプションクロップによるものだと思います。実行時に中心を選択する方法がわかりませんか？

第二に、私が入れた場合

Imagelist1.width := currentimage.width;
Imagelist1.height := currentimage.height;

次に、最後の画像を表示します。Imagelist1.GetBitmap()うまくいきませんでしたか？ だから私はどちらかの修正が素晴らしいと思います! 乾杯

procedure TForm1.Load1Click(Sender: TObject);
var
openDialog : TOpenDialog;
dir :string;
MyPicture :TPicture;
currentimage :Tbitmap;
image : integer;
clTrans : TColor;
begin
  Image := 0 ;
  //lets user select a dir
 SelectDirectory(Dir, [sdAllowCreate, sdPerformCreate, sdPrompt],SELDIRHELP);
  myPicture :=Tpicture.Create;
  currentimage := TBitmap.Create;
//keeps adding images as long as the file path exsist.
//thus comic pages should be renumbed to 0-XX
  while FileExists(Dir+'\'+inttostr(image)+'.jpg') do
  begin
   try
    MyPicture.LoadFromFile(Dir+'\'+inttostr(image)+'.jpg');   //load image to jpg holder
    currentimage.Width := mypicture.Width;       //set width same as jpg
    currentimage.Height:= mypicture.Height;      //set height same as jpg
    currentimage.Canvas.Draw(0, 0, myPicture.Graphic);     //draw jpg on bmp
    clTrans:=currentimage.TransparentColor;           //unknown if needed?
    //Imagelist1.Width := currentimage.Width;
    //imagelist1.Height := currentimage.Height;
    Imagelist1.Addmasked(Currentimage,clTrans);     //add to imagelist
   finally
    image := image +1;                          //add one so it adds next page
   end;
 end;
 ImageList1.GetBitmap(0,zImage1.Bitmap);
 mypicture.Free;
 currentimage.Free;
end;
4

1 に答える 1

3

TImage毎回使用することで、多くの不要なオーバーヘッドを追加しています。

このようなものを試してみてください（このように名前が付けられた画像でいっぱいのフォルダがないため、テストされていません-コンパイルされますが、<g>）。もちろん、実装句がまだ存在しない場合はJpeg、実装句に追加する必要があります。uses

procedure TForm2.Button1Click(Sender: TObject);
var
  DirName: string;
begin
  DirName := 'D:\Images';
  if SelectDirectory('Select Image Path', 
                     'D:\TempFiles', 
                     DirName, 
                     [sdNewUI], 
                     Self) then
    LoadImages(DirName);
end;

procedure TForm2.LoadImages(const Dir: string);
var
  i: Integer;
  CurFileName: string;
  JpgIn: TJPEGImage;
  BmpOut: TBitmap;
begin
  i := 1;
  while True do
  begin
    CurFileName := Format('%s%d.jpg', 
                          [IncludeTrailingPathDelimiter(Dir), i]);
    if not FileExists(CurFileName) then
      Break;
    JpgIn := TJPEGImage.Create;
    try
      JpgIn.LoadFromFile(CurFileName);

      // If you haven't initialized your ImageList width and height, it
      // defaults to 16 x 16; we can set it here, if all the images are
      // the same dimensions.
      if (ImageList1.Count = 0) then
        ImageList1.SetSize(JpgIn.Width, JpgIn.Height);

      BmpOut := TBitmap.Create;
      try
        BmpOut.Assign(JpgIn);
        ImageList1.Add(BmpOut, nil);
      finally
        BmpOut.Free;
      end;
    finally
      JpgIn.Free;
    end;
    Inc(i);
  end;
  if ImageList1.Count > 0 then
  begin
    BmpOut := TBitmap.Create;
    try
      ImageList1.GetBitmap(0, BmpOut);
      Image1.Picture.Assign(BmpOut);
    finally
      BmpOut.Free;
    end;
  end;
end;
于 2012-06-11T22:44:32.907 に答える