1

Asp.Net を MySql と一緒に使用しており、エラーを解決しようとしています:

Timeout expired. The timeout period elapsed prior to obtaining a connection from the pool. This may have occurred because all pooled connections were in use and max pool size was reached.

接続が漏れていないことを確認しようとしています。接続プールのステータス (現在開いている接続の数) を知る必要がありますか? このスレッド で、パフォーマンス モニターを使用してプール数を確認できることを学びました。しかし、Sql Server の代わりに MySql を使用する場合、どのようにすればよいでしょうか?

4

1 に答える 1

0

以下で説明する上記のコードの元のリファレンスはここにあります：

私はOracleで次のことを行いましたが、MySQLでいくつかの小さな変更（変更OracleConnectionなど）を行うことで機能すると思います。ConnectionSpyというクラスを作成できます（以下を参照）。これはVB.Netにあり、必要に応じてコードをC＃に変換できます。

Imports System
Imports System.Data
Imports Oracle.DataAccess.Client
Imports System.Diagnostics
Imports System.IO

Public Class ConnectionSpy
    Dim con As OracleConnection
    Dim st As StackTrace
    Dim handler As StateChangeEventHandler
    Dim logfileName As String

    Public Sub New(ByVal con As OracleConnection, ByVal st As StackTrace, ByVal logfileName As String)
        If (logfileName Is Nothing Or logfileName.Trim().Length() = 0) Then
            Throw New ArgumentException("The logfileName cannot be null or empty", logfileName)
        End If

        Me.logfileName = logfileName
        Me.st = st
        'latch on to the connection
        Me.con = con
        handler = AddressOf StateChange
        AddHandler con.StateChange, handler
        'substitute the spy's finalizer for the 
        'connection's
        GC.SuppressFinalize(con)
    End Sub
    Public Sub StateChange(ByVal sender As Object, ByVal args As System.Data.StateChangeEventArgs)
        If args.CurrentState = ConnectionState.Closed Then
            'detach the spy object and let it float away into space
            'if the connection and the spy are already in the FReachable queue
            'GC.SuppressFinalize doesn't do anyting.
            GC.SuppressFinalize(Me)
            RemoveHandler con.StateChange, handler
            con = Nothing
            st = Nothing
        End If
    End Sub
    Protected Overrides Sub Finalize()
        'if we got here then the connection was not closed.
        Using stream As FileStream = New FileStream( _
                    logfileName, _
                    FileMode.Append, _
                    FileAccess.Write, _
                    FileShare.Write)

            Using sw As StreamWriter = New StreamWriter(stream)
                Dim text As String = _
                    DateTime.Now.ToString("yyyy-MM-dd HH:mm:ss") & _
                    ": WARNING: Open Connection is being Garbage Collected" & _
                    Environment.NewLine & "The connection was initially opened " & st.ToString()
                sw.WriteLine(text)
                sw.Flush()
                RemoveHandler con.StateChange, handler
                'clean up the connection
                con.Dispose()
            End Using

        End Using
    End Sub
End Class

次に、web.config / app.configに、次のようなセクションを追加できます。

<configuration>
    <appSettings>
        <!--
          if you need to track connections that are not being closed, set
          UseConnectionSpy to "true". If you use the connection spy, a log
          will be created (the logfile can be specified with the ConnectionSpyLog
          parameter) which will give you a stack trace of each code location
          where a connection was not closed        
        -->
    <add key="UseConnectionSpy" value="true"/>
    <add key="ConnectionSpyLog" value="c:\\log\\connectionspy.log"/>
    </appSettings>
</configuration>

次に、コード内のどこでDB接続を作成する場合でも、これを行うことができます（以下を参照）。mConnection変数は、この時点ですでに作成されているMySQL接続を表します。

    If ConfigurationManager.AppSettings("UseConnectionSpy") = "true" Then
        Dim st As StackTrace = New StackTrace(True)
        Dim sl As ConnectionSpy = New ConnectionSpy(mConnection, st, _
                                                    ConfigurationManager.AppSettings("ConnectionSpyLog"))
    End If

したがって、閉じられる前にガベージコレクションされている接続がある場合は、ログファイルに報告されます。私はいくつかのアプリケーションでこの手法を使用しましたが、うまく機能します。

MySQL DB接続のラッパークラスを作成する必要があります。上記のコードを配置して、接続を追跡できます。または、接続を作成する場所に上記の呼び出しを追加することもできます。ラッパークラスは少しすっきりしています（それが私たちがやったことです）

于 2012-06-13T12:30:11.647 に答える