batch-file - コマンドプロンプトのレイアウトを変更する

Question

コマンドプロンプトのレイアウトをバッチファイルで変更したい。画面の中央またはどこかの位置に表示する必要がありますが、一番上には表示しないでください。私は試した：

@echo off
COLOR 8f
mode con:cols=80 lines=40 
mode con:top=10

mode con:cols=80 lines=40コマンドは機能していますが、機能していませmode con:top=10ん。
それを達成する権利を私に提案してください。

Answer 1

ウィンドウのプロパティを制御するには、次のことを行う必要があります

1. レジストリに何らかのタイトルでプロファイルを作成します。Windowsはレジストリを使用して、ウィンドウのタイトルに基づいてコマンドプロンプトウィンドウの設定を保存します。

2. プロファイルで使用されているタイトルと一致するタイトルのウィンドウを開きます

開始するには、サンプルとして次のコードを使用してください。

@echo off
setlocal
set mycmdTitle=My Special Command Prompt
Set mycmdHeight=40
Set mycmdWidth=80
Set mycmdBufferHeight=500
Set mycmdBufferWidth=%mycmdWidth%
Set mycmdxPos=0
Set mycmdyPos=120
Set mycmdColor=8f
Set /A mycmdBufferSize=mycmdBufferHeight*0x10000+mycmdBufferWidth
Set /A mycmdWindowPos=mycmdyPos*0x10000+mycmdxPos
Set /A mycmdWindowSize=mycmdHeight*0x10000+mycmdWidth
Set mycmdCmd=Title My First Command Prompt^&Echo.^&Echo.^&Echo.^&Echo.
Call :StartCommandPrompt %mycmdBufferSize% %mycmdColor% %mycmdWindowPos% %mycmdWindowSize% "%mycmdTitle%" "%mycmdCMD%"
endlocal
Goto :EOF

:StartCommandPrompt
REM receives %1=BufferSize %2=Color %3=WindowPos %4=WindowSize %5=Title %6=cmd
reg add "HKCU\Console\%~5" /V ScreenBufferSize /T REG_DWORD /D %1 /F >nul
reg add "HKCU\Console\%~5" /V ScreenColors /T REG_DWORD /D 0x%2 /F >nul
reg add "HKCU\Console\%~5" /V WindowPosition /T REG_DWORD /D %3 /F >nul
reg add "HKCU\Console\%~5" /V WindowSize /T REG_DWORD /D %4 /F >nul
start "%~5" %COMSPEC% /K %6
goto :eof

このコードは、Googleでかつて見つけた元のコードに基づいていますが、取得できないため、元の開発者に適切な帰属を示すことができません。