1

XSLT1.0 について質問があります。タスクは、XSL テンプレートのみを使用して、特定の著者によって書かれたすべての本を HTML で書き出すことです。

<?xml version="1.0" encoding="UTF-8"?>
    <books>
        <book author="herbert">
            <name>Dune</name>
        </book>
        <book author="herbert">
            <name>Chapterhouse: Dune</name>
        </book>
        <book author="pullman">
            <name>Lyras's Oxford</name>
        </book>
        <book author="pratchett">
            <name>I Shall Wear Midnight</name>
        </book>
        <book author="pratchett">
            <name>Going Postal</name>
        </book>
        <author id="pratchett"><name>Terry Pratchett</name></author>
        <author id="herbert"><name>Frank Herbert</name></author>
        <author id="pullman"><name>Philip Pullman</name></author>
    </books>

これまでのところ、私はこの解決策を持っています。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="html"/>
    <xsl:template match="/">
        <html>
            <head/>
            <body>
                <table border="1">
                    <xsl:apply-templates select="//author"/>
                </table>
            </body>
        </html>
    </xsl:template>

    <xsl:template match="author">
        <tr>
            <td>
                <xsl:value-of select="name/text()"/>
            </td>
            <td>
                <xsl:value-of select="@id"/>
            </td>
            <td>
                <xsl:apply-templates select="/books/book[@id=@author]"/>
                --previous XPath does not work properly, it should choose only those books that are written by the given author (that this template matches)
            </td>
        </tr>
    </xsl:template>
    <xsl:template match="book">
        <xsl:value-of select="name/text()"/>
    </xsl:template>
</xsl:stylesheet>

ただし、コメントで説明されている問題があります。

Martin と Marzipan に感謝します。もう一つあります。各著者の本のタイトルをコンマで区切って表示したい場合はどうすればよいですか? 私はこの解決策を提案しますが、これを達成するためのよりエレガントな方法はありますか?

...

<xsl:apply-templates select="/books/book[current()/@id=@author][not(position()=last())]" mode="notLast"/>
<xsl:apply-templates select="/books/book[current()/@id=@author][last()]"/>
                </td>
            </tr>
        </xsl:template>
        <xsl:template match="book">
            <xsl:value-of select="name/text()"/>
        </xsl:template>

        <xsl:template match="book" mode="notLast">
            <xsl:value-of select="name/text()"/>
            <xsl:text> , </xsl:text>
        </xsl:template>

    </xsl:stylesheet>

私の質問がすでにマジパンによって回答されていることに気付きました。それで疑問は解決。

4

2 に答える 2

2

キーが必要<xsl:apply-templates select="/books/book[current()/@id=@author]"/>か、それよりも良い (xsl:stylesheet 要素の子として):

<xsl:key name="book-by-author" match="books/book" use="@author"/>

そして<xsl:apply-templates select="key('book-by-author', @id)"/>。

于 2012-06-15T17:38:53.277 に答える