3

おそらく、この質問は言葉ではなく表で説明するのが一番です。

私はこのテーブルを変えようとしています:

Site | Year | Value
A    | 1999 | 5
A    | 1999 | 10
A    | 2001 | 12
B    | 1999 | 6
C    | 1996 | 4
C    | 1996 | 10

このテーブルに:

Site | Year | Value | Year-Average | Site-Average
A    | 1999 | 5     | 7.5          | 9.75
A    | 1999 | 10    | 7.5          | 9.75
A    | 2001 | 12    | 12           | 9.75
B    | 1999 | 6     | 6            | 6
C    | 1996 | 4     | 7            | 8.5
C    | 1996 | 10    | 7            | 8.5

お気付きかもしれませんが、年平均は、1 つのサイト内で1年以内に重複した値を平均したものです。次に、Site-Average は Year-Average 値から平均を計算します。

これは手動で行うことができますが、実際のデータ セットには何千もの行があり、将来使用する繰り返し可能な手順を探しています。

4

3 に答える 3

5

年平均の式は次のようになります。

=AVERAGE(IF(($A$2:$A$7=A2)*($B$2:$B$7=B2),$C$2:$C$7,""))

サイト平均の場合

=AVERAGE(IF($A$2:$A$7=A2,$D$2:$D$7,""))

Ctrl-Shift-Enter を使用して配列数式として最初のセルに入力し、列全体をコピーします。サイトの平均をカウントするときに重複した年を除外する必要がある場合、式は少し長くなります。

=AVERAGE(IF(($A$2:$A$8=A2)*(FREQUENCY(($A$2:$A$7=A2)*($B$2:$B$7=B2),($A$2:$A$7=A2)*($B$2:$B$7=B2))>0),$D$2:$D$7,""))

入力範囲の最初のオカレンスに追加の行があることに注意してください: $A$2:$A$7 ではなく、$A$2:$A$8。

于 2012-06-12T05:46:03.107 に答える
2

これらの配列数式を使用します。セルに数式を入力した後、CTL+ SHIFT+を押す必要がありますENTER

Year Averageこれをセル D2 に入れるには

=SUMPRODUCT(($A$2:$A$7=A2)*($B$2:$B$7=B2)*($C$2:$C$7))/COUNT(IF($A$2:$A$7=A2,IF($B$2:$B$7=B2,$C$2:$C$7)))

どうやって C の 8.5 にたどり着いたのですか？

スナップショット

ここに画像の説明を入力

編集

サイト平均を取得する方法は次のとおりです:)

Site-Average に必要な結果を得るには、ヘルパー列を使用する必要があります。スナップショットを見る

セルE2にこの式を入れます

=D2

E3にこの式を入れます

=IF(OR(A3<>A2,B3<>B2),D3,"")

下にドラッグします。

セルF2にこの式を入れます

=AVERAGE(IF($A$2:$A$7=A2,$E$2:$E$7,""))

CTL+ SHIFT+を押しますENTER

式を下にコピーします。

必要に応じて列 E を非表示にする

ここに画像の説明を入力

于 2012-06-12T04:43:57.750 に答える
1

ピボットテーブルを使用して年およびサイトごとの平均を計算し、vlookupsを使用して、初期テーブルの各行に関連する平均を追加できます。

于 2012-06-12T02:13:12.593 に答える