38

CMDシェルが使用している実行可能ファイルのバージョンを知りたいのですが。どのUNIXシェルでも、私はwhichそれを見つけるために使用します。

Windowsシェルの1つに同等のコマンドがありますか？

4

2 に答える 2

71

様々。

  1. where直接同等です：

    C:\Users\Joey>where cmd
C:\Windows\System32\cmd.exe

    in PowerShellwhere自体は のエイリアスであるためWhere-Object、PowerShell で使用する必要があることに注意してくださいwhere.exe。

  2. cmdあなたはまた使用することができますfor：

    C:\Users\Joey>for %x in (powershell.exe) do @echo %~$PATH:x
C:\Windows\System32\WindowsPowerShell\v1.0\powershell.exe

  3. PowerShell には、引数を渡すと同じことを行うGet-Commandエイリアスgcmがあります (ただし、PowerShell のエイリアス、コマンドレット、および関数に対しても機能します)。

    PS C:\Users\Joey> Get-Command where

CommandType     Name          Definition
-----------     ----          ----------
Alias           where         Where-Object
Application     where.exe     C:\Windows\system32\where.exe

    最初に返されたコマンドが実行されます。

于 2012-06-13T06:53:23.217 に答える
4

このコマンドは、現在のディレクトリまたはPATHで見つかったすべての一致するファイルを一覧表示するためWHERE、unixとはまったく同じではありません。whichジョーイが言うように、最初にリストされているのは実行するものです。最初に見つかったものだけを返すバッチスクリプトを作成するのは簡単です。

@echo off
for /f "delims=" %%F in ('where %1') do (
  echo %%F
  exit /b
)

しかしWHERE、比較的遅いです。

以下は、より高速でもう少し多くのことを行うWHICH.BATスクリプトです。次の理由により、大幅な遅延拡張トグルを使用します。1）引用符で囲まれていない特殊文字がある場合、％PATH％の拡張は信頼できません。2）遅延展開が有効になっているときにFOR変数を展開すると、を含む値が破損します!。

::WHICH.BAT  CommandName  [ReturnVar]
::
::  Determines the full path of the file that would execute if
::  CommandName were executed.
::
::  The result is stored in variable ReturnVar, or else it is
::  echoed to stdout if ReturnVar is not specified.
::
::  If no file is found, then an error message is echoed to stderr.
::
::  The ERRORLEVEL is set to one of the following values
::    0 - Success: A matching file was found
::    1 - CommandName is an internal command
::    2 - No file was found and CommandName is not an internal command
::    3 - Improper syntax - no CommandName specified
::
@echo off
setlocal disableDelayedExpansion

set "file=%~1"
setlocal enableDelayedExpansion

if not defined file (
  >&2 echo Syntax error: No CommandName specified
  exit /b 3
)


:: test for internal command
echo(!file!|findstr /i "[^abcdefghijklmnopqrstuvwxyz]" >nul || (
  set "empty=!temp!\emptyFolder"
  md "!empty!" 2>nul
  del /q "!empty!\*" 2>nul >nul
  setlocal
  pushd "!empty!"
  set path=
  (call )
  !file! /? >nul 2>nul
  if not errorlevel 9009 (
    >&2 echo "!file!" is an internal command
    popd
    exit /b 1
  )
  popd
  endlocal
)


:: test for external command
set "noExt="
if "%~x1" neq "" if "!PATHEXT:%~x1=!" neq "!PATHEXT!" set noExt="";
set "modpath=.\;!PATH!"
@for %%E in (%noExt%%PATHEXT%) do @for %%F in ("!file!%%~E") do (
  setlocal disableDelayedExpansion
  if not "%%~$modpath:F"=="" if not exist "%%~$modpath:F\" (
    endlocal & endlocal & endlocal
    if "%~2"=="" (echo %%~$modpath:F) else set "%~2=%%~$modpath:F"
    exit /b 0
  )
  endlocal
)
endlocal


>&2 echo "%~1" is not a valid command
exit /b 2

アップデート

PATHのどこかに同じルート名のexeファイルが存在する場合、内部コマンドが外部コマンドとして誤ってリストされていたため、上記のスクリプトを大幅に変更する必要がありました。

于 2012-06-13T11:51:15.183 に答える